sgeevx()

subroutine sgeevx	(	character	balanc,
		character	jobvl,
		character	jobvr,
		character	sense,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	wr,
		real, dimension( * )	wi,
		real, dimension( ldvl, * )	vl,
		integer	ldvl,
		real, dimension( ldvr, * )	vr,
		integer	ldvr,
		integer	ilo,
		integer	ihi,
		real, dimension( * )	scale,
		real	abnrm,
		real, dimension( * )	rconde,
		real, dimension( * )	rcondv,
		real, dimension( * )	work,
		integer	lwork,
		integer, dimension( * )	iwork,
		integer	info )

SGEEVX computes the eigenvalues and, optionally, the left and/or right eigenvectors for GE matrices

Download SGEEVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SGEEVX computes for an N-by-N real nonsymmetric matrix A, the
!> eigenvalues and, optionally, the left and/or right eigenvectors.
!>
!> Optionally also, it computes a balancing transformation to improve
!> the conditioning of the eigenvalues and eigenvectors (ILO, IHI,
!> SCALE, and ABNRM), reciprocal condition numbers for the eigenvalues
!> (RCONDE), and reciprocal condition numbers for the right
!> eigenvectors (RCONDV).
!>
!> The right eigenvector v(j) of A satisfies
!>                  A * v(j) = lambda(j) * v(j)
!> where lambda(j) is its eigenvalue.
!> The left eigenvector u(j) of A satisfies
!>               u(j)**H * A = lambda(j) * u(j)**H
!> where u(j)**H denotes the conjugate-transpose of u(j).
!>
!> The computed eigenvectors are normalized to have Euclidean norm
!> equal to 1 and largest component real.
!>
!> Balancing a matrix means permuting the rows and columns to make it
!> more nearly upper triangular, and applying a diagonal similarity
!> transformation D * A * D**(-1), where D is a diagonal matrix, to
!> make its rows and columns closer in norm and the condition numbers
!> of its eigenvalues and eigenvectors smaller.  The computed
!> reciprocal condition numbers correspond to the balanced matrix.
!> Permuting rows and columns will not change the condition numbers
!> (in exact arithmetic) but diagonal scaling will.  For further
!> explanation of balancing, see section 4.10.2 of the LAPACK
!> Users' Guide.
!> 

Parameters

[in]	BALANC	!> BALANC is CHARACTER*1 !> Indicates how the input matrix should be diagonally scaled !> and/or permuted to improve the conditioning of its !> eigenvalues. !> = 'N': Do not diagonally scale or permute; !> = 'P': Perform permutations to make the matrix more nearly !> upper triangular. Do not diagonally scale; !> = 'S': Diagonally scale the matrix, i.e. replace A by !> D*A*D**(-1), where D is a diagonal matrix chosen !> to make the rows and columns of A more equal in !> norm. Do not permute; !> = 'B': Both diagonally scale and permute A. !> !> Computed reciprocal condition numbers will be for the matrix !> after balancing and/or permuting. Permuting does not change !> condition numbers (in exact arithmetic), but balancing does. !>
[in]	JOBVL	!> JOBVL is CHARACTER*1 !> = 'N': left eigenvectors of A are not computed; !> = 'V': left eigenvectors of A are computed. !> If SENSE = 'E' or 'B', JOBVL must = 'V'. !>
[in]	JOBVR	!> JOBVR is CHARACTER*1 !> = 'N': right eigenvectors of A are not computed; !> = 'V': right eigenvectors of A are computed. !> If SENSE = 'E' or 'B', JOBVR must = 'V'. !>
[in]	SENSE	!> SENSE is CHARACTER*1 !> Determines which reciprocal condition numbers are computed. !> = 'N': None are computed; !> = 'E': Computed for eigenvalues only; !> = 'V': Computed for right eigenvectors only; !> = 'B': Computed for eigenvalues and right eigenvectors. !> !> If SENSE = 'E' or 'B', both left and right eigenvectors !> must also be computed (JOBVL = 'V' and JOBVR = 'V'). !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is REAL array, dimension (LDA,N) !> On entry, the N-by-N matrix A. !> On exit, A has been overwritten. If JOBVL = 'V' or !> JOBVR = 'V', A contains the real Schur form of the balanced !> version of the input matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	WR	!> WR is REAL array, dimension (N) !>
[out]	WI	!> WI is REAL array, dimension (N) !> WR and WI contain the real and imaginary parts, !> respectively, of the computed eigenvalues. Complex !> conjugate pairs of eigenvalues will appear consecutively !> with the eigenvalue having the positive imaginary part !> first. !>
[out]	VL	!> VL is REAL array, dimension (LDVL,N) !> If JOBVL = 'V', the left eigenvectors u(j) are stored one !> after another in the columns of VL, in the same order !> as their eigenvalues. !> If JOBVL = 'N', VL is not referenced. !> If the j-th eigenvalue is real, then u(j) = VL(:,j), !> the j-th column of VL. !> If the j-th and (j+1)-st eigenvalues form a complex !> conjugate pair, then u(j) = VL(:,j) + i*VL(:,j+1) and !> u(j+1) = VL(:,j) - i*VL(:,j+1). !>
[in]	LDVL	!> LDVL is INTEGER !> The leading dimension of the array VL. LDVL >= 1; if !> JOBVL = 'V', LDVL >= N. !>
[out]	VR	!> VR is REAL array, dimension (LDVR,N) !> If JOBVR = 'V', the right eigenvectors v(j) are stored one !> after another in the columns of VR, in the same order !> as their eigenvalues. !> If JOBVR = 'N', VR is not referenced. !> If the j-th eigenvalue is real, then v(j) = VR(:,j), !> the j-th column of VR. !> If the j-th and (j+1)-st eigenvalues form a complex !> conjugate pair, then v(j) = VR(:,j) + i*VR(:,j+1) and !> v(j+1) = VR(:,j) - i*VR(:,j+1). !>
[in]	LDVR	!> LDVR is INTEGER !> The leading dimension of the array VR. LDVR >= 1, and if !> JOBVR = 'V', LDVR >= N. !>
[out]	ILO	!> ILO is INTEGER !>
[out]	IHI	!> IHI is INTEGER !> ILO and IHI are integer values determined when A was !> balanced. The balanced A(i,j) = 0 if I > J and !> J = 1,...,ILO-1 or I = IHI+1,...,N. !>
[out]	SCALE	!> SCALE is REAL array, dimension (N) !> Details of the permutations and scaling factors applied !> when balancing A. If P(j) is the index of the row and column !> interchanged with row and column j, and D(j) is the scaling !> factor applied to row and column j, then !> SCALE(J) = P(J), for J = 1,...,ILO-1 !> = D(J), for J = ILO,...,IHI !> = P(J) for J = IHI+1,...,N. !> The order in which the interchanges are made is N to IHI+1, !> then 1 to ILO-1. !>
[out]	ABNRM	!> ABNRM is REAL !> The one-norm of the balanced matrix (the maximum !> of the sum of absolute values of elements of any column). !>
[out]	RCONDE	!> RCONDE is REAL array, dimension (N) !> RCONDE(j) is the reciprocal condition number of the j-th !> eigenvalue. !>
[out]	RCONDV	!> RCONDV is REAL array, dimension (N) !> RCONDV(j) is the reciprocal condition number of the j-th !> right eigenvector. !>
[out]	WORK	!> WORK is REAL array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. If SENSE = 'N' or 'E', !> LWORK >= max(1,2*N), and if JOBVL = 'V' or JOBVR = 'V', !> LWORK >= 3*N. If SENSE = 'V' or 'B', LWORK >= N*(N+6). !> For good performance, LWORK must generally be larger. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (2*N-2) !> If SENSE = 'N' or 'E', not referenced. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = i, the QR algorithm failed to compute all the !> eigenvalues, and no eigenvectors or condition numbers !> have been computed; elements 1:ILO-1 and i+1:N of WR !> and WI contain eigenvalues which have converged. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 301 of file sgeevx.f.

      implicit none
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          BALANC, JOBVL, JOBVR, SENSE
      INTEGER            IHI, ILO, INFO, LDA, LDVL, LDVR, LWORK, N
      REAL               ABNRM
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * )
      REAL               A( LDA, * ), RCONDE( * ), RCONDV( * ),
     $                   SCALE( * ), VL( LDVL, * ), VR( LDVR, * ),
     $                   WI( * ), WORK( * ), WR( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL   ZERO, ONE
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, SCALEA, WANTVL, WANTVR, WNTSNB, WNTSNE,
     $                   WNTSNN, WNTSNV
      CHARACTER          JOB, SIDE
      INTEGER            HSWORK, I, ICOND, IERR, ITAU, IWRK, K,
     $                   LWORK_TREVC, MAXWRK, MINWRK, NOUT
      REAL               ANRM, BIGNUM, CS, CSCALE, EPS, R, SCL, SMLNUM,
     $                   SN
*     ..
*     .. Local Arrays ..
      LOGICAL            SELECT( 1 )
      REAL               DUM( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgebak, sgebal, sgehrd, shseqr,
     $                   slacpy,
     $                   slartg, slascl, sorghr, srot, sscal, strevc3,
     $                   strsna, xerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ISAMAX, ILAENV
      REAL               SLAMCH, SLANGE, SLAPY2,
     $                   SNRM2, SROUNDUP_LWORK
      EXTERNAL           lsame, isamax, ilaenv,
     $                   slamch, slange, slapy2,
     $                   snrm2, sroundup_lwork
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      wantvl = lsame( jobvl, 'V' )
      wantvr = lsame( jobvr, 'V' )
      wntsnn = lsame( sense, 'N' )
      wntsne = lsame( sense, 'E' )
      wntsnv = lsame( sense, 'V' )
      wntsnb = lsame( sense, 'B' )
      IF( .NOT.( lsame( balanc, 'N' ) .OR. lsame( balanc, 'S' )
     $      .OR.
     $                  lsame( balanc, 'P' ) .OR.
     $                  lsame( balanc, 'B' ) ) )
     $     THEN
         info = -1
      ELSE IF( ( .NOT.wantvl ) .AND.
     $         ( .NOT.lsame( jobvl, 'N' ) ) ) THEN
         info = -2
      ELSE IF( ( .NOT.wantvr ) .AND.
     $         ( .NOT.lsame( jobvr, 'N' ) ) ) THEN
         info = -3
      ELSE IF( .NOT.( wntsnn .OR. wntsne .OR. wntsnb .OR. wntsnv ) .OR.
     $         ( ( wntsne .OR. wntsnb ) .AND. .NOT.( wantvl .AND.
     $         wantvr ) ) ) THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -7
      ELSE IF( ldvl.LT.1 .OR. ( wantvl .AND. ldvl.LT.n ) ) THEN
         info = -11
      ELSE IF( ldvr.LT.1 .OR. ( wantvr .AND. ldvr.LT.n ) ) THEN
         info = -13
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       NB refers to the optimal block size for the immediately
*       following subroutine, as returned by ILAENV.
*       HSWORK refers to the workspace preferred by SHSEQR, as
*       calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
*       the worst case.)
*
      IF( info.EQ.0 ) THEN
         IF( n.EQ.0 ) THEN
            minwrk = 1
            maxwrk = 1
         ELSE
            maxwrk = n + n*ilaenv( 1, 'SGEHRD', ' ', n, 1, n, 0 )
*
            IF( wantvl ) THEN
               CALL strevc3( 'L', 'B', SELECT, n, a, lda,
     $                       vl, ldvl, vr, ldvr,
     $                       n, nout, work, -1, ierr )
               lwork_trevc = int( work(1) )
               maxwrk = max( maxwrk, n + lwork_trevc )
               CALL shseqr( 'S', 'V', n, 1, n, a, lda, wr, wi, vl,
     $                      ldvl,
     $                work, -1, info )
            ELSE IF( wantvr ) THEN
               CALL strevc3( 'R', 'B', SELECT, n, a, lda,
     $                       vl, ldvl, vr, ldvr,
     $                       n, nout, work, -1, ierr )
               lwork_trevc = int( work(1) )
               maxwrk = max( maxwrk, n + lwork_trevc )
               CALL shseqr( 'S', 'V', n, 1, n, a, lda, wr, wi, vr,
     $                      ldvr,
     $                work, -1, info )
            ELSE
               IF( wntsnn ) THEN
                  CALL shseqr( 'E', 'N', n, 1, n, a, lda, wr, wi, vr,
     $                ldvr, work, -1, info )
               ELSE
                  CALL shseqr( 'S', 'N', n, 1, n, a, lda, wr, wi, vr,
     $                ldvr, work, -1, info )
               END IF
            END IF
            hswork = int( work(1) )
*
            IF( ( .NOT.wantvl ) .AND. ( .NOT.wantvr ) ) THEN
               minwrk = 2*n
               IF( .NOT.wntsnn )
     $            minwrk = max( minwrk, n*n+6*n )
               maxwrk = max( maxwrk, hswork )
               IF( .NOT.wntsnn )
     $            maxwrk = max( maxwrk, n*n + 6*n )
            ELSE
               minwrk = 3*n
               IF( ( .NOT.wntsnn ) .AND. ( .NOT.wntsne ) )
     $            minwrk = max( minwrk, n*n + 6*n )
               maxwrk = max( maxwrk, hswork )
               maxwrk = max( maxwrk, n + ( n - 1 )*ilaenv( 1,
     $                       'SORGHR',
     $                       ' ', n, 1, n, -1 ) )
               IF( ( .NOT.wntsnn ) .AND. ( .NOT.wntsne ) )
     $            maxwrk = max( maxwrk, n*n + 6*n )
               maxwrk = max( maxwrk, 3*n )
            END IF
            maxwrk = max( maxwrk, minwrk )
         END IF
         work( 1 ) = sroundup_lwork(maxwrk)
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -21
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGEEVX', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Get machine constants
*
      eps = slamch( 'P' )
      smlnum = slamch( 'S' )
      bignum = one / smlnum
      smlnum = sqrt( smlnum ) / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      icond = 0
      anrm = slange( 'M', n, n, a, lda, dum )
      scalea = .false.
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
         scalea = .true.
         cscale = smlnum
      ELSE IF( anrm.GT.bignum ) THEN
         scalea = .true.
         cscale = bignum
      END IF
      IF( scalea )
     $   CALL slascl( 'G', 0, 0, anrm, cscale, n, n, a, lda, ierr )
*
*     Balance the matrix and compute ABNRM
*
      CALL sgebal( balanc, n, a, lda, ilo, ihi, scale, ierr )
      abnrm = slange( '1', n, n, a, lda, dum )
      IF( scalea ) THEN
         dum( 1 ) = abnrm
         CALL slascl( 'G', 0, 0, cscale, anrm, 1, 1, dum, 1, ierr )
         abnrm = dum( 1 )
      END IF
*
*     Reduce to upper Hessenberg form
*     (Workspace: need 2*N, prefer N+N*NB)
*
      itau = 1
      iwrk = itau + n
      CALL sgehrd( n, ilo, ihi, a, lda, work( itau ), work( iwrk ),
     $             lwork-iwrk+1, ierr )
*
      IF( wantvl ) THEN
*
*        Want left eigenvectors
*        Copy Householder vectors to VL
*
         side = 'L'
         CALL slacpy( 'L', n, n, a, lda, vl, ldvl )
*
*        Generate orthogonal matrix in VL
*        (Workspace: need 2*N-1, prefer N+(N-1)*NB)
*
         CALL sorghr( n, ilo, ihi, vl, ldvl, work( itau ),
     $                work( iwrk ),
     $                lwork-iwrk+1, ierr )
*
*        Perform QR iteration, accumulating Schur vectors in VL
*        (Workspace: need 1, prefer HSWORK (see comments) )
*
         iwrk = itau
         CALL shseqr( 'S', 'V', n, ilo, ihi, a, lda, wr, wi, vl,
     $                ldvl,
     $                work( iwrk ), lwork-iwrk+1, info )
*
         IF( wantvr ) THEN
*
*           Want left and right eigenvectors
*           Copy Schur vectors to VR
*
            side = 'B'
            CALL slacpy( 'F', n, n, vl, ldvl, vr, ldvr )
         END IF
*
      ELSE IF( wantvr ) THEN
*
*        Want right eigenvectors
*        Copy Householder vectors to VR
*
         side = 'R'
         CALL slacpy( 'L', n, n, a, lda, vr, ldvr )
*
*        Generate orthogonal matrix in VR
*        (Workspace: need 2*N-1, prefer N+(N-1)*NB)
*
         CALL sorghr( n, ilo, ihi, vr, ldvr, work( itau ),
     $                work( iwrk ),
     $                lwork-iwrk+1, ierr )
*
*        Perform QR iteration, accumulating Schur vectors in VR
*        (Workspace: need 1, prefer HSWORK (see comments) )
*
         iwrk = itau
         CALL shseqr( 'S', 'V', n, ilo, ihi, a, lda, wr, wi, vr,
     $                ldvr,
     $                work( iwrk ), lwork-iwrk+1, info )
*
      ELSE
*
*        Compute eigenvalues only
*        If condition numbers desired, compute Schur form
*
         IF( wntsnn ) THEN
            job = 'E'
         ELSE
            job = 'S'
         END IF
*
*        (Workspace: need 1, prefer HSWORK (see comments) )
*
         iwrk = itau
         CALL shseqr( job, 'N', n, ilo, ihi, a, lda, wr, wi, vr,
     $                ldvr,
     $                work( iwrk ), lwork-iwrk+1, info )
      END IF
*
*     If INFO .NE. 0 from SHSEQR, then quit
*
      IF( info.NE.0 )
     $   GO TO 50
*
      IF( wantvl .OR. wantvr ) THEN
*
*        Compute left and/or right eigenvectors
*        (Workspace: need 3*N, prefer N + 2*N*NB)
*
         CALL strevc3( side, 'B', SELECT, n, a, lda, vl, ldvl, vr,
     $                 ldvr,
     $                 n, nout, work( iwrk ), lwork-iwrk+1, ierr )
      END IF
*
*     Compute condition numbers if desired
*     (Workspace: need N*N+6*N unless SENSE = 'E')
*
      IF( .NOT.wntsnn ) THEN
         CALL strsna( sense, 'A', SELECT, n, a, lda, vl, ldvl, vr,
     $                ldvr,
     $                rconde, rcondv, n, nout, work( iwrk ), n, iwork,
     $                icond )
      END IF
*
      IF( wantvl ) THEN
*
*        Undo balancing of left eigenvectors
*
         CALL sgebak( balanc, 'L', n, ilo, ihi, scale, n, vl, ldvl,
     $                ierr )
*
*        Normalize left eigenvectors and make largest component real
*
         DO 20 i = 1, n
            IF( wi( i ).EQ.zero ) THEN
               scl = one / snrm2( n, vl( 1, i ), 1 )
               CALL sscal( n, scl, vl( 1, i ), 1 )
            ELSE IF( wi( i ).GT.zero ) THEN
               scl = one / slapy2( snrm2( n, vl( 1, i ), 1 ),
     $               snrm2( n, vl( 1, i+1 ), 1 ) )
               CALL sscal( n, scl, vl( 1, i ), 1 )
               CALL sscal( n, scl, vl( 1, i+1 ), 1 )
               DO 10 k = 1, n
                  work( k ) = vl( k, i )**2 + vl( k, i+1 )**2
   10          CONTINUE
               k = isamax( n, work, 1 )
               CALL slartg( vl( k, i ), vl( k, i+1 ), cs, sn, r )
               CALL srot( n, vl( 1, i ), 1, vl( 1, i+1 ), 1, cs, sn )
               vl( k, i+1 ) = zero
            END IF
   20    CONTINUE
      END IF
*
      IF( wantvr ) THEN
*
*        Undo balancing of right eigenvectors
*
         CALL sgebak( balanc, 'R', n, ilo, ihi, scale, n, vr, ldvr,
     $                ierr )
*
*        Normalize right eigenvectors and make largest component real
*
         DO 40 i = 1, n
            IF( wi( i ).EQ.zero ) THEN
               scl = one / snrm2( n, vr( 1, i ), 1 )
               CALL sscal( n, scl, vr( 1, i ), 1 )
            ELSE IF( wi( i ).GT.zero ) THEN
               scl = one / slapy2( snrm2( n, vr( 1, i ), 1 ),
     $               snrm2( n, vr( 1, i+1 ), 1 ) )
               CALL sscal( n, scl, vr( 1, i ), 1 )
               CALL sscal( n, scl, vr( 1, i+1 ), 1 )
               DO 30 k = 1, n
                  work( k ) = vr( k, i )**2 + vr( k, i+1 )**2
   30          CONTINUE
               k = isamax( n, work, 1 )
               CALL slartg( vr( k, i ), vr( k, i+1 ), cs, sn, r )
               CALL srot( n, vr( 1, i ), 1, vr( 1, i+1 ), 1, cs, sn )
               vr( k, i+1 ) = zero
            END IF
   40    CONTINUE
      END IF
*
*     Undo scaling if necessary
*
   50 CONTINUE
      IF( scalea ) THEN
         CALL slascl( 'G', 0, 0, cscale, anrm, n-info, 1,
     $                wr( info+1 ),
     $                max( n-info, 1 ), ierr )
         CALL slascl( 'G', 0, 0, cscale, anrm, n-info, 1,
     $                wi( info+1 ),
     $                max( n-info, 1 ), ierr )
         IF( info.EQ.0 ) THEN
            IF( ( wntsnv .OR. wntsnb ) .AND. icond.EQ.0 )
     $         CALL slascl( 'G', 0, 0, cscale, anrm, n, 1, rcondv, n,
     $                      ierr )
         ELSE
            CALL slascl( 'G', 0, 0, cscale, anrm, ilo-1, 1, wr, n,
     $                   ierr )
            CALL slascl( 'G', 0, 0, cscale, anrm, ilo-1, 1, wi, n,
     $                   ierr )
         END IF
      END IF
*
      work( 1 ) = sroundup_lwork(maxwrk)
      RETURN
*
*     End of SGEEVX
*

Here is the call graph for this function:

Here is the caller graph for this function: