double precision function zlansy	(	character	NORM,
		character	UPLO,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( * )	WORK
	)

ZLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex symmetric matrix.

Download ZLANSY + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLANSY  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex symmetric matrix A.

Returns

ZLANSY

    ZLANSY = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.

Parameters

[in]	NORM	NORM is CHARACTER*1 Specifies the value to be returned in ZLANSY as described above.
[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is to be referenced. = 'U': Upper triangular part of A is referenced = 'L': Lower triangular part of A is referenced
[in]	N	N is INTEGER The order of the matrix A. N >= 0. When N = 0, ZLANSY is set to zero.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The symmetric matrix A. If UPLO = 'U', the leading n by n upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n by n lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(N,1).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)), where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise, WORK is not referenced.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2015

Definition at line 125 of file zlansy.f.

*
*  -- LAPACK auxiliary routine (version 3.6.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2015
*
*     .. Scalar Arguments ..
      CHARACTER          norm, uplo
      INTEGER            lda, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   work( * )
      COMPLEX*16         a( lda, * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      DOUBLE PRECISION   absa, scale, sum, value
*     ..
*     .. External Functions ..
      LOGICAL            lsame, disnan
      EXTERNAL           lsame, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           zlassq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.EQ.0 ) THEN
         VALUE = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         VALUE = zero
         IF( lsame( uplo, 'U' ) ) THEN
            DO 20 j = 1, n
               DO 10 i = 1, j
                  sum = abs( a( i, j ) )
                  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   10          CONTINUE
   20       CONTINUE
         ELSE
            DO 40 j = 1, n
               DO 30 i = j, n
                  sum = abs( a( i, j ) )
                  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   30          CONTINUE
   40       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
     $         ( norm.EQ.'1' ) ) THEN
*
*        Find normI(A) ( = norm1(A), since A is symmetric).
*
         VALUE = zero
         IF( lsame( uplo, 'U' ) ) THEN
            DO 60 j = 1, n
               sum = zero
               DO 50 i = 1, j - 1
                  absa = abs( a( i, j ) )
                  sum = sum + absa
                  work( i ) = work( i ) + absa
   50          CONTINUE
               work( j ) = sum + abs( a( j, j ) )
   60       CONTINUE
            DO 70 i = 1, n
               sum = work( i )
               IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   70       CONTINUE
         ELSE
            DO 80 i = 1, n
               work( i ) = zero
   80       CONTINUE
            DO 100 j = 1, n
               sum = work( j ) + abs( a( j, j ) )
               DO 90 i = j + 1, n
                  absa = abs( a( i, j ) )
                  sum = sum + absa
                  work( i ) = work( i ) + absa
   90          CONTINUE
               IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
  100       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         scale = zero
         sum = one
         IF( lsame( uplo, 'U' ) ) THEN
            DO 110 j = 2, n
               CALL zlassq( j-1, a( 1, j ), 1, scale, sum )
  110       CONTINUE
         ELSE
            DO 120 j = 1, n - 1
               CALL zlassq( n-j, a( j+1, j ), 1, scale, sum )
  120       CONTINUE
         END IF
         sum = 2*sum
         CALL zlassq( n, a, lda+1, scale, sum )
         VALUE = scale*sqrt( sum )
      END IF
*
      zlansy = VALUE
      RETURN
*
*     End of ZLANSY
*

Here is the call graph for this function:

Here is the caller graph for this function: