dlaqgb()

subroutine dlaqgb	(	integer	m,
		integer	n,
		integer	kl,
		integer	ku,
		double precision, dimension( ldab, * )	ab,
		integer	ldab,
		double precision, dimension( * )	r,
		double precision, dimension( * )	c,
		double precision	rowcnd,
		double precision	colcnd,
		double precision	amax,
		character	equed )

DLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ.

Download DLAQGB + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DLAQGB equilibrates a general M by N band matrix A with KL
!> subdiagonals and KU superdiagonals using the row and scaling factors
!> in the vectors R and C.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	KL	!> KL is INTEGER !> The number of subdiagonals within the band of A. KL >= 0. !>
[in]	KU	!> KU is INTEGER !> The number of superdiagonals within the band of A. KU >= 0. !>
[in,out]	AB	!> AB is DOUBLE PRECISION array, dimension (LDAB,N) !> On entry, the matrix A in band storage, in rows 1 to KL+KU+1. !> The j-th column of A is stored in the j-th column of the !> array AB as follows: !> AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(m,j+kl) !> !> On exit, the equilibrated matrix, in the same storage format !> as A. See EQUED for the form of the equilibrated matrix. !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDA >= KL+KU+1. !>
[in]	R	!> R is DOUBLE PRECISION array, dimension (M) !> The row scale factors for A. !>
[in]	C	!> C is DOUBLE PRECISION array, dimension (N) !> The column scale factors for A. !>
[in]	ROWCND	!> ROWCND is DOUBLE PRECISION !> Ratio of the smallest R(i) to the largest R(i). !>
[in]	COLCND	!> COLCND is DOUBLE PRECISION !> Ratio of the smallest C(i) to the largest C(i). !>
[in]	AMAX	!> AMAX is DOUBLE PRECISION !> Absolute value of largest matrix entry. !>
[out]	EQUED	!> EQUED is CHARACTER*1 !> Specifies the form of equilibration that was done. !> = 'N': No equilibration !> = 'R': Row equilibration, i.e., A has been premultiplied by !> diag(R). !> = 'C': Column equilibration, i.e., A has been postmultiplied !> by diag(C). !> = 'B': Both row and column equilibration, i.e., A has been !> replaced by diag(R) * A * diag(C). !>

Internal Parameters:

!>  THRESH is a threshold value used to decide if row or column scaling
!>  should be done based on the ratio of the row or column scaling
!>  factors.  If ROWCND < THRESH, row scaling is done, and if
!>  COLCND < THRESH, column scaling is done.
!>
!>  LARGE and SMALL are threshold values used to decide if row scaling
!>  should be done based on the absolute size of the largest matrix
!>  element.  If AMAX > LARGE or AMAX < SMALL, row scaling is done.
!> 

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 155 of file dlaqgb.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          EQUED
      INTEGER            KL, KU, LDAB, M, N
      DOUBLE PRECISION   AMAX, COLCND, ROWCND
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AB( LDAB, * ), C( * ), R( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, THRESH
      parameter( one = 1.0d+0, thresh = 0.1d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   CJ, LARGE, SMALL
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 ) THEN
         equed = 'N'
         RETURN
      END IF
*
*     Initialize LARGE and SMALL.
*
      small = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
      large = one / small
*
      IF( rowcnd.GE.thresh .AND. amax.GE.small .AND. amax.LE.large )
     $     THEN
*
*        No row scaling
*
         IF( colcnd.GE.thresh ) THEN
*
*           No column scaling
*
            equed = 'N'
         ELSE
*
*           Column scaling
*
            DO 20 j = 1, n
               cj = c( j )
               DO 10 i = max( 1, j-ku ), min( m, j+kl )
                  ab( ku+1+i-j, j ) = cj*ab( ku+1+i-j, j )
   10          CONTINUE
   20       CONTINUE
            equed = 'C'
         END IF
      ELSE IF( colcnd.GE.thresh ) THEN
*
*        Row scaling, no column scaling
*
         DO 40 j = 1, n
            DO 30 i = max( 1, j-ku ), min( m, j+kl )
               ab( ku+1+i-j, j ) = r( i )*ab( ku+1+i-j, j )
   30       CONTINUE
   40    CONTINUE
         equed = 'R'
      ELSE
*
*        Row and column scaling
*
         DO 60 j = 1, n
            cj = c( j )
            DO 50 i = max( 1, j-ku ), min( m, j+kl )
               ab( ku+1+i-j, j ) = cj*r( i )*ab( ku+1+i-j, j )
   50       CONTINUE
   60    CONTINUE
         equed = 'B'
      END IF
*
      RETURN
*
*     End of DLAQGB
*

Here is the caller graph for this function: