zlqt01.f

Go to the documentation of this file.

*> \brief \b ZLQT01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZLQT01( M, N, A, AF, Q, L, LDA, TAU, WORK, LWORK,
*                          RWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   RESULT( * ), RWORK( * )
*       COMPLEX*16         A( LDA, * ), AF( LDA, * ), L( LDA, * ),
*      $                   Q( LDA, * ), TAU( * ), WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZLQT01 tests ZGELQF, which computes the LQ factorization of an m-by-n
*> matrix A, and partially tests ZUNGLQ which forms the n-by-n
*> orthogonal matrix Q.
*>
*> ZLQT01 compares L with A*Q', and checks that Q is orthogonal.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          The m-by-n matrix A.
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is COMPLEX*16 array, dimension (LDA,N)
*>          Details of the LQ factorization of A, as returned by ZGELQF.
*>          See ZGELQF for further details.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is COMPLEX*16 array, dimension (LDA,N)
*>          The n-by-n orthogonal matrix Q.
*> \endverbatim
*>
*> \param[out] L
*> \verbatim
*>          L is COMPLEX*16 array, dimension (LDA,max(M,N))
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays A, AF, Q and L.
*>          LDA >= max(M,N).
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is COMPLEX*16 array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by ZGELQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (max(M,N))
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (2)
*>          The test ratios:
*>          RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS )
*>          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zlqt01( M, N, A, AF, Q, L, LDA, TAU, WORK, LWORK,
     $                   rwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RESULT( * ), RWORK( * )
      COMPLEX*16         A( lda, * ), AF( lda, * ), L( lda, * ),
     $                   q( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         ROGUE
      parameter                ( rogue = ( -1.0d+10, -1.0d+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      DOUBLE PRECISION   ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE, ZLANSY
      EXTERNAL           dlamch, zlange, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgelqf, zgemm, zherk, zlacpy, zlaset, zunglq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max, min
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = dlamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL zlacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'ZGELQF'
      CALL zgelqf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL zlaset( 'Full', n, n, rogue, rogue, q, lda )
      IF( n.GT.1 )
     $   CALL zlacpy( 'Upper', m, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'ZUNGLQ'
      CALL zunglq( n, n, minmn, q, lda, tau, work, lwork, info )
*
*     Copy L
*
      CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( zero ), l,
     $             lda )
      CALL zlacpy( 'Lower', m, n, af, lda, l, lda )
*
*     Compute L - A*Q'
*
      CALL zgemm( 'No transpose', 'Conjugate transpose', m, n, n,
     $            dcmplx( -one ), a, lda, q, lda, dcmplx( one ), l,
     $            lda )
*
*     Compute norm( L - Q'*A ) / ( N * norm(A) * EPS ) .
*
      anorm = zlange( '1', m, n, a, lda, rwork )
      resid = zlange( '1', m, n, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL zlaset( 'Full', n, n, dcmplx( zero ), dcmplx( one ), l, lda )
      CALL zherk( 'Upper', 'No transpose', n, n, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = zlansy( '1', 'Upper', n, l, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of ZLQT01
*
      END