cchktp.f

Go to the documentation of this file.

*> \brief \b CCHKTP
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CCHKTP( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
*                          NMAX, AP, AINVP, B, X, XACT, WORK, RWORK,
*                          NOUT )
* 
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NNS, NOUT
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            NSVAL( * ), NVAL( * )
*       REAL               RWORK( * )
*       COMPLEX            AINVP( * ), AP( * ), B( * ), WORK( * ), X( * ),
*      $                   XACT( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CCHKTP tests CTPTRI, -TRS, -RFS, and -CON, and CLATPS
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The leading dimension of the work arrays.  NMAX >= the
*>          maximumm value of N in NVAL.
*> \endverbatim
*>
*> \param[out] AP
*> \verbatim
*>          AP is COMPLEX array, dimension (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] AINVP
*> \verbatim
*>          AINVP is COMPLEX array, dimension (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is COMPLEX array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is COMPLEX array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is COMPLEX array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension
*>                      (NMAX*max(3,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension
*>                      (max(NMAX,2*NSMAX))
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cchktp( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
     $                   nmax, ap, ainvp, b, x, xact, work, rwork,
     $                   nout )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNS, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NSVAL( * ), NVAL( * )
      REAL               RWORK( * )
      COMPLEX            AINVP( * ), AP( * ), B( * ), WORK( * ), X( * ),
     $                   xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTYPE1, NTYPES
      parameter                ( ntype1 = 10, ntypes = 18 )
      INTEGER            NTESTS
      parameter                ( ntests = 9 )
      INTEGER            NTRAN
      parameter                ( ntran = 3 )
      REAL               ONE, ZERO
      parameter                ( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          DIAG, NORM, TRANS, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IDIAG, IMAT, IN, INFO, IRHS, ITRAN, IUPLO,
     $                   k, lap, lda, n, nerrs, nfail, nrhs, nrun
      REAL               AINVNM, ANORM, RCOND, RCONDC, RCONDI, RCONDO,
     $                   scale
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( ntran ), UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( ntests )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               CLANTP
      EXTERNAL           lsame, clantp
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, ccopy, cerrtr, cget04,
     $                   clacpy, clarhs, clatps, clattp, ctpcon, ctprfs,
     $                   ctpt01, ctpt02, ctpt03, ctpt05, ctpt06, ctptri,
     $                   ctptrs
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, IOUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, iounit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' / , transs / 'N', 'T', 'C' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'TP'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL cerrtr( path, nout )
      infot = 0
*
      DO 110 in = 1, nn
*
*        Do for each value of N in NVAL
*
         n = nval( in )
         lda = max( 1, n )
         lap = lda*( lda+1 ) / 2
         xtype = 'N'
*
         DO 70 imat = 1, ntype1
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 70
*
            DO 60 iuplo = 1, 2
*
*              Do first for UPLO = 'U', then for UPLO = 'L'
*
               uplo = uplos( iuplo )
*
*              Call CLATTP to generate a triangular test matrix.
*
               srnamt = 'CLATTP'
               CALL clattp( imat, uplo, 'No transpose', diag, iseed, n,
     $                      ap, x, work, rwork, info )
*
*              Set IDIAG = 1 for non-unit matrices, 2 for unit.
*
               IF( lsame( diag, 'N' ) ) THEN
                  idiag = 1
               ELSE
                  idiag = 2
               END IF
*
*+    TEST 1
*              Form the inverse of A.
*
               IF( n.GT.0 )
     $            CALL ccopy( lap, ap, 1, ainvp, 1 )
               srnamt = 'CTPTRI'
               CALL ctptri( uplo, diag, n, ainvp, info )
*
*              Check error code from CTPTRI.
*
               IF( info.NE.0 )
     $            CALL alaerh( path, 'CTPTRI', info, 0, uplo // diag, n,
     $                         n, -1, -1, -1, imat, nfail, nerrs, nout )
*
*              Compute the infinity-norm condition number of A.
*
               anorm = clantp( 'I', uplo, diag, n, ap, rwork )
               ainvnm = clantp( 'I', uplo, diag, n, ainvp, rwork )
               IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                  rcondi = one
               ELSE
                  rcondi = ( one / anorm ) / ainvnm
               END IF
*
*              Compute the residual for the triangular matrix times its
*              inverse.  Also compute the 1-norm condition number of A.
*
               CALL ctpt01( uplo, diag, n, ap, ainvp, rcondo, rwork,
     $                      result( 1 ) )
*
*              Print the test ratio if it is .GE. THRESH.
*
               IF( result( 1 ).GE.thresh ) THEN
                  IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $               CALL alahd( nout, path )
                  WRITE( nout, fmt = 9999 )uplo, diag, n, imat, 1,
     $               result( 1 )
                  nfail = nfail + 1
               END IF
               nrun = nrun + 1
*
               DO 40 irhs = 1, nns
                  nrhs = nsval( irhs )
                  xtype = 'N'
*
                  DO 30 itran = 1, ntran
*
*                 Do for op(A) = A, A**T, or A**H.
*
                     trans = transs( itran )
                     IF( itran.EQ.1 ) THEN
                        norm = 'O'
                        rcondc = rcondo
                     ELSE
                        norm = 'I'
                        rcondc = rcondi
                     END IF
*
*+    TEST 2
*                 Solve and compute residual for op(A)*x = b.
*
                     srnamt = 'CLARHS'
                     CALL clarhs( path, xtype, uplo, trans, n, n, 0,
     $                            idiag, nrhs, ap, lap, xact, lda, b,
     $                            lda, iseed, info )
                     xtype = 'C'
                     CALL clacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'CTPTRS'
                     CALL ctptrs( uplo, trans, diag, n, nrhs, ap, x,
     $                            lda, info )
*
*                 Check error code from CTPTRS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'CTPTRS', info, 0,
     $                               uplo // trans // diag, n, n, -1,
     $                               -1, -1, imat, nfail, nerrs, nout )
*
                     CALL ctpt02( uplo, trans, diag, n, nrhs, ap, x,
     $                            lda, b, lda, work, rwork,
     $                            result( 2 ) )
*
*+    TEST 3
*                 Check solution from generated exact solution.
*
                     CALL cget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 3 ) )
*
*+    TESTS 4, 5, and 6
*                 Use iterative refinement to improve the solution and
*                 compute error bounds.
*
                     srnamt = 'CTPRFS'
                     CALL ctprfs( uplo, trans, diag, n, nrhs, ap, b,
     $                            lda, x, lda, rwork, rwork( nrhs+1 ),
     $                            work, rwork( 2*nrhs+1 ), info )
*
*                 Check error code from CTPRFS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'CTPRFS', info, 0,
     $                               uplo // trans // diag, n, n, -1,
     $                               -1, nrhs, imat, nfail, nerrs,
     $                               nout )
*
                     CALL cget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 4 ) )
                     CALL ctpt05( uplo, trans, diag, n, nrhs, ap, b,
     $                            lda, x, lda, xact, lda, rwork,
     $                            rwork( nrhs+1 ), result( 5 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 20 k = 2, 6
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9998 )uplo, trans, diag,
     $                        n, nrhs, imat, k, result( k )
                           nfail = nfail + 1
                        END IF
   20                CONTINUE
                     nrun = nrun + 5
   30             CONTINUE
   40          CONTINUE
*
*+    TEST 7
*                 Get an estimate of RCOND = 1/CNDNUM.
*
               DO 50 itran = 1, 2
                  IF( itran.EQ.1 ) THEN
                     norm = 'O'
                     rcondc = rcondo
                  ELSE
                     norm = 'I'
                     rcondc = rcondi
                  END IF
                  srnamt = 'CTPCON'
                  CALL ctpcon( norm, uplo, diag, n, ap, rcond, work,
     $                         rwork, info )
*
*                 Check error code from CTPCON.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'CTPCON', info, 0,
     $                            norm // uplo // diag, n, n, -1, -1,
     $                            -1, imat, nfail, nerrs, nout )
*
                  CALL ctpt06( rcond, rcondc, uplo, diag, n, ap, rwork,
     $                         result( 7 ) )
*
*                 Print the test ratio if it is .GE. THRESH.
*
                  IF( result( 7 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9997 ) 'CTPCON', norm, uplo,
     $                  diag, n, imat, 7, result( 7 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 1
   50          CONTINUE
   60       CONTINUE
   70    CONTINUE
*
*        Use pathological test matrices to test CLATPS.
*
         DO 100 imat = ntype1 + 1, ntypes
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 100
*
            DO 90 iuplo = 1, 2
*
*              Do first for UPLO = 'U', then for UPLO = 'L'
*
               uplo = uplos( iuplo )
               DO 80 itran = 1, ntran
*
*                 Do for op(A) = A, A**T, or A**H.
*
                  trans = transs( itran )
*
*                 Call CLATTP to generate a triangular test matrix.
*
                  srnamt = 'CLATTP'
                  CALL clattp( imat, uplo, trans, diag, iseed, n, ap, x,
     $                         work, rwork, info )
*
*+    TEST 8
*                 Solve the system op(A)*x = b.
*
                  srnamt = 'CLATPS'
                  CALL ccopy( n, x, 1, b, 1 )
                  CALL clatps( uplo, trans, diag, 'N', n, ap, b, scale,
     $                         rwork, info )
*
*                 Check error code from CLATPS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'CLATPS', info, 0,
     $                            uplo // trans // diag // 'N', n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  CALL ctpt03( uplo, trans, diag, n, 1, ap, scale,
     $                         rwork, one, b, lda, x, lda, work,
     $                         result( 8 ) )
*
*+    TEST 9
*                 Solve op(A)*x = b again with NORMIN = 'Y'.
*
                  CALL ccopy( n, x, 1, b( n+1 ), 1 )
                  CALL clatps( uplo, trans, diag, 'Y', n, ap, b( n+1 ),
     $                         scale, rwork, info )
*
*                 Check error code from CLATPS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'CLATPS', info, 0,
     $                            uplo // trans // diag // 'Y', n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  CALL ctpt03( uplo, trans, diag, n, 1, ap, scale,
     $                         rwork, one, b( n+1 ), lda, x, lda, work,
     $                         result( 9 ) )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  IF( result( 8 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9996 )'CLATPS', uplo, trans,
     $                  diag, 'N', n, imat, 8, result( 8 )
                     nfail = nfail + 1
                  END IF
                  IF( result( 9 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9996 )'CLATPS', uplo, trans,
     $                  diag, 'Y', n, imat, 9, result( 9 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 2
   80          CONTINUE
   90       CONTINUE
  100    CONTINUE
  110 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO=''', a1, ''', DIAG=''', a1, ''', N=', i5,
     $      ', type ', i2, ', test(', i2, ')= ', g12.5 )
 9998 FORMAT( ' UPLO=''', a1, ''', TRANS=''', a1, ''', DIAG=''', a1,
     $      ''', N=', i5, ''', NRHS=', i5, ', type ', i2, ', test(',
     $      i2, ')= ', g12.5 )
 9997 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''',',
     $      i5, ', ... ), type ', i2, ', test(', i2, ')=', g12.5 )
 9996 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''', ''',
     $      a1, ''',', i5, ', ... ), type ', i2, ', test(', i2, ')=',
     $      g12.5 )
      RETURN
*
*     End of CCHKTP
*
      END