subroutine cget04	(	integer	N,
		integer	NRHS,
		complex, dimension( ldx, * )	X,
		integer	LDX,
		complex, dimension( ldxact, * )	XACT,
		integer	LDXACT,
		real	RCOND,
		real	RESID
	)

CGET04

Purpose:

 CGET04 computes the difference between a computed solution and the
 true solution to a system of linear equations.

 RESID =  ( norm(X-XACT) * RCOND ) / ( norm(XACT) * EPS ),
 where RCOND is the reciprocal of the condition number and EPS is the
 machine epsilon.

Parameters

[in]	N	N is INTEGER The number of rows of the matrices X and XACT. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of columns of the matrices X and XACT. NRHS >= 0.
[in]	X	X is COMPLEX array, dimension (LDX,NRHS) The computed solution vectors. Each vector is stored as a column of the matrix X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).
[in]	XACT	XACT is COMPLEX array, dimension (LDX,NRHS) The exact solution vectors. Each vector is stored as a column of the matrix XACT.
[in]	LDXACT	LDXACT is INTEGER The leading dimension of the array XACT. LDXACT >= max(1,N).
[in]	RCOND	RCOND is REAL The reciprocal of the condition number of the coefficient matrix in the system of equations.
[out]	RESID	RESID is REAL The maximum over the NRHS solution vectors of ( norm(X-XACT) * RCOND ) / ( norm(XACT) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 104 of file cget04.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            ldx, ldxact, n, nrhs
      REAL               rcond, resid
*     ..
*     .. Array Arguments ..
      COMPLEX            x( ldx, * ), xact( ldxact, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero
      parameter                ( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, ix, j
      REAL               diffnm, eps, xnorm
      COMPLEX            zdum
*     ..
*     .. External Functions ..
      INTEGER            icamax
      REAL               slamch
      EXTERNAL           icamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, real
*     ..
*     .. Statement Functions ..
      REAL               cabs1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if RCOND is invalid.
*
      eps = slamch( 'Epsilon' )
      IF( rcond.LT.zero ) THEN
         resid = 1.0 / eps
         RETURN
      END IF
*
*     Compute the maximum of
*        norm(X - XACT) / ( norm(XACT) * EPS )
*     over all the vectors X and XACT .
*
      resid = zero
      DO 20 j = 1, nrhs
         ix = icamax( n, xact( 1, j ), 1 )
         xnorm = cabs1( xact( ix, j ) )
         diffnm = zero
         DO 10 i = 1, n
            diffnm = max( diffnm, cabs1( x( i, j )-xact( i, j ) ) )
   10    CONTINUE
         IF( xnorm.LE.zero ) THEN
            IF( diffnm.GT.zero )
     $         resid = 1.0 / eps
         ELSE
            resid = max( resid, ( diffnm / xnorm )*rcond )
         END IF
   20 CONTINUE
      IF( resid*eps.LT.1.0 )
     $   resid = resid / eps
*
      RETURN
*
*     End of CGET04
*

Here is the caller graph for this function: