LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
cla_porfsx_extended.f
Go to the documentation of this file.
1 *> \brief \b CLA_PORFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric or Hermitian positive-definite matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cla_porfsx_extended.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cla_porfsx_extended.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cla_porfsx_extended.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CLA_PORFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
22 * AF, LDAF, COLEQU, C, B, LDB, Y,
23 * LDY, BERR_OUT, N_NORMS,
24 * ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
25 * AYB, DY, Y_TAIL, RCOND, ITHRESH,
26 * RTHRESH, DZ_UB, IGNORE_CWISE,
27 * INFO )
28 *
29 * .. Scalar Arguments ..
30 * INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
31 * \$ N_NORMS, ITHRESH
32 * CHARACTER UPLO
33 * LOGICAL COLEQU, IGNORE_CWISE
34 * REAL RTHRESH, DZ_UB
35 * ..
36 * .. Array Arguments ..
37 * COMPLEX A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
38 * \$ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
39 * REAL C( * ), AYB( * ), RCOND, BERR_OUT( * ),
40 * \$ ERR_BNDS_NORM( NRHS, * ),
41 * \$ ERR_BNDS_COMP( NRHS, * )
42 * ..
43 *
44 *
45 *> \par Purpose:
46 * =============
47 *>
48 *> \verbatim
49 *>
50 *> CLA_PORFSX_EXTENDED improves the computed solution to a system of
51 *> linear equations by performing extra-precise iterative refinement
52 *> and provides error bounds and backward error estimates for the solution.
53 *> This subroutine is called by CPORFSX to perform iterative refinement.
54 *> In addition to normwise error bound, the code provides maximum
55 *> componentwise error bound if possible. See comments for ERR_BNDS_NORM
56 *> and ERR_BNDS_COMP for details of the error bounds. Note that this
57 *> subroutine is only resonsible for setting the second fields of
58 *> ERR_BNDS_NORM and ERR_BNDS_COMP.
59 *> \endverbatim
60 *
61 * Arguments:
62 * ==========
63 *
64 *> \param[in] PREC_TYPE
65 *> \verbatim
66 *> PREC_TYPE is INTEGER
67 *> Specifies the intermediate precision to be used in refinement.
68 *> The value is defined by ILAPREC(P) where P is a CHARACTER and
69 *> P = 'S': Single
70 *> = 'D': Double
71 *> = 'I': Indigenous
72 *> = 'X', 'E': Extra
73 *> \endverbatim
74 *>
75 *> \param[in] UPLO
76 *> \verbatim
77 *> UPLO is CHARACTER*1
78 *> = 'U': Upper triangle of A is stored;
79 *> = 'L': Lower triangle of A is stored.
80 *> \endverbatim
81 *>
82 *> \param[in] N
83 *> \verbatim
84 *> N is INTEGER
85 *> The number of linear equations, i.e., the order of the
86 *> matrix A. N >= 0.
87 *> \endverbatim
88 *>
89 *> \param[in] NRHS
90 *> \verbatim
91 *> NRHS is INTEGER
92 *> The number of right-hand-sides, i.e., the number of columns of the
93 *> matrix B.
94 *> \endverbatim
95 *>
96 *> \param[in] A
97 *> \verbatim
98 *> A is COMPLEX array, dimension (LDA,N)
99 *> On entry, the N-by-N matrix A.
100 *> \endverbatim
101 *>
102 *> \param[in] LDA
103 *> \verbatim
104 *> LDA is INTEGER
105 *> The leading dimension of the array A. LDA >= max(1,N).
106 *> \endverbatim
107 *>
108 *> \param[in] AF
109 *> \verbatim
110 *> AF is COMPLEX array, dimension (LDAF,N)
111 *> The triangular factor U or L from the Cholesky factorization
112 *> A = U**T*U or A = L*L**T, as computed by CPOTRF.
113 *> \endverbatim
114 *>
115 *> \param[in] LDAF
116 *> \verbatim
117 *> LDAF is INTEGER
118 *> The leading dimension of the array AF. LDAF >= max(1,N).
119 *> \endverbatim
120 *>
121 *> \param[in] COLEQU
122 *> \verbatim
123 *> COLEQU is LOGICAL
124 *> If .TRUE. then column equilibration was done to A before calling
125 *> this routine. This is needed to compute the solution and error
126 *> bounds correctly.
127 *> \endverbatim
128 *>
129 *> \param[in] C
130 *> \verbatim
131 *> C is REAL array, dimension (N)
132 *> The column scale factors for A. If COLEQU = .FALSE., C
133 *> is not accessed. If C is input, each element of C should be a power
134 *> of the radix to ensure a reliable solution and error estimates.
135 *> Scaling by powers of the radix does not cause rounding errors unless
136 *> the result underflows or overflows. Rounding errors during scaling
137 *> lead to refining with a matrix that is not equivalent to the
138 *> input matrix, producing error estimates that may not be
139 *> reliable.
140 *> \endverbatim
141 *>
142 *> \param[in] B
143 *> \verbatim
144 *> B is COMPLEX array, dimension (LDB,NRHS)
145 *> The right-hand-side matrix B.
146 *> \endverbatim
147 *>
148 *> \param[in] LDB
149 *> \verbatim
150 *> LDB is INTEGER
151 *> The leading dimension of the array B. LDB >= max(1,N).
152 *> \endverbatim
153 *>
154 *> \param[in,out] Y
155 *> \verbatim
156 *> Y is COMPLEX array, dimension
157 *> (LDY,NRHS)
158 *> On entry, the solution matrix X, as computed by CPOTRS.
159 *> On exit, the improved solution matrix Y.
160 *> \endverbatim
161 *>
162 *> \param[in] LDY
163 *> \verbatim
164 *> LDY is INTEGER
165 *> The leading dimension of the array Y. LDY >= max(1,N).
166 *> \endverbatim
167 *>
168 *> \param[out] BERR_OUT
169 *> \verbatim
170 *> BERR_OUT is REAL array, dimension (NRHS)
171 *> On exit, BERR_OUT(j) contains the componentwise relative backward
172 *> error for right-hand-side j from the formula
173 *> max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
174 *> where abs(Z) is the componentwise absolute value of the matrix
175 *> or vector Z. This is computed by CLA_LIN_BERR.
176 *> \endverbatim
177 *>
178 *> \param[in] N_NORMS
179 *> \verbatim
180 *> N_NORMS is INTEGER
181 *> Determines which error bounds to return (see ERR_BNDS_NORM
182 *> and ERR_BNDS_COMP).
183 *> If N_NORMS >= 1 return normwise error bounds.
184 *> If N_NORMS >= 2 return componentwise error bounds.
185 *> \endverbatim
186 *>
187 *> \param[in,out] ERR_BNDS_NORM
188 *> \verbatim
189 *> ERR_BNDS_NORM is REAL array, dimension
190 *> (NRHS, N_ERR_BNDS)
191 *> For each right-hand side, this array contains information about
192 *> various error bounds and condition numbers corresponding to the
193 *> normwise relative error, which is defined as follows:
194 *>
195 *> Normwise relative error in the ith solution vector:
196 *> max_j (abs(XTRUE(j,i) - X(j,i)))
197 *> ------------------------------
198 *> max_j abs(X(j,i))
199 *>
200 *> The array is indexed by the type of error information as described
201 *> below. There currently are up to three pieces of information
202 *> returned.
203 *>
204 *> The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
205 *> right-hand side.
206 *>
207 *> The second index in ERR_BNDS_NORM(:,err) contains the following
208 *> three fields:
209 *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
210 *> reciprocal condition number is less than the threshold
211 *> sqrt(n) * slamch('Epsilon').
212 *>
213 *> err = 2 "Guaranteed" error bound: The estimated forward error,
214 *> almost certainly within a factor of 10 of the true error
215 *> so long as the next entry is greater than the threshold
216 *> sqrt(n) * slamch('Epsilon'). This error bound should only
217 *> be trusted if the previous boolean is true.
218 *>
219 *> err = 3 Reciprocal condition number: Estimated normwise
220 *> reciprocal condition number. Compared with the threshold
221 *> sqrt(n) * slamch('Epsilon') to determine if the error
222 *> estimate is "guaranteed". These reciprocal condition
223 *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
224 *> appropriately scaled matrix Z.
225 *> Let Z = S*A, where S scales each row by a power of the
226 *> radix so all absolute row sums of Z are approximately 1.
227 *>
228 *> This subroutine is only responsible for setting the second field
229 *> above.
230 *> See Lapack Working Note 165 for further details and extra
231 *> cautions.
232 *> \endverbatim
233 *>
234 *> \param[in,out] ERR_BNDS_COMP
235 *> \verbatim
236 *> ERR_BNDS_COMP is REAL array, dimension
237 *> (NRHS, N_ERR_BNDS)
238 *> For each right-hand side, this array contains information about
239 *> various error bounds and condition numbers corresponding to the
240 *> componentwise relative error, which is defined as follows:
241 *>
242 *> Componentwise relative error in the ith solution vector:
243 *> abs(XTRUE(j,i) - X(j,i))
244 *> max_j ----------------------
245 *> abs(X(j,i))
246 *>
247 *> The array is indexed by the right-hand side i (on which the
248 *> componentwise relative error depends), and the type of error
249 *> information as described below. There currently are up to three
250 *> pieces of information returned for each right-hand side. If
251 *> componentwise accuracy is not requested (PARAMS(3) = 0.0), then
252 *> ERR_BNDS_COMP is not accessed. If N_ERR_BNDS .LT. 3, then at most
253 *> the first (:,N_ERR_BNDS) entries are returned.
254 *>
255 *> The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
256 *> right-hand side.
257 *>
258 *> The second index in ERR_BNDS_COMP(:,err) contains the following
259 *> three fields:
260 *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
261 *> reciprocal condition number is less than the threshold
262 *> sqrt(n) * slamch('Epsilon').
263 *>
264 *> err = 2 "Guaranteed" error bound: The estimated forward error,
265 *> almost certainly within a factor of 10 of the true error
266 *> so long as the next entry is greater than the threshold
267 *> sqrt(n) * slamch('Epsilon'). This error bound should only
268 *> be trusted if the previous boolean is true.
269 *>
270 *> err = 3 Reciprocal condition number: Estimated componentwise
271 *> reciprocal condition number. Compared with the threshold
272 *> sqrt(n) * slamch('Epsilon') to determine if the error
273 *> estimate is "guaranteed". These reciprocal condition
274 *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
275 *> appropriately scaled matrix Z.
276 *> Let Z = S*(A*diag(x)), where x is the solution for the
277 *> current right-hand side and S scales each row of
278 *> A*diag(x) by a power of the radix so all absolute row
279 *> sums of Z are approximately 1.
280 *>
281 *> This subroutine is only responsible for setting the second field
282 *> above.
283 *> See Lapack Working Note 165 for further details and extra
284 *> cautions.
285 *> \endverbatim
286 *>
287 *> \param[in] RES
288 *> \verbatim
289 *> RES is COMPLEX array, dimension (N)
290 *> Workspace to hold the intermediate residual.
291 *> \endverbatim
292 *>
293 *> \param[in] AYB
294 *> \verbatim
295 *> AYB is REAL array, dimension (N)
296 *> Workspace.
297 *> \endverbatim
298 *>
299 *> \param[in] DY
300 *> \verbatim
301 *> DY is COMPLEX array, dimension (N)
302 *> Workspace to hold the intermediate solution.
303 *> \endverbatim
304 *>
305 *> \param[in] Y_TAIL
306 *> \verbatim
307 *> Y_TAIL is COMPLEX array, dimension (N)
308 *> Workspace to hold the trailing bits of the intermediate solution.
309 *> \endverbatim
310 *>
311 *> \param[in] RCOND
312 *> \verbatim
313 *> RCOND is REAL
314 *> Reciprocal scaled condition number. This is an estimate of the
315 *> reciprocal Skeel condition number of the matrix A after
316 *> equilibration (if done). If this is less than the machine
317 *> precision (in particular, if it is zero), the matrix is singular
318 *> to working precision. Note that the error may still be small even
319 *> if this number is very small and the matrix appears ill-
320 *> conditioned.
321 *> \endverbatim
322 *>
323 *> \param[in] ITHRESH
324 *> \verbatim
325 *> ITHRESH is INTEGER
326 *> The maximum number of residual computations allowed for
327 *> refinement. The default is 10. For 'aggressive' set to 100 to
328 *> permit convergence using approximate factorizations or
329 *> factorizations other than LU. If the factorization uses a
330 *> technique other than Gaussian elimination, the guarantees in
331 *> ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
332 *> \endverbatim
333 *>
334 *> \param[in] RTHRESH
335 *> \verbatim
336 *> RTHRESH is REAL
337 *> Determines when to stop refinement if the error estimate stops
338 *> decreasing. Refinement will stop when the next solution no longer
339 *> satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
340 *> the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
341 *> default value is 0.5. For 'aggressive' set to 0.9 to permit
342 *> convergence on extremely ill-conditioned matrices. See LAWN 165
343 *> for more details.
344 *> \endverbatim
345 *>
346 *> \param[in] DZ_UB
347 *> \verbatim
348 *> DZ_UB is REAL
349 *> Determines when to start considering componentwise convergence.
350 *> Componentwise convergence is only considered after each component
351 *> of the solution Y is stable, which we definte as the relative
352 *> change in each component being less than DZ_UB. The default value
353 *> is 0.25, requiring the first bit to be stable. See LAWN 165 for
354 *> more details.
355 *> \endverbatim
356 *>
357 *> \param[in] IGNORE_CWISE
358 *> \verbatim
359 *> IGNORE_CWISE is LOGICAL
360 *> If .TRUE. then ignore componentwise convergence. Default value
361 *> is .FALSE..
362 *> \endverbatim
363 *>
364 *> \param[out] INFO
365 *> \verbatim
366 *> INFO is INTEGER
367 *> = 0: Successful exit.
368 *> < 0: if INFO = -i, the ith argument to CPOTRS had an illegal
369 *> value
370 *> \endverbatim
371 *
372 * Authors:
373 * ========
374 *
375 *> \author Univ. of Tennessee
376 *> \author Univ. of California Berkeley
377 *> \author Univ. of Colorado Denver
378 *> \author NAG Ltd.
379 *
380 *> \date September 2012
381 *
382 *> \ingroup complexPOcomputational
383 *
384 * =====================================================================
385  SUBROUTINE cla_porfsx_extended( PREC_TYPE, UPLO, N, NRHS, A, LDA,
386  \$ af, ldaf, colequ, c, b, ldb, y,
387  \$ ldy, berr_out, n_norms,
388  \$ err_bnds_norm, err_bnds_comp, res,
389  \$ ayb, dy, y_tail, rcond, ithresh,
390  \$ rthresh, dz_ub, ignore_cwise,
391  \$ info )
392 *
393 * -- LAPACK computational routine (version 3.4.2) --
394 * -- LAPACK is a software package provided by Univ. of Tennessee, --
395 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
396 * September 2012
397 *
398 * .. Scalar Arguments ..
399  INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
400  \$ n_norms, ithresh
401  CHARACTER UPLO
402  LOGICAL COLEQU, IGNORE_CWISE
403  REAL RTHRESH, DZ_UB
404 * ..
405 * .. Array Arguments ..
406  COMPLEX A( lda, * ), AF( ldaf, * ), B( ldb, * ),
407  \$ y( ldy, * ), res( * ), dy( * ), y_tail( * )
408  REAL C( * ), AYB( * ), RCOND, BERR_OUT( * ),
409  \$ err_bnds_norm( nrhs, * ),
410  \$ err_bnds_comp( nrhs, * )
411 * ..
412 *
413 * =====================================================================
414 *
415 * .. Local Scalars ..
416  INTEGER UPLO2, CNT, I, J, X_STATE, Z_STATE,
417  \$ y_prec_state
418  REAL YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
419  \$ dzrat, prevnormdx, prev_dz_z, dxratmax,
420  \$ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
421  \$ eps, hugeval, incr_thresh
422  LOGICAL INCR_PREC
423  COMPLEX ZDUM
424 * ..
425 * .. Parameters ..
426  INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
427  \$ noprog_state, base_residual, extra_residual,
428  \$ extra_y
429  parameter ( unstable_state = 0, working_state = 1,
430  \$ conv_state = 2, noprog_state = 3 )
431  parameter ( base_residual = 0, extra_residual = 1,
432  \$ extra_y = 2 )
433  INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
434  INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
435  INTEGER CMP_ERR_I, PIV_GROWTH_I
436  parameter ( final_nrm_err_i = 1, final_cmp_err_i = 2,
437  \$ berr_i = 3 )
438  parameter ( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
439  parameter ( cmp_rcond_i = 7, cmp_err_i = 8,
440  \$ piv_growth_i = 9 )
441  INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
442  \$ la_linrx_cwise_i
443  parameter ( la_linrx_itref_i = 1,
444  \$ la_linrx_ithresh_i = 2 )
445  parameter ( la_linrx_cwise_i = 3 )
446  INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
447  \$ la_linrx_rcond_i
448  parameter ( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
449  parameter ( la_linrx_rcond_i = 3 )
450 * ..
451 * .. External Functions ..
452  LOGICAL LSAME
453  EXTERNAL ilauplo
454  INTEGER ILAUPLO
455 * ..
456 * .. External Subroutines ..
457  EXTERNAL caxpy, ccopy, cpotrs, chemv, blas_chemv_x,
460  REAL SLAMCH
461 * ..
462 * .. Intrinsic Functions ..
463  INTRINSIC abs, REAL, AIMAG, MAX, MIN
464 * ..
465 * .. Statement Functions ..
466  REAL CABS1
467 * ..
468 * .. Statement Function Definitions ..
469  cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( AIMAG( zdum ) )
470 * ..
471 * .. Executable Statements ..
472 *
473  IF (info.NE.0) RETURN
474  eps = slamch( 'Epsilon' )
475  hugeval = slamch( 'Overflow' )
476 * Force HUGEVAL to Inf
477  hugeval = hugeval * hugeval
478 * Using HUGEVAL may lead to spurious underflows.
479  incr_thresh = REAL(N) * EPS
480
481  IF (lsame(uplo, 'L')) THEN
482  uplo2 = ilauplo( 'L' )
483  ELSE
484  uplo2 = ilauplo( 'U' )
485  ENDIF
486
487  DO j = 1, nrhs
488  y_prec_state = extra_residual
489  IF (y_prec_state .EQ. extra_y) THEN
490  DO i = 1, n
491  y_tail( i ) = 0.0
492  END DO
493  END IF
494
495  dxrat = 0.0
496  dxratmax = 0.0
497  dzrat = 0.0
498  dzratmax = 0.0
499  final_dx_x = hugeval
500  final_dz_z = hugeval
501  prevnormdx = hugeval
502  prev_dz_z = hugeval
503  dz_z = hugeval
504  dx_x = hugeval
505
506  x_state = working_state
507  z_state = unstable_state
508  incr_prec = .false.
509
510  DO cnt = 1, ithresh
511 *
512 * Compute residual RES = B_s - op(A_s) * Y,
513 * op(A) = A, A**T, or A**H depending on TRANS (and type).
514 *
515  CALL ccopy( n, b( 1, j ), 1, res, 1 )
516  IF (y_prec_state .EQ. base_residual) THEN
517  CALL chemv(uplo, n, cmplx(-1.0), a, lda, y(1,j), 1,
518  \$ cmplx(1.0), res, 1)
519  ELSE IF (y_prec_state .EQ. extra_residual) THEN
520  CALL blas_chemv_x(uplo2, n, cmplx(-1.0), a, lda,
521  \$ y( 1, j ), 1, cmplx(1.0), res, 1, prec_type)
522  ELSE
523  CALL blas_chemv2_x(uplo2, n, cmplx(-1.0), a, lda,
524  \$ y(1, j), y_tail, 1, cmplx(1.0), res, 1, prec_type)
525  END IF
526
527 ! XXX: RES is no longer needed.
528  CALL ccopy( n, res, 1, dy, 1 )
529  CALL cpotrs( uplo, n, 1, af, ldaf, dy, n, info)
530 *
531 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
532 *
533  normx = 0.0
534  normy = 0.0
535  normdx = 0.0
536  dz_z = 0.0
537  ymin = hugeval
538
539  DO i = 1, n
540  yk = cabs1(y(i, j))
541  dyk = cabs1(dy(i))
542
543  IF (yk .NE. 0.0) THEN
544  dz_z = max( dz_z, dyk / yk )
545  ELSE IF (dyk .NE. 0.0) THEN
546  dz_z = hugeval
547  END IF
548
549  ymin = min( ymin, yk )
550
551  normy = max( normy, yk )
552
553  IF ( colequ ) THEN
554  normx = max(normx, yk * c(i))
555  normdx = max(normdx, dyk * c(i))
556  ELSE
557  normx = normy
558  normdx = max(normdx, dyk)
559  END IF
560  END DO
561
562  IF (normx .NE. 0.0) THEN
563  dx_x = normdx / normx
564  ELSE IF (normdx .EQ. 0.0) THEN
565  dx_x = 0.0
566  ELSE
567  dx_x = hugeval
568  END IF
569
570  dxrat = normdx / prevnormdx
571  dzrat = dz_z / prev_dz_z
572 *
573 * Check termination criteria.
574 *
575  IF (ymin*rcond .LT. incr_thresh*normy
576  \$ .AND. y_prec_state .LT. extra_y)
577  \$ incr_prec = .true.
578
579  IF (x_state .EQ. noprog_state .AND. dxrat .LE. rthresh)
580  \$ x_state = working_state
581  IF (x_state .EQ. working_state) THEN
582  IF (dx_x .LE. eps) THEN
583  x_state = conv_state
584  ELSE IF (dxrat .GT. rthresh) THEN
585  IF (y_prec_state .NE. extra_y) THEN
586  incr_prec = .true.
587  ELSE
588  x_state = noprog_state
589  END IF
590  ELSE
591  IF (dxrat .GT. dxratmax) dxratmax = dxrat
592  END IF
593  IF (x_state .GT. working_state) final_dx_x = dx_x
594  END IF
595
596  IF (z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub)
597  \$ z_state = working_state
598  IF (z_state .EQ. noprog_state .AND. dzrat .LE. rthresh)
599  \$ z_state = working_state
600  IF (z_state .EQ. working_state) THEN
601  IF (dz_z .LE. eps) THEN
602  z_state = conv_state
603  ELSE IF (dz_z .GT. dz_ub) THEN
604  z_state = unstable_state
605  dzratmax = 0.0
606  final_dz_z = hugeval
607  ELSE IF (dzrat .GT. rthresh) THEN
608  IF (y_prec_state .NE. extra_y) THEN
609  incr_prec = .true.
610  ELSE
611  z_state = noprog_state
612  END IF
613  ELSE
614  IF (dzrat .GT. dzratmax) dzratmax = dzrat
615  END IF
616  IF (z_state .GT. working_state) final_dz_z = dz_z
617  END IF
618
619  IF ( x_state.NE.working_state.AND.
620  \$ (ignore_cwise.OR.z_state.NE.working_state) )
621  \$ GOTO 666
622
623  IF (incr_prec) THEN
624  incr_prec = .false.
625  y_prec_state = y_prec_state + 1
626  DO i = 1, n
627  y_tail( i ) = 0.0
628  END DO
629  END IF
630
631  prevnormdx = normdx
632  prev_dz_z = dz_z
633 *
634 * Update soluton.
635 *
636  IF (y_prec_state .LT. extra_y) THEN
637  CALL caxpy( n, cmplx(1.0), dy, 1, y(1,j), 1 )
638  ELSE
639  CALL cla_wwaddw(n, y(1,j), y_tail, dy)
640  END IF
641
642  END DO
643 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
644  666 CONTINUE
645 *
646 * Set final_* when cnt hits ithresh.
647 *
648  IF (x_state .EQ. working_state) final_dx_x = dx_x
649  IF (z_state .EQ. working_state) final_dz_z = dz_z
650 *
651 * Compute error bounds.
652 *
653  IF (n_norms .GE. 1) THEN
654  err_bnds_norm( j, la_linrx_err_i ) =
655  \$ final_dx_x / (1 - dxratmax)
656  END IF
657  IF (n_norms .GE. 2) THEN
658  err_bnds_comp( j, la_linrx_err_i ) =
659  \$ final_dz_z / (1 - dzratmax)
660  END IF
661 *
662 * Compute componentwise relative backward error from formula
663 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
664 * where abs(Z) is the componentwise absolute value of the matrix
665 * or vector Z.
666 *
667 * Compute residual RES = B_s - op(A_s) * Y,
668 * op(A) = A, A**T, or A**H depending on TRANS (and type).
669 *
670  CALL ccopy( n, b( 1, j ), 1, res, 1 )
671  CALL chemv(uplo, n, cmplx(-1.0), a, lda, y(1,j), 1, cmplx(1.0),
672  \$ res, 1)
673
674  DO i = 1, n
675  ayb( i ) = cabs1( b( i, j ) )
676  END DO
677 *
678 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
679 *
680  CALL cla_heamv (uplo2, n, 1.0,
681  \$ a, lda, y(1, j), 1, 1.0, ayb, 1)
682
683  CALL cla_lin_berr (n, n, 1, res, ayb, berr_out(j))
684 *
685 * End of loop for each RHS.
686 *
687  END DO
688 *
689  RETURN
690  END
subroutine cla_porfsx_extended(PREC_TYPE, UPLO, N, NRHS, A, LDA, AF, LDAF, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
CLA_PORFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric or H...
subroutine cla_heamv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CLA_HEAMV computes a matrix-vector product using a Hermitian indefinite matrix to calculate error bou...
Definition: cla_heamv.f:180
subroutine cpotrs(UPLO, N, NRHS, A, LDA, B, LDB, INFO)
CPOTRS
Definition: cpotrs.f:112
integer function ilauplo(UPLO)
ILAUPLO
Definition: ilauplo.f:60
subroutine chemv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CHEMV
Definition: chemv.f:156
subroutine cla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
CLA_LIN_BERR computes a component-wise relative backward error.
Definition: cla_lin_berr.f:103
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:52