ddrvge.f

Go to the documentation of this file.

*> \brief \b DDRVGE
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE DDRVGE( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, NMAX,
*                          A, AFAC, ASAV, B, BSAV, X, XACT, S, WORK,
*                          RWORK, IWORK, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NOUT, NRHS
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), NVAL( * )
*       DOUBLE PRECISION   A( * ), AFAC( * ), ASAV( * ), B( * ),
*      $                   BSAV( * ), RWORK( * ), S( * ), WORK( * ),
*      $                   X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DDRVGE tests the driver routines DGESV and -SVX.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand side vectors to be generated for
*>          each linear system.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for N, used in dimensioning the
*>          work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AFAC
*> \verbatim
*>          AFAC is DOUBLE PRECISION array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] ASAV
*> \verbatim
*>          ASAV is DOUBLE PRECISION array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] BSAV
*> \verbatim
*>          BSAV is DOUBLE PRECISION array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is DOUBLE PRECISION array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is DOUBLE PRECISION array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is DOUBLE PRECISION array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension
*>                      (NMAX*max(3,NRHS))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (2*NRHS+NMAX)
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE ddrvge( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, NMAX,
     $                   A, AFAC, ASAV, B, BSAV, X, XACT, S, WORK,
     $                   RWORK, IWORK, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NOUT, NRHS
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NVAL( * )
      DOUBLE PRECISION   A( * ), AFAC( * ), ASAV( * ), B( * ),
     $                   bsav( * ), rwork( * ), s( * ), work( * ),
     $                   x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      PARAMETER          ( ONE = 1.0d+0, zero = 0.0d+0 )
      INTEGER            NTYPES
      parameter( ntypes = 11 )
      INTEGER            NTESTS
      parameter( ntests = 7 )
      INTEGER            NTRAN
      parameter( ntran = 3 )
*     ..
*     .. Local Scalars ..
      LOGICAL            EQUIL, NOFACT, PREFAC, TRFCON, ZEROT
      CHARACTER          DIST, EQUED, FACT, TRANS, TYPE, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IEQUED, IFACT, IMAT, IN, INFO, IOFF, ITRAN,
     $                   izero, k, k1, kl, ku, lda, lwork, mode, n, nb,
     $                   nbmin, nerrs, nfact, nfail, nimat, nrun, nt
      DOUBLE PRECISION   AINVNM, AMAX, ANORM, ANORMI, ANORMO, CNDNUM,
     $                   COLCND, RCOND, RCONDC, RCONDI, RCONDO, ROLDC,
     $                   roldi, roldo, rowcnd, rpvgrw
*     ..
*     .. Local Arrays ..
      CHARACTER          EQUEDS( 4 ), FACTS( 3 ), TRANSS( NTRAN )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DGET06, DLAMCH, DLANGE, DLANTR
      EXTERNAL           lsame, dget06, dlamch, dlange, dlantr
*     ..
*     .. External Subroutines ..
      EXTERNAL           aladhd, alaerh, alasvm, derrvx, dgeequ, dgesv,
     $                   dgesvx, dget01, dget02, dget04, dget07, dgetrf,
     $                   dgetri, dlacpy, dlaqge, dlarhs, dlaset, dlatb4,
     $                   dlatms, xlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               transs / 'N', 'T', 'C' /
      DATA               facts / 'F', 'N', 'E' /
      DATA               equeds / 'N', 'R', 'C', 'B' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Double precision'
      path( 2: 3 ) = 'GE'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL derrvx( path, nout )
      infot = 0
*
*     Set the block size and minimum block size for testing.
*
      nb = 1
      nbmin = 2
      CALL xlaenv( 1, nb )
      CALL xlaenv( 2, nbmin )
*
*     Do for each value of N in NVAL
*
      DO 90 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 80 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 80
*
*           Skip types 5, 6, or 7 if the matrix size is too small.
*
            zerot = imat.GE.5 .AND. imat.LE.7
            IF( zerot .AND. n.LT.imat-4 )
     $         GO TO 80
*
*           Set up parameters with DLATB4 and generate a test matrix
*           with DLATMS.
*
            CALL dlatb4( path, imat, n, n, TYPE, kl, ku, anorm, mode,
     $                   cndnum, dist )
            rcondc = one / cndnum
*
            srnamt = 'DLATMS'
            CALL dlatms( n, n, dist, iseed, TYPE, rwork, mode, cndnum,
     $                   anorm, kl, ku, 'No packing', a, lda, work,
     $                   info )
*
*           Check error code from DLATMS.
*
            IF( info.NE.0 ) THEN
               CALL alaerh( path, 'DLATMS', info, 0, ' ', n, n, -1, -1,
     $                      -1, imat, nfail, nerrs, nout )
               GO TO 80
            END IF
*
*           For types 5-7, zero one or more columns of the matrix to
*           test that INFO is returned correctly.
*
            IF( zerot ) THEN
               IF( imat.EQ.5 ) THEN
                  izero = 1
               ELSE IF( imat.EQ.6 ) THEN
                  izero = n
               ELSE
                  izero = n / 2 + 1
               END IF
               ioff = ( izero-1 )*lda
               IF( imat.LT.7 ) THEN
                  DO 20 i = 1, n
                     a( ioff+i ) = zero
   20             CONTINUE
               ELSE
                  CALL dlaset( 'Full', n, n-izero+1, zero, zero,
     $                         a( ioff+1 ), lda )
               END IF
            ELSE
               izero = 0
            END IF
*
*           Save a copy of the matrix A in ASAV.
*
            CALL dlacpy( 'Full', n, n, a, lda, asav, lda )
*
            DO 70 iequed = 1, 4
               equed = equeds( iequed )
               IF( iequed.EQ.1 ) THEN
                  nfact = 3
               ELSE
                  nfact = 1
               END IF
*
               DO 60 ifact = 1, nfact
                  fact = facts( ifact )
                  prefac = lsame( fact, 'F' )
                  nofact = lsame( fact, 'N' )
                  equil = lsame( fact, 'E' )
*
                  IF( zerot ) THEN
                     IF( prefac )
     $                  GO TO 60
                     rcondo = zero
                     rcondi = zero
*
                  ELSE IF( .NOT.nofact ) THEN
*
*                    Compute the condition number for comparison with
*                    the value returned by DGESVX (FACT = 'N' reuses
*                    the condition number from the previous iteration
*                    with FACT = 'F').
*
                     CALL dlacpy( 'Full', n, n, asav, lda, afac, lda )
                     IF( equil .OR. iequed.GT.1 ) THEN
*
*                       Compute row and column scale factors to
*                       equilibrate the matrix A.
*
                        CALL dgeequ( n, n, afac, lda, s, s( n+1 ),
     $                               rowcnd, colcnd, amax, info )
                        IF( info.EQ.0 .AND. n.GT.0 ) THEN
                           IF( lsame( equed, 'R' ) ) THEN
                              rowcnd = zero
                              colcnd = one
                           ELSE IF( lsame( equed, 'C' ) ) THEN
                              rowcnd = one
                              colcnd = zero
                           ELSE IF( lsame( equed, 'B' ) ) THEN
                              rowcnd = zero
                              colcnd = zero
                           END IF
*
*                          Equilibrate the matrix.
*
                           CALL dlaqge( n, n, afac, lda, s, s( n+1 ),
     $                                  rowcnd, colcnd, amax, equed )
                        END IF
                     END IF
*
*                    Save the condition number of the non-equilibrated
*                    system for use in DGET04.
*
                     IF( equil ) THEN
                        roldo = rcondo
                        roldi = rcondi
                     END IF
*
*                    Compute the 1-norm and infinity-norm of A.
*
                     anormo = dlange( '1', n, n, afac, lda, rwork )
                     anormi = dlange( 'I', n, n, afac, lda, rwork )
*
*                    Factor the matrix A.
*
                     srnamt = 'DGETRF'
                     CALL dgetrf( n, n, afac, lda, iwork, info )
*
*                    Form the inverse of A.
*
                     CALL dlacpy( 'Full', n, n, afac, lda, a, lda )
                     lwork = nmax*max( 3, nrhs )
                     srnamt = 'DGETRI'
                     CALL dgetri( n, a, lda, iwork, work, lwork, info )
*
*                    Compute the 1-norm condition number of A.
*
                     ainvnm = dlange( '1', n, n, a, lda, rwork )
                     IF( anormo.LE.zero .OR. ainvnm.LE.zero ) THEN
                        rcondo = one
                     ELSE
                        rcondo = ( one / anormo ) / ainvnm
                     END IF
*
*                    Compute the infinity-norm condition number of A.
*
                     ainvnm = dlange( 'I', n, n, a, lda, rwork )
                     IF( anormi.LE.zero .OR. ainvnm.LE.zero ) THEN
                        rcondi = one
                     ELSE
                        rcondi = ( one / anormi ) / ainvnm
                     END IF
                  END IF
*
                  DO 50 itran = 1, ntran
*
*                    Do for each value of TRANS.
*
                     trans = transs( itran )
                     IF( itran.EQ.1 ) THEN
                        rcondc = rcondo
                     ELSE
                        rcondc = rcondi
                     END IF
*
*                    Restore the matrix A.
*
                     CALL dlacpy( 'Full', n, n, asav, lda, a, lda )
*
*                    Form an exact solution and set the right hand side.
*
                     srnamt = 'DLARHS'
                     CALL dlarhs( path, xtype, 'Full', trans, n, n, kl,
     $                            ku, nrhs, a, lda, xact, lda, b, lda,
     $                            iseed, info )
                     xtype = 'C'
                     CALL dlacpy( 'Full', n, nrhs, b, lda, bsav, lda )
*
                     IF( nofact .AND. itran.EQ.1 ) THEN
*
*                       --- Test DGESV  ---
*
*                       Compute the LU factorization of the matrix and
*                       solve the system.
*
                        CALL dlacpy( 'Full', n, n, a, lda, afac, lda )
                        CALL dlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                        srnamt = 'DGESV '
                        CALL dgesv( n, nrhs, afac, lda, iwork, x, lda,
     $                              info )
*
*                       Check error code from DGESV .
*
                        IF( info.NE.izero )
     $                     CALL alaerh( path, 'DGESV ', info, izero,
     $                                  ' ', n, n, -1, -1, nrhs, imat,
     $                                  nfail, nerrs, nout )
*
*                       Reconstruct matrix from factors and compute
*                       residual.
*
                        CALL dget01( n, n, a, lda, afac, lda, iwork,
     $                               rwork, result( 1 ) )
                        nt = 1
                        IF( izero.EQ.0 ) THEN
*
*                          Compute residual of the computed solution.
*
                           CALL dlacpy( 'Full', n, nrhs, b, lda, work,
     $                                  lda )
                           CALL dget02( 'No transpose', n, n, nrhs, a,
     $                                  lda, x, lda, work, lda, rwork,
     $                                  result( 2 ) )
*
*                          Check solution from generated exact solution.
*
                           CALL dget04( n, nrhs, x, lda, xact, lda,
     $                                  rcondc, result( 3 ) )
                           nt = 3
                        END IF
*
*                       Print information about the tests that did not
*                       pass the threshold.
*
                        DO 30 k = 1, nt
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL aladhd( nout, path )
                              WRITE( nout, fmt = 9999 )'DGESV ', n,
     $                           imat, k, result( k )
                              nfail = nfail + 1
                           END IF
   30                   CONTINUE
                        nrun = nrun + nt
                     END IF
*
*                    --- Test DGESVX ---
*
                     IF( .NOT.prefac )
     $                  CALL dlaset( 'Full', n, n, zero, zero, afac,
     $                               lda )
                     CALL dlaset( 'Full', n, nrhs, zero, zero, x, lda )
                     IF( iequed.GT.1 .AND. n.GT.0 ) THEN
*
*                       Equilibrate the matrix if FACT = 'F' and
*                       EQUED = 'R', 'C', or 'B'.
*
                        CALL dlaqge( n, n, a, lda, s, s( n+1 ), rowcnd,
     $                               colcnd, amax, equed )
                     END IF
*
*                    Solve the system and compute the condition number
*                    and error bounds using DGESVX.
*
                     srnamt = 'DGESVX'
                     CALL dgesvx( fact, trans, n, nrhs, a, lda, afac,
     $                            lda, iwork, equed, s, s( n+1 ), b,
     $                            lda, x, lda, rcond, rwork,
     $                            rwork( nrhs+1 ), work, iwork( n+1 ),
     $                            info )
*
*                    Check the error code from DGESVX.
*
                     IF( info.NE.izero )
     $                  CALL alaerh( path, 'DGESVX', info, izero,
     $                               fact // trans, n, n, -1, -1, nrhs,
     $                               imat, nfail, nerrs, nout )
*
*                    Compare WORK(1) from DGESVX with the computed
*                    reciprocal pivot growth factor RPVGRW
*
                     IF( info.NE.0 .AND. info.LE.n) THEN
                        rpvgrw = dlantr( 'M', 'U', 'N', info, info,
     $                           afac, lda, work )
                        IF( rpvgrw.EQ.zero ) THEN
                           rpvgrw = one
                        ELSE
                           rpvgrw = dlange( 'M', n, info, a, lda,
     $                              work ) / rpvgrw
                        END IF
                     ELSE
                        rpvgrw = dlantr( 'M', 'U', 'N', n, n, afac, lda,
     $                           work )
                        IF( rpvgrw.EQ.zero ) THEN
                           rpvgrw = one
                        ELSE
                           rpvgrw = dlange( 'M', n, n, a, lda, work ) /
     $                              rpvgrw
                        END IF
                     END IF
                     result( 7 ) = abs( rpvgrw-work( 1 ) ) /
     $                             max( work( 1 ), rpvgrw ) /
     $                             dlamch( 'E' )
*
                     IF( .NOT.prefac ) THEN
*
*                       Reconstruct matrix from factors and compute
*                       residual.
*
                        CALL dget01( n, n, a, lda, afac, lda, iwork,
     $                               rwork( 2*nrhs+1 ), result( 1 ) )
                        k1 = 1
                     ELSE
                        k1 = 2
                     END IF
*
                     IF( info.EQ.0 ) THEN
                        trfcon = .false.
*
*                       Compute residual of the computed solution.
*
                        CALL dlacpy( 'Full', n, nrhs, bsav, lda, work,
     $                               lda )
                        CALL dget02( trans, n, n, nrhs, asav, lda, x,
     $                               lda, work, lda, rwork( 2*nrhs+1 ),
     $                               result( 2 ) )
*
*                       Check solution from generated exact solution.
*
                        IF( nofact .OR. ( prefac .AND. lsame( equed,
     $                      'N' ) ) ) THEN
                           CALL dget04( n, nrhs, x, lda, xact, lda,
     $                                  rcondc, result( 3 ) )
                        ELSE
                           IF( itran.EQ.1 ) THEN
                              roldc = roldo
                           ELSE
                              roldc = roldi
                           END IF
                           CALL dget04( n, nrhs, x, lda, xact, lda,
     $                                  roldc, result( 3 ) )
                        END IF
*
*                       Check the error bounds from iterative
*                       refinement.
*
                        CALL dget07( trans, n, nrhs, asav, lda, b, lda,
     $                               x, lda, xact, lda, rwork, .true.,
     $                               rwork( nrhs+1 ), result( 4 ) )
                     ELSE
                        trfcon = .true.
                     END IF
*
*                    Compare RCOND from DGESVX with the computed value
*                    in RCONDC.
*
                     result( 6 ) = dget06( rcond, rcondc )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     IF( .NOT.trfcon ) THEN
                        DO 40 k = k1, ntests
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL aladhd( nout, path )
                              IF( prefac ) THEN
                                 WRITE( nout, fmt = 9997 )'DGESVX',
     $                              fact, trans, n, equed, imat, k,
     $                              result( k )
                              ELSE
                                 WRITE( nout, fmt = 9998 )'DGESVX',
     $                              fact, trans, n, imat, k, result( k )
                              END IF
                              nfail = nfail + 1
                           END IF
   40                   CONTINUE
                        nrun = nrun + ntests - k1 + 1
                     ELSE
                        IF( result( 1 ).GE.thresh .AND. .NOT.prefac )
     $                       THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL aladhd( nout, path )
                           IF( prefac ) THEN
                              WRITE( nout, fmt = 9997 )'DGESVX', fact,
     $                           trans, n, equed, imat, 1, result( 1 )
                           ELSE
                              WRITE( nout, fmt = 9998 )'DGESVX', fact,
     $                           trans, n, imat, 1, result( 1 )
                           END IF
                           nfail = nfail + 1
                           nrun = nrun + 1
                        END IF
                        IF( result( 6 ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL aladhd( nout, path )
                           IF( prefac ) THEN
                              WRITE( nout, fmt = 9997 )'DGESVX', fact,
     $                           trans, n, equed, imat, 6, result( 6 )
                           ELSE
                              WRITE( nout, fmt = 9998 )'DGESVX', fact,
     $                           trans, n, imat, 6, result( 6 )
                           END IF
                           nfail = nfail + 1
                           nrun = nrun + 1
                        END IF
                        IF( result( 7 ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL aladhd( nout, path )
                           IF( prefac ) THEN
                              WRITE( nout, fmt = 9997 )'DGESVX', fact,
     $                           trans, n, equed, imat, 7, result( 7 )
                           ELSE
                              WRITE( nout, fmt = 9998 )'DGESVX', fact,
     $                           trans, n, imat, 7, result( 7 )
                           END IF
                           nfail = nfail + 1
                           nrun = nrun + 1
                        END IF
*
                     END IF
*
   50             CONTINUE
   60          CONTINUE
   70       CONTINUE
   80    CONTINUE
   90 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasvm( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 1x, a, ', N =', i5, ', type ', i2, ', test(', i2, ') =',
     $      g12.5 )
 9998 FORMAT( 1x, a, ', FACT=''', a1, ''', TRANS=''', a1, ''', N=', i5,
     $      ', type ', i2, ', test(', i1, ')=', g12.5 )
 9997 FORMAT( 1x, a, ', FACT=''', a1, ''', TRANS=''', a1, ''', N=', i5,
     $      ', EQUED=''', a1, ''', type ', i2, ', test(', i1, ')=',
     $      g12.5 )
      RETURN
*
*     End of DDRVGE
*
      END