real function sqrt12	(	integer	M,
		integer	N,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( * )	S,
		real, dimension( lwork )	WORK,
		integer	LWORK
	)

SQRT12

Purpose:

 SQRT12 computes the singular values `svlues' of the upper trapezoid
 of A(1:M,1:N) and returns the ratio

      || s - svlues||/(||svlues||*eps*max(M,N))

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A.
[in]	N	N is INTEGER The number of columns of the matrix A.
[in]	A	A is REAL array, dimension (LDA,N) The M-by-N matrix A. Only the upper trapezoid is referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[in]	S	S is REAL array, dimension (min(M,N)) The singular values of the matrix A.
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= max(M*N + 4*min(M,N) + max(M,N), M*N+2*MIN( M, N )+4*N).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 91 of file sqrt12.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), s( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, iscl, j, mn
      REAL               anrm, bignum, nrmsvl, smlnum
*     ..
*     .. External Functions ..
      REAL               sasum, slamch, slange, snrm2
      EXTERNAL           sasum, slamch, slange, snrm2
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, sbdsqr, sgebd2, slabad, slascl, slaset,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Local Arrays ..
      REAL               dummy( 1 )
*     ..
*     .. Executable Statements ..
*
      sqrt12 = zero
*
*     Test that enough workspace is supplied
*
      IF( lwork.LT.max( m*n+4*min( m, n )+max( m, n ),
     $                  m*n+2*min( m, n )+4*n) ) THEN
         CALL xerbla( 'SQRT12', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      mn = min( m, n )
      IF( mn.LE.zero )
     $   RETURN
*
      nrmsvl = snrm2( mn, s, 1 )
*
*     Copy upper triangle of A into work
*
      CALL slaset( 'Full', m, n, zero, zero, work, m )
      DO 20 j = 1, n
         DO 10 i = 1, min( j, m )
            work( ( j-1 )*m+i ) = a( i, j )
   10    CONTINUE
   20 CONTINUE
*
*     Get machine parameters
*
      smlnum = slamch( 'S' ) / slamch( 'P' )
      bignum = one / smlnum
      CALL slabad( smlnum, bignum )
*
*     Scale work if max entry outside range [SMLNUM,BIGNUM]
*
      anrm = slange( 'M', m, n, work, m, dummy )
      iscl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL slascl( 'G', 0, 0, anrm, smlnum, m, n, work, m, info )
         iscl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL slascl( 'G', 0, 0, anrm, bignum, m, n, work, m, info )
         iscl = 1
      END IF
*
      IF( anrm.NE.zero ) THEN
*
*        Compute SVD of work
*
         CALL sgebd2( m, n, work, m, work( m*n+1 ), work( m*n+mn+1 ),
     $                work( m*n+2*mn+1 ), work( m*n+3*mn+1 ),
     $                work( m*n+4*mn+1 ), info )
         CALL sbdsqr( 'Upper', mn, 0, 0, 0, work( m*n+1 ),
     $                work( m*n+mn+1 ), dummy, mn, dummy, 1, dummy, mn,
     $                work( m*n+2*mn+1 ), info )
*
         IF( iscl.EQ.1 ) THEN
            IF( anrm.GT.bignum ) THEN
               CALL slascl( 'G', 0, 0, bignum, anrm, mn, 1,
     $                      work( m*n+1 ), mn, info )
            END IF
            IF( anrm.LT.smlnum ) THEN
               CALL slascl( 'G', 0, 0, smlnum, anrm, mn, 1,
     $                      work( m*n+1 ), mn, info )
            END IF
         END IF
*
      ELSE
*
         DO 30 i = 1, mn
            work( m*n+i ) = zero
   30    CONTINUE
      END IF
*
*     Compare s and singular values of work
*
      CALL saxpy( mn, -one, s, 1, work( m*n+1 ), 1 )
      sqrt12 = sasum( mn, work( m*n+1 ), 1 ) /
     $         ( slamch( 'Epsilon' )*REAL( MAX( M, N ) ) )
      IF( nrmsvl.NE.zero )
     $   sqrt12 = sqrt12 / nrmsvl
*
      RETURN
*
*     End of SQRT12
*

Here is the call graph for this function: