LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ csyrfsx()

subroutine csyrfsx ( character uplo,
character equed,
integer n,
integer nrhs,
complex, dimension( lda, * ) a,
integer lda,
complex, dimension( ldaf, * ) af,
integer ldaf,
integer, dimension( * ) ipiv,
real, dimension( * ) s,
complex, dimension( ldb, * ) b,
integer ldb,
complex, dimension( ldx, * ) x,
integer ldx,
real rcond,
real, dimension( * ) berr,
integer n_err_bnds,
real, dimension( nrhs, * ) err_bnds_norm,
real, dimension( nrhs, * ) err_bnds_comp,
integer nparams,
real, dimension( * ) params,
complex, dimension( * ) work,
real, dimension( * ) rwork,
integer info )

CSYRFSX

Download CSYRFSX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!>    CSYRFSX improves the computed solution to a system of linear
!>    equations when the coefficient matrix is symmetric indefinite, and
!>    provides error bounds and backward error estimates for the
!>    solution.  In addition to normwise error bound, the code provides
!>    maximum componentwise error bound if possible.  See comments for
!>    ERR_BNDS_NORM and ERR_BNDS_COMP for details of the error bounds.
!>
!>    The original system of linear equations may have been equilibrated
!>    before calling this routine, as described by arguments EQUED and S
!>    below. In this case, the solution and error bounds returned are
!>    for the original unequilibrated system.
!> 
!>     Some optional parameters are bundled in the PARAMS array.  These
!>     settings determine how refinement is performed, but often the
!>     defaults are acceptable.  If the defaults are acceptable, users
!>     can pass NPARAMS = 0 which prevents the source code from accessing
!>     the PARAMS argument.
!>
Parameters
[in]UPLO
!>          UPLO is CHARACTER*1
!>       = 'U':  Upper triangle of A is stored;
!>       = 'L':  Lower triangle of A is stored.
!>
[in]EQUED
!>          EQUED is CHARACTER*1
!>     Specifies the form of equilibration that was done to A
!>     before calling this routine. This is needed to compute
!>     the solution and error bounds correctly.
!>       = 'N':  No equilibration
!>       = 'Y':  Both row and column equilibration, i.e., A has been
!>               replaced by diag(S) * A * diag(S).
!>               The right hand side B has been changed accordingly.
!>
[in]N
!>          N is INTEGER
!>     The order of the matrix A.  N >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>     The number of right hand sides, i.e., the number of columns
!>     of the matrices B and X.  NRHS >= 0.
!>
[in]A
!>          A is COMPLEX array, dimension (LDA,N)
!>     The symmetric matrix A.  If UPLO = 'U', the leading N-by-N
!>     upper triangular part of A contains the upper triangular
!>     part of the matrix A, and the strictly lower triangular
!>     part of A is not referenced.  If UPLO = 'L', the leading
!>     N-by-N lower triangular part of A contains the lower
!>     triangular part of the matrix A, and the strictly upper
!>     triangular part of A is not referenced.
!>
[in]LDA
!>          LDA is INTEGER
!>     The leading dimension of the array A.  LDA >= max(1,N).
!>
[in]AF
!>          AF is COMPLEX array, dimension (LDAF,N)
!>     The factored form of the matrix A.  AF contains the block
!>     diagonal matrix D and the multipliers used to obtain the
!>     factor U or L from the factorization A = U*D*U**T or A =
!>     L*D*L**T as computed by CSYTRF.
!>
[in]LDAF
!>          LDAF is INTEGER
!>     The leading dimension of the array AF.  LDAF >= max(1,N).
!>
[in]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>     Details of the interchanges and the block structure of D
!>     as determined by CSYTRF.
!>
[in,out]S
!>          S is REAL array, dimension (N)
!>     The scale factors for A.  If EQUED = 'Y', A is multiplied on
!>     the left and right by diag(S).  S is an input argument if FACT =
!>     'F'; otherwise, S is an output argument.  If FACT = 'F' and EQUED
!>     = 'Y', each element of S must be positive.  If S is output, each
!>     element of S is a power of the radix. If S is input, each element
!>     of S should be a power of the radix to ensure a reliable solution
!>     and error estimates. Scaling by powers of the radix does not cause
!>     rounding errors unless the result underflows or overflows.
!>     Rounding errors during scaling lead to refining with a matrix that
!>     is not equivalent to the input matrix, producing error estimates
!>     that may not be reliable.
!>
[in]B
!>          B is COMPLEX array, dimension (LDB,NRHS)
!>     The right hand side matrix B.
!>
[in]LDB
!>          LDB is INTEGER
!>     The leading dimension of the array B.  LDB >= max(1,N).
!>
[in,out]X
!>          X is COMPLEX array, dimension (LDX,NRHS)
!>     On entry, the solution matrix X, as computed by CGETRS.
!>     On exit, the improved solution matrix X.
!>
[in]LDX
!>          LDX is INTEGER
!>     The leading dimension of the array X.  LDX >= max(1,N).
!>
[out]RCOND
!>          RCOND is REAL
!>     Reciprocal scaled condition number.  This is an estimate of the
!>     reciprocal Skeel condition number of the matrix A after
!>     equilibration (if done).  If this is less than the machine
!>     precision (in particular, if it is zero), the matrix is singular
!>     to working precision.  Note that the error may still be small even
!>     if this number is very small and the matrix appears ill-
!>     conditioned.
!>
[out]BERR
!>          BERR is REAL array, dimension (NRHS)
!>     Componentwise relative backward error.  This is the
!>     componentwise relative backward error of each solution vector X(j)
!>     (i.e., the smallest relative change in any element of A or B that
!>     makes X(j) an exact solution).
!>
[in]N_ERR_BNDS
!>          N_ERR_BNDS is INTEGER
!>     Number of error bounds to return for each right hand side
!>     and each type (normwise or componentwise).  See ERR_BNDS_NORM and
!>     ERR_BNDS_COMP below.
!>
[out]ERR_BNDS_NORM
!>          ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     normwise relative error, which is defined as follows:
!>
!>     Normwise relative error in the ith solution vector:
!>             max_j (abs(XTRUE(j,i) - X(j,i)))
!>            ------------------------------
!>                  max_j abs(X(j,i))
!>
!>     The array is indexed by the type of error information as described
!>     below. There currently are up to three pieces of information
!>     returned.
!>
!>     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERR_BNDS_NORM(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated normwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*A, where S scales each row by a power of the
!>              radix so all absolute row sums of Z are approximately 1.
!>
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[out]ERR_BNDS_COMP
!>          ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     componentwise relative error, which is defined as follows:
!>
!>     Componentwise relative error in the ith solution vector:
!>                    abs(XTRUE(j,i) - X(j,i))
!>             max_j ----------------------
!>                         abs(X(j,i))
!>
!>     The array is indexed by the right-hand side i (on which the
!>     componentwise relative error depends), and the type of error
!>     information as described below. There currently are up to three
!>     pieces of information returned for each right-hand side. If
!>     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
!>     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS < 3, then at most
!>     the first (:,N_ERR_BNDS) entries are returned.
!>
!>     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERR_BNDS_COMP(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated componentwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*(A*diag(x)), where x is the solution for the
!>              current right-hand side and S scales each row of
!>              A*diag(x) by a power of the radix so all absolute row
!>              sums of Z are approximately 1.
!>
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[in]NPARAMS
!>          NPARAMS is INTEGER
!>     Specifies the number of parameters set in PARAMS.  If <= 0, the
!>     PARAMS array is never referenced and default values are used.
!>
[in,out]PARAMS
!>          PARAMS is REAL array, dimension NPARAMS
!>     Specifies algorithm parameters.  If an entry is < 0.0, then
!>     that entry will be filled with default value used for that
!>     parameter.  Only positions up to NPARAMS are accessed; defaults
!>     are used for higher-numbered parameters.
!>
!>       PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
!>            refinement or not.
!>         Default: 1.0
!>            = 0.0:  No refinement is performed, and no error bounds are
!>                    computed.
!>            = 1.0:  Use the double-precision refinement algorithm,
!>                    possibly with doubled-single computations if the
!>                    compilation environment does not support DOUBLE
!>                    PRECISION.
!>              (other values are reserved for future use)
!>
!>       PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
!>            computations allowed for refinement.
!>         Default: 10
!>         Aggressive: Set to 100 to permit convergence using approximate
!>                     factorizations or factorizations other than LU. If
!>                     the factorization uses a technique other than
!>                     Gaussian elimination, the guarantees in
!>                     err_bnds_norm and err_bnds_comp may no longer be
!>                     trustworthy.
!>
!>       PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
!>            will attempt to find a solution with small componentwise
!>            relative error in the double-precision algorithm.  Positive
!>            is true, 0.0 is false.
!>         Default: 1.0 (attempt componentwise convergence)
!>
[out]WORK
!>          WORK is COMPLEX array, dimension (2*N)
!>
[out]RWORK
!>          RWORK is REAL array, dimension (2*N)
!>
[out]INFO
!>          INFO is INTEGER
!>       = 0:  Successful exit. The solution to every right-hand side is
!>         guaranteed.
!>       < 0:  If INFO = -i, the i-th argument had an illegal value
!>       > 0 and <= N:  U(INFO,INFO) is exactly zero.  The factorization
!>         has been completed, but the factor U is exactly singular, so
!>         the solution and error bounds could not be computed. RCOND = 0
!>         is returned.
!>       = N+J: The solution corresponding to the Jth right-hand side is
!>         not guaranteed. The solutions corresponding to other right-
!>         hand sides K with K > J may not be guaranteed as well, but
!>         only the first such right-hand side is reported. If a small
!>         componentwise error is not requested (PARAMS(3) = 0.0) then
!>         the Jth right-hand side is the first with a normwise error
!>         bound that is not guaranteed (the smallest J such
!>         that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
!>         the Jth right-hand side is the first with either a normwise or
!>         componentwise error bound that is not guaranteed (the smallest
!>         J such that either ERR_BNDS_NORM(J,1) = 0.0 or
!>         ERR_BNDS_COMP(J,1) = 0.0). See the definition of
!>         ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
!>         about all of the right-hand sides check ERR_BNDS_NORM or
!>         ERR_BNDS_COMP.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 396 of file csyrfsx.f.

401*
402* -- LAPACK computational routine --
403* -- LAPACK is a software package provided by Univ. of Tennessee, --
404* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
405*
406* .. Scalar Arguments ..
407 CHARACTER UPLO, EQUED
408 INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS, NPARAMS,
409 $ N_ERR_BNDS
410 REAL RCOND
411* ..
412* .. Array Arguments ..
413 INTEGER IPIV( * )
414 COMPLEX A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
415 $ X( LDX, * ), WORK( * )
416 REAL S( * ), PARAMS( * ), BERR( * ), RWORK( * ),
417 $ ERR_BNDS_NORM( NRHS, * ),
418 $ ERR_BNDS_COMP( NRHS, * )
419* ..
420*
421* ==================================================================
422*
423* .. Parameters ..
424 REAL ZERO, ONE
425 parameter( zero = 0.0e+0, one = 1.0e+0 )
426 REAL ITREF_DEFAULT, ITHRESH_DEFAULT,
427 $ COMPONENTWISE_DEFAULT
428 REAL RTHRESH_DEFAULT, DZTHRESH_DEFAULT
429 parameter( itref_default = 1.0 )
430 parameter( ithresh_default = 10.0 )
431 parameter( componentwise_default = 1.0 )
432 parameter( rthresh_default = 0.5 )
433 parameter( dzthresh_default = 0.25 )
434 INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
435 $ LA_LINRX_CWISE_I
436 parameter( la_linrx_itref_i = 1,
437 $ la_linrx_ithresh_i = 2 )
438 parameter( la_linrx_cwise_i = 3 )
439 INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
440 $ LA_LINRX_RCOND_I
441 parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
442 parameter( la_linrx_rcond_i = 3 )
443* ..
444* .. Local Scalars ..
445 CHARACTER(1) NORM
446 LOGICAL RCEQU
447 INTEGER J, PREC_TYPE, REF_TYPE
448 INTEGER N_NORMS
449 REAL ANORM, RCOND_TMP
450 REAL ILLRCOND_THRESH, ERR_LBND, CWISE_WRONG
451 LOGICAL IGNORE_CWISE
452 INTEGER ITHRESH
453 REAL RTHRESH, UNSTABLE_THRESH
454* ..
455* .. External Subroutines ..
456 EXTERNAL xerbla, csycon, cla_syrfsx_extended
457* ..
458* .. Intrinsic Functions ..
459 INTRINSIC max, sqrt, transfer
460* ..
461* .. External Functions ..
462 EXTERNAL lsame, ilaprec
463 EXTERNAL slamch, clansy, cla_syrcond_x,
464 $ cla_syrcond_c
465 REAL SLAMCH, CLANSY, CLA_SYRCOND_X, CLA_SYRCOND_C
466 LOGICAL LSAME
467 INTEGER ILAPREC
468* ..
469* .. Executable Statements ..
470*
471* Check the input parameters.
472*
473 info = 0
474 ref_type = int( itref_default )
475 IF ( nparams .GE. la_linrx_itref_i ) THEN
476 IF ( params( la_linrx_itref_i ) .LT. 0.0 ) THEN
477 params( la_linrx_itref_i ) = itref_default
478 ELSE
479 ref_type = params( la_linrx_itref_i )
480 END IF
481 END IF
482*
483* Set default parameters.
484*
485 illrcond_thresh = real( n ) * slamch( 'Epsilon' )
486 ithresh = int( ithresh_default )
487 rthresh = rthresh_default
488 unstable_thresh = dzthresh_default
489 ignore_cwise = componentwise_default .EQ. 0.0
490*
491 IF ( nparams.GE.la_linrx_ithresh_i ) THEN
492 IF ( params( la_linrx_ithresh_i ).LT.0.0 ) THEN
493 params( la_linrx_ithresh_i ) = ithresh
494 ELSE
495 ithresh = int( params( la_linrx_ithresh_i ) )
496 END IF
497 END IF
498 IF ( nparams.GE.la_linrx_cwise_i ) THEN
499 IF ( params( la_linrx_cwise_i ).LT.0.0 ) THEN
500 IF ( ignore_cwise ) THEN
501 params( la_linrx_cwise_i ) = 0.0
502 ELSE
503 params( la_linrx_cwise_i ) = 1.0
504 END IF
505 ELSE
506 ignore_cwise = params( la_linrx_cwise_i ) .EQ. 0.0
507 END IF
508 END IF
509 IF ( ref_type .EQ. 0 .OR. n_err_bnds .EQ. 0 ) THEN
510 n_norms = 0
511 ELSE IF ( ignore_cwise ) THEN
512 n_norms = 1
513 ELSE
514 n_norms = 2
515 END IF
516*
517 rcequ = lsame( equed, 'Y' )
518*
519* Test input parameters.
520*
521 IF ( .NOT.lsame( uplo, 'U' ) .AND.
522 $ .NOT.lsame( uplo, 'L' ) ) THEN
523 info = -1
524 ELSE IF( .NOT.rcequ .AND. .NOT.lsame( equed, 'N' ) ) THEN
525 info = -2
526 ELSE IF( n.LT.0 ) THEN
527 info = -3
528 ELSE IF( nrhs.LT.0 ) THEN
529 info = -4
530 ELSE IF( lda.LT.max( 1, n ) ) THEN
531 info = -6
532 ELSE IF( ldaf.LT.max( 1, n ) ) THEN
533 info = -8
534 ELSE IF( ldb.LT.max( 1, n ) ) THEN
535 info = -12
536 ELSE IF( ldx.LT.max( 1, n ) ) THEN
537 info = -14
538 END IF
539 IF( info.NE.0 ) THEN
540 CALL xerbla( 'CSYRFSX', -info )
541 RETURN
542 END IF
543*
544* Quick return if possible.
545*
546 IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
547 rcond = 1.0
548 DO j = 1, nrhs
549 berr( j ) = 0.0
550 IF ( n_err_bnds .GE. 1 ) THEN
551 err_bnds_norm( j, la_linrx_trust_i ) = 1.0
552 err_bnds_comp( j, la_linrx_trust_i ) = 1.0
553 END IF
554 IF ( n_err_bnds .GE. 2 ) THEN
555 err_bnds_norm( j, la_linrx_err_i ) = 0.0
556 err_bnds_comp( j, la_linrx_err_i ) = 0.0
557 END IF
558 IF ( n_err_bnds .GE. 3 ) THEN
559 err_bnds_norm( j, la_linrx_rcond_i ) = 1.0
560 err_bnds_comp( j, la_linrx_rcond_i ) = 1.0
561 END IF
562 END DO
563 RETURN
564 END IF
565*
566* Default to failure.
567*
568 rcond = 0.0
569 DO j = 1, nrhs
570 berr( j ) = 1.0
571 IF ( n_err_bnds .GE. 1 ) THEN
572 err_bnds_norm( j, la_linrx_trust_i ) = 1.0
573 err_bnds_comp( j, la_linrx_trust_i ) = 1.0
574 END IF
575 IF ( n_err_bnds .GE. 2 ) THEN
576 err_bnds_norm( j, la_linrx_err_i ) = 1.0
577 err_bnds_comp( j, la_linrx_err_i ) = 1.0
578 END IF
579 IF ( n_err_bnds .GE. 3 ) THEN
580 err_bnds_norm( j, la_linrx_rcond_i ) = 0.0
581 err_bnds_comp( j, la_linrx_rcond_i ) = 0.0
582 END IF
583 END DO
584*
585* Compute the norm of A and the reciprocal of the condition
586* number of A.
587*
588 norm = 'I'
589 anorm = clansy( norm, uplo, n, a, lda, rwork )
590 CALL csycon( uplo, n, af, ldaf, ipiv, anorm, rcond, work,
591 $ info )
592*
593* Perform refinement on each right-hand side
594*
595 IF ( ref_type .NE. 0 ) THEN
596
597 prec_type = ilaprec( 'D' )
598
599 CALL cla_syrfsx_extended( prec_type, uplo, n,
600 $ nrhs, a, lda, af, ldaf, ipiv, rcequ, s, b,
601 $ ldb, x, ldx, berr, n_norms, err_bnds_norm, err_bnds_comp,
602 $ work, rwork, work(n+1),
603 $ transfer(rwork(1:2*n), (/ (zero, zero) /), n), rcond,
604 $ ithresh, rthresh, unstable_thresh, ignore_cwise,
605 $ info )
606 END IF
607
608 err_lbnd = max( 10.0, sqrt( real( n ) ) ) * slamch( 'Epsilon' )
609 IF (n_err_bnds .GE. 1 .AND. n_norms .GE. 1) THEN
610*
611* Compute scaled normwise condition number cond(A*C).
612*
613 IF ( rcequ ) THEN
614 rcond_tmp = cla_syrcond_c( uplo, n, a, lda, af, ldaf,
615 $ ipiv,
616 $ s, .true., info, work, rwork )
617 ELSE
618 rcond_tmp = cla_syrcond_c( uplo, n, a, lda, af, ldaf,
619 $ ipiv,
620 $ s, .false., info, work, rwork )
621 END IF
622 DO j = 1, nrhs
623*
624* Cap the error at 1.0.
625*
626 IF ( n_err_bnds .GE. la_linrx_err_i
627 $ .AND. err_bnds_norm( j, la_linrx_err_i ) .GT. 1.0 )
628 $ err_bnds_norm( j, la_linrx_err_i ) = 1.0
629*
630* Threshold the error (see LAWN).
631*
632 IF ( rcond_tmp .LT. illrcond_thresh ) THEN
633 err_bnds_norm( j, la_linrx_err_i ) = 1.0
634 err_bnds_norm( j, la_linrx_trust_i ) = 0.0
635 IF ( info .LE. n ) info = n + j
636 ELSE IF ( err_bnds_norm( j, la_linrx_err_i ) .LT. err_lbnd )
637 $ THEN
638 err_bnds_norm( j, la_linrx_err_i ) = err_lbnd
639 err_bnds_norm( j, la_linrx_trust_i ) = 1.0
640 END IF
641*
642* Save the condition number.
643*
644 IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
645 err_bnds_norm( j, la_linrx_rcond_i ) = rcond_tmp
646 END IF
647 END DO
648 END IF
649
650 IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 2 ) THEN
651*
652* Compute componentwise condition number cond(A*diag(Y(:,J))) for
653* each right-hand side using the current solution as an estimate of
654* the true solution. If the componentwise error estimate is too
655* large, then the solution is a lousy estimate of truth and the
656* estimated RCOND may be too optimistic. To avoid misleading users,
657* the inverse condition number is set to 0.0 when the estimated
658* cwise error is at least CWISE_WRONG.
659*
660 cwise_wrong = sqrt( slamch( 'Epsilon' ) )
661 DO j = 1, nrhs
662 IF ( err_bnds_comp( j, la_linrx_err_i ) .LT. cwise_wrong )
663 $ THEN
664 rcond_tmp = cla_syrcond_x( uplo, n, a, lda, af, ldaf,
665 $ ipiv, x(1,j), info, work, rwork )
666 ELSE
667 rcond_tmp = 0.0
668 END IF
669*
670* Cap the error at 1.0.
671*
672 IF ( n_err_bnds .GE. la_linrx_err_i
673 $ .AND. err_bnds_comp( j, la_linrx_err_i ) .GT. 1.0 )
674 $ err_bnds_comp( j, la_linrx_err_i ) = 1.0
675
676*
677* Threshold the error (see LAWN).
678*
679 IF ( rcond_tmp .LT. illrcond_thresh ) THEN
680 err_bnds_comp( j, la_linrx_err_i ) = 1.0
681 err_bnds_comp( j, la_linrx_trust_i ) = 0.0
682 IF ( .NOT. ignore_cwise
683 $ .AND. info.LT.n + j ) info = n + j
684 ELSE IF ( err_bnds_comp( j, la_linrx_err_i )
685 $ .LT. err_lbnd ) THEN
686 err_bnds_comp( j, la_linrx_err_i ) = err_lbnd
687 err_bnds_comp( j, la_linrx_trust_i ) = 1.0
688 END IF
689*
690* Save the condition number.
691*
692 IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
693 err_bnds_comp( j, la_linrx_rcond_i ) = rcond_tmp
694 END IF
695
696 END DO
697 END IF
698*
699 RETURN
700*
701* End of CSYRFSX
702*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
csycon
subroutine csycon(uplo, n, a, lda, ipiv, anorm, rcond, work, info)
CSYCON
Definition csycon.f:123
ilaprec
integer function ilaprec(prec)
ILAPREC
Definition ilaprec.f:56
cla_syrcond_c
real function cla_syrcond_c(uplo, n, a, lda, af, ldaf, ipiv, c, capply, info, work, rwork)
CLA_SYRCOND_C computes the infinity norm condition number of op(A)*inv(diag(c)) for symmetric indefin...
Definition cla_syrcond_c.f:137
cla_syrcond_x
real function cla_syrcond_x(uplo, n, a, lda, af, ldaf, ipiv, x, info, work, rwork)
CLA_SYRCOND_X computes the infinity norm condition number of op(A)*diag(x) for symmetric indefinite m...
Definition cla_syrcond_x.f:130
cla_syrfsx_extended
subroutine cla_syrfsx_extended(prec_type, uplo, n, nrhs, a, lda, af, ldaf, ipiv, colequ, c, b, ldb, y, ldy, berr_out, n_norms, err_bnds_norm, err_bnds_comp, res, ayb, dy, y_tail, rcond, ithresh, rthresh, dz_ub, ignore_cwise, info)
CLA_SYRFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric inde...
Definition cla_syrfsx_extended.f:394
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
clansy
real function clansy(norm, uplo, n, a, lda, work)
CLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition clansy.f:121
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: