dpot03()

subroutine dpot03	(	character	uplo,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldainv, * )	ainv,
		integer	ldainv,
		double precision, dimension( ldwork, * )	work,
		integer	ldwork,
		double precision, dimension( * )	rwork,
		double precision	rcond,
		double precision	resid
	)

DPOT03

Purpose:

 DPOT03 computes the residual for a symmetric matrix times its
 inverse:
    norm( I - A*AINV ) / ( N * norm(A) * norm(AINV) * EPS ),
 where EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The original symmetric matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N)
[in,out]	AINV	AINV is DOUBLE PRECISION array, dimension (LDAINV,N) On entry, the inverse of the matrix A, stored as a symmetric matrix in the same format as A. In this version, AINV is expanded into a full matrix and multiplied by A, so the opposing triangle of AINV will be changed; i.e., if the upper triangular part of AINV is stored, the lower triangular part will be used as work space.
[in]	LDAINV	LDAINV is INTEGER The leading dimension of the array AINV. LDAINV >= max(1,N).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LDWORK,N)
[in]	LDWORK	LDWORK is INTEGER The leading dimension of the array WORK. LDWORK >= max(1,N).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RCOND	RCOND is DOUBLE PRECISION The reciprocal of the condition number of A, computed as ( 1/norm(A) ) / norm(AINV).
[out]	RESID	RESID is DOUBLE PRECISION norm(I - A*AINV) / ( N * norm(A) * norm(AINV) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 123 of file dpot03.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDA, LDAINV, LDWORK, N
      DOUBLE PRECISION   RCOND, RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AINV( LDAINV, * ), RWORK( * ),
     $                   WORK( LDWORK, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   AINVNM, ANORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, DLANGE, DLANSY
      EXTERNAL           lsame, dlamch, dlange, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dsymm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = dlansy( '1', uplo, n, a, lda, rwork )
      ainvnm = dlansy( '1', uplo, n, ainv, ldainv, rwork )
      IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
         rcond = zero
         resid = one / eps
         RETURN
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     Expand AINV into a full matrix and call DSYMM to multiply
*     AINV on the left by A.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 20 j = 1, n
            DO 10 i = 1, j - 1
               ainv( j, i ) = ainv( i, j )
   10       CONTINUE
   20    CONTINUE
      ELSE
         DO 40 j = 1, n
            DO 30 i = j + 1, n
               ainv( j, i ) = ainv( i, j )
   30       CONTINUE
   40    CONTINUE
      END IF
      CALL dsymm( 'Left', uplo, n, n, -one, a, lda, ainv, ldainv, zero,
     $            work, ldwork )
*
*     Add the identity matrix to WORK .
*
      DO 50 i = 1, n
         work( i, i ) = work( i, i ) + one
   50 CONTINUE
*
*     Compute norm(I - A*AINV) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = dlange( '1', n, n, work, ldwork, rwork )
*
      resid = ( ( resid*rcond ) / eps ) / dble( n )
*
      RETURN
*
*     End of DPOT03
*

Here is the call graph for this function:

Here is the caller graph for this function: