LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
sgebd2.f
Go to the documentation of this file.
1 *> \brief \b SGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SGEBD2 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgebd2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgebd2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgebd2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SGEBD2( M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * INTEGER INFO, LDA, M, N
25 * ..
26 * .. Array Arguments ..
27 * REAL A( LDA, * ), D( * ), E( * ), TAUP( * ),
28 * $ TAUQ( * ), WORK( * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> SGEBD2 reduces a real general m by n matrix A to upper or lower
38 *> bidiagonal form B by an orthogonal transformation: Q**T * A * P = B.
39 *>
40 *> If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
41 *> \endverbatim
42 *
43 * Arguments:
44 * ==========
45 *
46 *> \param[in] M
47 *> \verbatim
48 *> M is INTEGER
49 *> The number of rows in the matrix A. M >= 0.
50 *> \endverbatim
51 *>
52 *> \param[in] N
53 *> \verbatim
54 *> N is INTEGER
55 *> The number of columns in the matrix A. N >= 0.
56 *> \endverbatim
57 *>
58 *> \param[in,out] A
59 *> \verbatim
60 *> A is REAL array, dimension (LDA,N)
61 *> On entry, the m by n general matrix to be reduced.
62 *> On exit,
63 *> if m >= n, the diagonal and the first superdiagonal are
64 *> overwritten with the upper bidiagonal matrix B; the
65 *> elements below the diagonal, with the array TAUQ, represent
66 *> the orthogonal matrix Q as a product of elementary
67 *> reflectors, and the elements above the first superdiagonal,
68 *> with the array TAUP, represent the orthogonal matrix P as
69 *> a product of elementary reflectors;
70 *> if m < n, the diagonal and the first subdiagonal are
71 *> overwritten with the lower bidiagonal matrix B; the
72 *> elements below the first subdiagonal, with the array TAUQ,
73 *> represent the orthogonal matrix Q as a product of
74 *> elementary reflectors, and the elements above the diagonal,
75 *> with the array TAUP, represent the orthogonal matrix P as
76 *> a product of elementary reflectors.
77 *> See Further Details.
78 *> \endverbatim
79 *>
80 *> \param[in] LDA
81 *> \verbatim
82 *> LDA is INTEGER
83 *> The leading dimension of the array A. LDA >= max(1,M).
84 *> \endverbatim
85 *>
86 *> \param[out] D
87 *> \verbatim
88 *> D is REAL array, dimension (min(M,N))
89 *> The diagonal elements of the bidiagonal matrix B:
90 *> D(i) = A(i,i).
91 *> \endverbatim
92 *>
93 *> \param[out] E
94 *> \verbatim
95 *> E is REAL array, dimension (min(M,N)-1)
96 *> The off-diagonal elements of the bidiagonal matrix B:
97 *> if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
98 *> if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
99 *> \endverbatim
100 *>
101 *> \param[out] TAUQ
102 *> \verbatim
103 *> TAUQ is REAL array dimension (min(M,N))
104 *> The scalar factors of the elementary reflectors which
105 *> represent the orthogonal matrix Q. See Further Details.
106 *> \endverbatim
107 *>
108 *> \param[out] TAUP
109 *> \verbatim
110 *> TAUP is REAL array, dimension (min(M,N))
111 *> The scalar factors of the elementary reflectors which
112 *> represent the orthogonal matrix P. See Further Details.
113 *> \endverbatim
114 *>
115 *> \param[out] WORK
116 *> \verbatim
117 *> WORK is REAL array, dimension (max(M,N))
118 *> \endverbatim
119 *>
120 *> \param[out] INFO
121 *> \verbatim
122 *> INFO is INTEGER
123 *> = 0: successful exit.
124 *> < 0: if INFO = -i, the i-th argument had an illegal value.
125 *> \endverbatim
126 *
127 * Authors:
128 * ========
129 *
130 *> \author Univ. of Tennessee
131 *> \author Univ. of California Berkeley
132 *> \author Univ. of Colorado Denver
133 *> \author NAG Ltd.
134 *
135 *> \date September 2012
136 *
137 *> \ingroup realGEcomputational
138 *
139 *> \par Further Details:
140 * =====================
141 *>
142 *> \verbatim
143 *>
144 *> The matrices Q and P are represented as products of elementary
145 *> reflectors:
146 *>
147 *> If m >= n,
148 *>
149 *> Q = H(1) H(2) . . . H(n) and P = G(1) G(2) . . . G(n-1)
150 *>
151 *> Each H(i) and G(i) has the form:
152 *>
153 *> H(i) = I - tauq * v * v**T and G(i) = I - taup * u * u**T
154 *>
155 *> where tauq and taup are real scalars, and v and u are real vectors;
156 *> v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in A(i+1:m,i);
157 *> u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in A(i,i+2:n);
158 *> tauq is stored in TAUQ(i) and taup in TAUP(i).
159 *>
160 *> If m < n,
161 *>
162 *> Q = H(1) H(2) . . . H(m-1) and P = G(1) G(2) . . . G(m)
163 *>
164 *> Each H(i) and G(i) has the form:
165 *>
166 *> H(i) = I - tauq * v * v**T and G(i) = I - taup * u * u**T
167 *>
168 *> where tauq and taup are real scalars, and v and u are real vectors;
169 *> v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
170 *> u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
171 *> tauq is stored in TAUQ(i) and taup in TAUP(i).
172 *>
173 *> The contents of A on exit are illustrated by the following examples:
174 *>
175 *> m = 6 and n = 5 (m > n): m = 5 and n = 6 (m < n):
176 *>
177 *> ( d e u1 u1 u1 ) ( d u1 u1 u1 u1 u1 )
178 *> ( v1 d e u2 u2 ) ( e d u2 u2 u2 u2 )
179 *> ( v1 v2 d e u3 ) ( v1 e d u3 u3 u3 )
180 *> ( v1 v2 v3 d e ) ( v1 v2 e d u4 u4 )
181 *> ( v1 v2 v3 v4 d ) ( v1 v2 v3 e d u5 )
182 *> ( v1 v2 v3 v4 v5 )
183 *>
184 *> where d and e denote diagonal and off-diagonal elements of B, vi
185 *> denotes an element of the vector defining H(i), and ui an element of
186 *> the vector defining G(i).
187 *> \endverbatim
188 *>
189 * =====================================================================
190  SUBROUTINE sgebd2( M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO )
191 *
192 * -- LAPACK computational routine (version 3.4.2) --
193 * -- LAPACK is a software package provided by Univ. of Tennessee, --
194 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
195 * September 2012
196 *
197 * .. Scalar Arguments ..
198  INTEGER INFO, LDA, M, N
199 * ..
200 * .. Array Arguments ..
201  REAL A( lda, * ), D( * ), E( * ), TAUP( * ),
202  $ tauq( * ), work( * )
203 * ..
204 *
205 * =====================================================================
206 *
207 * .. Parameters ..
208  REAL ZERO, ONE
209  parameter ( zero = 0.0e+0, one = 1.0e+0 )
210 * ..
211 * .. Local Scalars ..
212  INTEGER I
213 * ..
214 * .. External Subroutines ..
215  EXTERNAL slarf, slarfg, xerbla
216 * ..
217 * .. Intrinsic Functions ..
218  INTRINSIC max, min
219 * ..
220 * .. Executable Statements ..
221 *
222 * Test the input parameters
223 *
224  info = 0
225  IF( m.LT.0 ) THEN
226  info = -1
227  ELSE IF( n.LT.0 ) THEN
228  info = -2
229  ELSE IF( lda.LT.max( 1, m ) ) THEN
230  info = -4
231  END IF
232  IF( info.LT.0 ) THEN
233  CALL xerbla( 'SGEBD2', -info )
234  RETURN
235  END IF
236 *
237  IF( m.GE.n ) THEN
238 *
239 * Reduce to upper bidiagonal form
240 *
241  DO 10 i = 1, n
242 *
243 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
244 *
245  CALL slarfg( m-i+1, a( i, i ), a( min( i+1, m ), i ), 1,
246  $ tauq( i ) )
247  d( i ) = a( i, i )
248  a( i, i ) = one
249 *
250 * Apply H(i) to A(i:m,i+1:n) from the left
251 *
252  IF( i.LT.n )
253  $ CALL slarf( 'Left', m-i+1, n-i, a( i, i ), 1, tauq( i ),
254  $ a( i, i+1 ), lda, work )
255  a( i, i ) = d( i )
256 *
257  IF( i.LT.n ) THEN
258 *
259 * Generate elementary reflector G(i) to annihilate
260 * A(i,i+2:n)
261 *
262  CALL slarfg( n-i, a( i, i+1 ), a( i, min( i+2, n ) ),
263  $ lda, taup( i ) )
264  e( i ) = a( i, i+1 )
265  a( i, i+1 ) = one
266 *
267 * Apply G(i) to A(i+1:m,i+1:n) from the right
268 *
269  CALL slarf( 'Right', m-i, n-i, a( i, i+1 ), lda,
270  $ taup( i ), a( i+1, i+1 ), lda, work )
271  a( i, i+1 ) = e( i )
272  ELSE
273  taup( i ) = zero
274  END IF
275  10 CONTINUE
276  ELSE
277 *
278 * Reduce to lower bidiagonal form
279 *
280  DO 20 i = 1, m
281 *
282 * Generate elementary reflector G(i) to annihilate A(i,i+1:n)
283 *
284  CALL slarfg( n-i+1, a( i, i ), a( i, min( i+1, n ) ), lda,
285  $ taup( i ) )
286  d( i ) = a( i, i )
287  a( i, i ) = one
288 *
289 * Apply G(i) to A(i+1:m,i:n) from the right
290 *
291  IF( i.LT.m )
292  $ CALL slarf( 'Right', m-i, n-i+1, a( i, i ), lda,
293  $ taup( i ), a( i+1, i ), lda, work )
294  a( i, i ) = d( i )
295 *
296  IF( i.LT.m ) THEN
297 *
298 * Generate elementary reflector H(i) to annihilate
299 * A(i+2:m,i)
300 *
301  CALL slarfg( m-i, a( i+1, i ), a( min( i+2, m ), i ), 1,
302  $ tauq( i ) )
303  e( i ) = a( i+1, i )
304  a( i+1, i ) = one
305 *
306 * Apply H(i) to A(i+1:m,i+1:n) from the left
307 *
308  CALL slarf( 'Left', m-i, n-i, a( i+1, i ), 1, tauq( i ),
309  $ a( i+1, i+1 ), lda, work )
310  a( i+1, i ) = e( i )
311  ELSE
312  tauq( i ) = zero
313  END IF
314  20 CONTINUE
315  END IF
316  RETURN
317 *
318 * End of SGEBD2
319 *
320  END
subroutine slarfg(N, ALPHA, X, INCX, TAU)
SLARFG generates an elementary reflector (Householder matrix).
Definition: slarfg.f:108
subroutine sgebd2(M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO)
SGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.
Definition: sgebd2.f:191
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine slarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition: slarf.f:126