subroutine cpotrs	(	character	UPLO,
		integer	N,
		integer	NRHS,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( ldb, * )	B,
		integer	LDB,
		integer	INFO
	)

CPOTRS

Download CPOTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CPOTRS solves a system of linear equations A*X = B with a Hermitian
 positive definite matrix A using the Cholesky factorization 
 A = U**H*U or A = L*L**H computed by CPOTRF.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The triangular factor U or L from the Cholesky factorization A = U**H*U or A = L*L**H, as computed by CPOTRF.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in,out]	B	B is COMPLEX array, dimension (LDB,NRHS) On entry, the right hand side matrix B. On exit, the solution matrix X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 112 of file cpotrs.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, lda, ldb, n, nrhs
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * ), b( ldb, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            one
      parameter                ( one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           ctrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPOTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Solve A*X = B where A = U**H *U.
*
*        Solve U**H *X = B, overwriting B with X.
*
         CALL ctrsm( 'Left', 'Upper', 'Conjugate transpose', 'Non-unit',
     $               n, nrhs, one, a, lda, b, ldb )
*
*        Solve U*X = B, overwriting B with X.
*
         CALL ctrsm( 'Left', 'Upper', 'No transpose', 'Non-unit', n,
     $               nrhs, one, a, lda, b, ldb )
      ELSE
*
*        Solve A*X = B where A = L*L**H.
*
*        Solve L*X = B, overwriting B with X.
*
         CALL ctrsm( 'Left', 'Lower', 'No transpose', 'Non-unit', n,
     $               nrhs, one, a, lda, b, ldb )
*
*        Solve L**H *X = B, overwriting B with X.
*
         CALL ctrsm( 'Left', 'Lower', 'Conjugate transpose', 'Non-unit',
     $               n, nrhs, one, a, lda, b, ldb )
      END IF
*
      RETURN
*
*     End of CPOTRS
*

Here is the call graph for this function:

Here is the caller graph for this function: