sqlt03.f

Go to the documentation of this file.

*> \brief \b SQLT03
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SQLT03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
*                          RWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            K, LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       REAL               AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
*      $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
*      $                   WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SQLT03 tests SORMQL, which computes Q*C, Q'*C, C*Q or C*Q'.
*>
*> SQLT03 compares the results of a call to SORMQL with the results of
*> forming Q explicitly by a call to SORGQL and then performing matrix
*> multiplication by a call to SGEMM.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The order of the orthogonal matrix Q.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows or columns of the matrix C; C is m-by-n if
*>          Q is applied from the left, or n-by-m if Q is applied from
*>          the right.  N >= 0.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of elementary reflectors whose product defines the
*>          orthogonal matrix Q.  M >= K >= 0.
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is REAL array, dimension (LDA,N)
*>          Details of the QL factorization of an m-by-n matrix, as
*>          returned by SGEQLF. See SGEQLF for further details.
*> \endverbatim
*>
*> \param[out] C
*> \verbatim
*>          C is REAL array, dimension (LDA,N)
*> \endverbatim
*>
*> \param[out] CC
*> \verbatim
*>          CC is REAL array, dimension (LDA,N)
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is REAL array, dimension (LDA,M)
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays AF, C, CC, and Q.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is REAL array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors corresponding
*>          to the QL factorization in AF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The length of WORK.  LWORK must be at least M, and should be
*>          M*NB, where NB is the blocksize for this environment.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (4)
*>          The test ratios compare two techniques for multiplying a
*>          random matrix C by an m-by-m orthogonal matrix Q.
*>          RESULT(1) = norm( Q*C - Q*C )  / ( M * norm(C) * EPS )
*>          RESULT(2) = norm( C*Q - C*Q )  / ( M * norm(C) * EPS )
*>          RESULT(3) = norm( Q'*C - Q'*C )/ ( M * norm(C) * EPS )
*>          RESULT(4) = norm( C*Q' - C*Q' )/ ( M * norm(C) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE sqlt03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
     $                   rwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               AF( lda, * ), C( lda, * ), CC( lda, * ),
     $                   q( lda, * ), result( * ), rwork( * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter                ( zero = 0.0e0, one = 1.0e0 )
      REAL               ROGUE
      parameter                ( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, ISIDE, ITRANS, J, MC, MINMN, NC
      REAL               CNORM, EPS, RESID
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, SLANGE
      EXTERNAL           lsame, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, slarnv, slaset, sorgql, sormql
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseed / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
      minmn = min( m, n )
*
*     Quick return if possible
*
      IF( minmn.EQ.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         result( 3 ) = zero
         result( 4 ) = zero
         RETURN
      END IF
*
*     Copy the last k columns of the factorization to the array Q
*
      CALL slaset( 'Full', m, m, rogue, rogue, q, lda )
      IF( k.GT.0 .AND. m.GT.k )
     $   CALL slacpy( 'Full', m-k, k, af( 1, n-k+1 ), lda,
     $                q( 1, m-k+1 ), lda )
      IF( k.GT.1 )
     $   CALL slacpy( 'Upper', k-1, k-1, af( m-k+1, n-k+2 ), lda,
     $                q( m-k+1, m-k+2 ), lda )
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'SORGQL'
      CALL sorgql( m, m, k, q, lda, tau( minmn-k+1 ), work, lwork,
     $             info )
*
      DO 30 iside = 1, 2
         IF( iside.EQ.1 ) THEN
            side = 'L'
            mc = m
            nc = n
         ELSE
            side = 'R'
            mc = n
            nc = m
         END IF
*
*        Generate MC by NC matrix C
*
         DO 10 j = 1, nc
            CALL slarnv( 2, iseed, mc, c( 1, j ) )
   10    CONTINUE
         cnorm = slange( '1', mc, nc, c, lda, rwork )
         IF( cnorm.EQ.0.0 )
     $      cnorm = one
*
         DO 20 itrans = 1, 2
            IF( itrans.EQ.1 ) THEN
               trans = 'N'
            ELSE
               trans = 'T'
            END IF
*
*           Copy C
*
            CALL slacpy( 'Full', mc, nc, c, lda, cc, lda )
*
*           Apply Q or Q' to C
*
            srnamt = 'SORMQL'
            IF( k.GT.0 )
     $         CALL sormql( side, trans, mc, nc, k, af( 1, n-k+1 ), lda,
     $                      tau( minmn-k+1 ), cc, lda, work, lwork,
     $                      info )
*
*           Form explicit product and subtract
*
            IF( lsame( side, 'L' ) ) THEN
               CALL sgemm( trans, 'No transpose', mc, nc, mc, -one, q,
     $                     lda, c, lda, one, cc, lda )
            ELSE
               CALL sgemm( 'No transpose', trans, mc, nc, nc, -one, c,
     $                     lda, q, lda, one, cc, lda )
            END IF
*
*           Compute error in the difference
*
            resid = slange( '1', mc, nc, cc, lda, rwork )
            result( ( iside-1 )*2+itrans ) = resid /
     $         ( REAL( MAX( 1, M ) )*cnorm*eps )
*
   20    CONTINUE
   30 CONTINUE
*
      RETURN
*
*     End of SQLT03
*
      END