subroutine zqlt01	(	integer	M,
		integer	N,
		complex*16, dimension( lda, * )	A,
		complex*16, dimension( lda, * )	AF,
		complex*16, dimension( lda, * )	Q,
		complex*16, dimension( lda, * )	L,
		integer	LDA,
		complex*16, dimension( * )	TAU,
		complex*16, dimension( lwork )	WORK,
		integer	LWORK,
		double precision, dimension( * )	RWORK,
		double precision, dimension( * )	RESULT
	)

ZQLT01

Purpose:

 ZQLT01 tests ZGEQLF, which computes the QL factorization of an m-by-n
 matrix A, and partially tests ZUNGQL which forms the m-by-m
 orthogonal matrix Q.

 ZQLT01 compares L with Q'*A, and checks that Q is orthogonal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The m-by-n matrix A.
[out]	AF	AF is COMPLEX*16 array, dimension (LDA,N) Details of the QL factorization of A, as returned by ZGEQLF. See ZGEQLF for further details.
[out]	Q	Q is COMPLEX*16 array, dimension (LDA,M) The m-by-m orthogonal matrix Q.
[out]	L	L is COMPLEX*16 array, dimension (LDA,max(M,N))
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and R. LDA >= max(M,N).
[out]	TAU	TAU is COMPLEX*16 array, dimension (min(M,N)) The scalar factors of the elementary reflectors, as returned by ZGEQLF.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (M)
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (2) The test ratios: RESULT(1) = norm( L - Q'*A ) / ( M * norm(A) * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 128 of file zqlt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( * ), rwork( * )
      COMPLEX*16         a( lda, * ), af( lda, * ), l( lda, * ),
     $                   q( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         rogue
      parameter                ( rogue = ( -1.0d+10, -1.0d+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info, minmn
      DOUBLE PRECISION   anorm, eps, resid
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange, zlansy
      EXTERNAL           dlamch, zlange, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zgeqlf, zherk, zlacpy, zlaset, zungql
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max, min
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = dlamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL zlacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'ZGEQLF'
      CALL zgeqlf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL zlaset( 'Full', m, m, rogue, rogue, q, lda )
      IF( m.GE.n ) THEN
         IF( n.LT.m .AND. n.GT.0 )
     $      CALL zlacpy( 'Full', m-n, n, af, lda, q( 1, m-n+1 ), lda )
         IF( n.GT.1 )
     $      CALL zlacpy( 'Upper', n-1, n-1, af( m-n+1, 2 ), lda,
     $                   q( m-n+1, m-n+2 ), lda )
      ELSE
         IF( m.GT.1 )
     $      CALL zlacpy( 'Upper', m-1, m-1, af( 1, n-m+2 ), lda,
     $                   q( 1, 2 ), lda )
      END IF
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'ZUNGQL'
      CALL zungql( m, m, minmn, q, lda, tau, work, lwork, info )
*
*     Copy L
*
      CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( zero ), l,
     $             lda )
      IF( m.GE.n ) THEN
         IF( n.GT.0 )
     $      CALL zlacpy( 'Lower', n, n, af( m-n+1, 1 ), lda,
     $                   l( m-n+1, 1 ), lda )
      ELSE
         IF( n.GT.m .AND. m.GT.0 )
     $      CALL zlacpy( 'Full', m, n-m, af, lda, l, lda )
         IF( m.GT.0 )
     $      CALL zlacpy( 'Lower', m, m, af( 1, n-m+1 ), lda,
     $                   l( 1, n-m+1 ), lda )
      END IF
*
*     Compute L - Q'*A
*
      CALL zgemm( 'Conjugate transpose', 'No transpose', m, n, m,
     $            dcmplx( -one ), q, lda, a, lda, dcmplx( one ), l,
     $            lda )
*
*     Compute norm( L - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = zlange( '1', m, n, a, lda, rwork )
      resid = zlange( '1', m, n, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, m ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( one ), l, lda )
      CALL zherk( 'Upper', 'Conjugate transpose', m, m, -one, q, lda,
     $            one, l, lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = zlansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, m ) ) ) / eps
*
      RETURN
*
*     End of ZQLT01
*

Here is the call graph for this function:

Here is the caller graph for this function: