double precision function zrzt01	(	integer	M,
		integer	N,
		complex*16, dimension( lda, * )	A,
		complex*16, dimension( lda, * )	AF,
		integer	LDA,
		complex*16, dimension( * )	TAU,
		complex*16, dimension( lwork )	WORK,
		integer	LWORK
	)

ZRZT01

Purpose:

 ZRZT01 returns
      || A - R*Q || / ( M * eps * ||A|| )
 for an upper trapezoidal A that was factored with ZTZRZF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and AF.
[in]	N	N is INTEGER The number of columns of the matrices A and AF.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The original upper trapezoidal M by N matrix A.
[in]	AF	AF is COMPLEX*16 array, dimension (LDA,N) The output of ZTZRZF for input matrix A. The lower triangle is not referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A and AF.
[in]	TAU	TAU is COMPLEX*16 array, dimension (M) Details of the Householder transformations as returned by ZTZRZF.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= m*n + m.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 100 of file zrzt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         a( lda, * ), af( lda, * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j
      DOUBLE PRECISION   norma
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   rwork( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zaxpy, zlaset, zunmrz
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Executable Statements ..
*
      zrzt01 = zero
*
      IF( lwork.LT.m*n+m ) THEN
         CALL xerbla( 'ZRZT01', 8 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      norma = zlange( 'One-norm', m, n, a, lda, rwork )
*
*     Copy upper triangle R
*
      CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( zero ), work,
     $             m )
      DO 20 j = 1, m
         DO 10 i = 1, j
            work( ( j-1 )*m+i ) = af( i, j )
   10    CONTINUE
   20 CONTINUE
*
*     R = R * P(1) * ... *P(m)
*
      CALL zunmrz( 'Right', 'No tranpose', m, n, m, n-m, af, lda, tau,
     $             work, m, work( m*n+1 ), lwork-m*n, info )
*
*     R = R - A
*
      DO 30 i = 1, n
         CALL zaxpy( m, dcmplx( -one ), a( 1, i ), 1,
     $               work( ( i-1 )*m+1 ), 1 )
   30 CONTINUE
*
      zrzt01 = zlange( 'One-norm', m, n, work, m, rwork )
*
      zrzt01 = zrzt01 / ( dlamch( 'Epsilon' )*dble( max( m, n ) ) )
      IF( norma.NE.zero )
     $   zrzt01 = zrzt01 / norma
*
      RETURN
*
*     End of ZRZT01
*

Here is the call graph for this function: