dchkbb.f

Go to the documentation of this file.

*> \brief \b DCHKBB
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DCHKBB( NSIZES, MVAL, NVAL, NWDTHS, KK, NTYPES, DOTYPE,
*                          NRHS, ISEED, THRESH, NOUNIT, A, LDA, AB, LDAB,
*                          BD, BE, Q, LDQ, P, LDP, C, LDC, CC, WORK,
*                          LWORK, RESULT, INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDAB, LDC, LDP, LDQ, LWORK, NOUNIT,
*      $                   NRHS, NSIZES, NTYPES, NWDTHS
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            ISEED( 4 ), KK( * ), MVAL( * ), NVAL( * )
*       DOUBLE PRECISION   A( LDA, * ), AB( LDAB, * ), BD( * ), BE( * ),
*      $                   C( LDC, * ), CC( LDC, * ), P( LDP, * ),
*      $                   Q( LDQ, * ), RESULT( * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DCHKBB tests the reduction of a general real rectangular band
*> matrix to bidiagonal form.
*>
*> DGBBRD factors a general band matrix A as  Q B P* , where * means
*> transpose, B is upper bidiagonal, and Q and P are orthogonal;
*> DGBBRD can also overwrite a given matrix C with Q* C .
*>
*> For each pair of matrix dimensions (M,N) and each selected matrix
*> type, an M by N matrix A and an M by NRHS matrix C are generated.
*> The problem dimensions are as follows
*>    A:          M x N
*>    Q:          M x M
*>    P:          N x N
*>    B:          min(M,N) x min(M,N)
*>    C:          M x NRHS
*>
*> For each generated matrix, 4 tests are performed:
*>
*> (1)   | A - Q B PT | / ( |A| max(M,N) ulp ), PT = P'
*>
*> (2)   | I - Q' Q | / ( M ulp )
*>
*> (3)   | I - PT PT' | / ( N ulp )
*>
*> (4)   | Y - Q' C | / ( |Y| max(M,NRHS) ulp ), where Y = Q' C.
*>
*> The "types" are specified by a logical array DOTYPE( 1:NTYPES );
*> if DOTYPE(j) is .TRUE., then matrix type "j" will be generated.
*> Currently, the list of possible types is:
*>
*> The possible matrix types are
*>
*> (1)  The zero matrix.
*> (2)  The identity matrix.
*>
*> (3)  A diagonal matrix with evenly spaced entries
*>      1, ..., ULP  and random signs.
*>      (ULP = (first number larger than 1) - 1 )
*> (4)  A diagonal matrix with geometrically spaced entries
*>      1, ..., ULP  and random signs.
*> (5)  A diagonal matrix with "clustered" entries 1, ULP, ..., ULP
*>      and random signs.
*>
*> (6)  Same as (3), but multiplied by SQRT( overflow threshold )
*> (7)  Same as (3), but multiplied by SQRT( underflow threshold )
*>
*> (8)  A matrix of the form  U D V, where U and V are orthogonal and
*>      D has evenly spaced entries 1, ..., ULP with random signs
*>      on the diagonal.
*>
*> (9)  A matrix of the form  U D V, where U and V are orthogonal and
*>      D has geometrically spaced entries 1, ..., ULP with random
*>      signs on the diagonal.
*>
*> (10) A matrix of the form  U D V, where U and V are orthogonal and
*>      D has "clustered" entries 1, ULP,..., ULP with random
*>      signs on the diagonal.
*>
*> (11) Same as (8), but multiplied by SQRT( overflow threshold )
*> (12) Same as (8), but multiplied by SQRT( underflow threshold )
*>
*> (13) Rectangular matrix with random entries chosen from (-1,1).
*> (14) Same as (13), but multiplied by SQRT( overflow threshold )
*> (15) Same as (13), but multiplied by SQRT( underflow threshold )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NSIZES
*> \verbatim
*>          NSIZES is INTEGER
*>          The number of values of M and N contained in the vectors
*>          MVAL and NVAL.  The matrix sizes are used in pairs (M,N).
*>          If NSIZES is zero, DCHKBB does nothing.  NSIZES must be at
*>          least zero.
*> \endverbatim
*>
*> \param[in] MVAL
*> \verbatim
*>          MVAL is INTEGER array, dimension (NSIZES)
*>          The values of the matrix row dimension M.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NSIZES)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NWDTHS
*> \verbatim
*>          NWDTHS is INTEGER
*>          The number of bandwidths to use.  If it is zero,
*>          DCHKBB does nothing.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] KK
*> \verbatim
*>          KK is INTEGER array, dimension (NWDTHS)
*>          An array containing the bandwidths to be used for the band
*>          matrices.  The values must be at least zero.
*> \endverbatim
*>
*> \param[in] NTYPES
*> \verbatim
*>          NTYPES is INTEGER
*>          The number of elements in DOTYPE.   If it is zero, DCHKBB
*>          does nothing.  It must be at least zero.  If it is MAXTYP+1
*>          and NSIZES is 1, then an additional type, MAXTYP+1 is
*>          defined, which is to use whatever matrix is in A.  This
*>          is only useful if DOTYPE(1:MAXTYP) is .FALSE. and
*>          DOTYPE(MAXTYP+1) is .TRUE. .
*> \endverbatim
*>
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          If DOTYPE(j) is .TRUE., then for each size in NN a
*>          matrix of that size and of type j will be generated.
*>          If NTYPES is smaller than the maximum number of types
*>          defined (PARAMETER MAXTYP), then types NTYPES+1 through
*>          MAXTYP will not be generated.  If NTYPES is larger
*>          than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES)
*>          will be ignored.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of columns in the "right-hand side" matrix C.
*>          If NRHS = 0, then the operations on the right-hand side will
*>          not be tested. NRHS must be at least 0.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry ISEED specifies the seed of the random number
*>          generator. The array elements should be between 0 and 4095;
*>          if not they will be reduced mod 4096.  Also, ISEED(4) must
*>          be odd.  The random number generator uses a linear
*>          congruential sequence limited to small integers, and so
*>          should produce machine independent random numbers. The
*>          values of ISEED are changed on exit, and can be used in the
*>          next call to DCHKBB to continue the same random number
*>          sequence.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          A test will count as "failed" if the "error", computed as
*>          described above, exceeds THRESH.  Note that the error
*>          is scaled to be O(1), so THRESH should be a reasonably
*>          small multiple of 1, e.g., 10 or 100.  In particular,
*>          it should not depend on the precision (single vs. double)
*>          or the size of the matrix.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] NOUNIT
*> \verbatim
*>          NOUNIT is INTEGER
*>          The FORTRAN unit number for printing out error messages
*>          (e.g., if a routine returns IINFO not equal to 0.)
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension
*>                            (LDA, max(NN))
*>          Used to hold the matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A.  It must be at least 1
*>          and at least max( NN ).
*> \endverbatim
*>
*> \param[out] AB
*> \verbatim
*>          AB is DOUBLE PRECISION array, dimension (LDAB, max(NN))
*>          Used to hold A in band storage format.
*> \endverbatim
*>
*> \param[in] LDAB
*> \verbatim
*>          LDAB is INTEGER
*>          The leading dimension of AB.  It must be at least 2 (not 1!)
*>          and at least max( KK )+1.
*> \endverbatim
*>
*> \param[out] BD
*> \verbatim
*>          BD is DOUBLE PRECISION array, dimension (max(NN))
*>          Used to hold the diagonal of the bidiagonal matrix computed
*>          by DGBBRD.
*> \endverbatim
*>
*> \param[out] BE
*> \verbatim
*>          BE is DOUBLE PRECISION array, dimension (max(NN))
*>          Used to hold the off-diagonal of the bidiagonal matrix
*>          computed by DGBBRD.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is DOUBLE PRECISION array, dimension (LDQ, max(NN))
*>          Used to hold the orthogonal matrix Q computed by DGBBRD.
*> \endverbatim
*>
*> \param[in] LDQ
*> \verbatim
*>          LDQ is INTEGER
*>          The leading dimension of Q.  It must be at least 1
*>          and at least max( NN ).
*> \endverbatim
*>
*> \param[out] P
*> \verbatim
*>          P is DOUBLE PRECISION array, dimension (LDP, max(NN))
*>          Used to hold the orthogonal matrix P computed by DGBBRD.
*> \endverbatim
*>
*> \param[in] LDP
*> \verbatim
*>          LDP is INTEGER
*>          The leading dimension of P.  It must be at least 1
*>          and at least max( NN ).
*> \endverbatim
*>
*> \param[out] C
*> \verbatim
*>          C is DOUBLE PRECISION array, dimension (LDC, max(NN))
*>          Used to hold the matrix C updated by DGBBRD.
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*>          LDC is INTEGER
*>          The leading dimension of U.  It must be at least 1
*>          and at least max( NN ).
*> \endverbatim
*>
*> \param[out] CC
*> \verbatim
*>          CC is DOUBLE PRECISION array, dimension (LDC, max(NN))
*>          Used to hold a copy of the matrix C.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The number of entries in WORK.  This must be at least
*>          max( LDA+1, max(NN)+1 )*max(NN).
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (4)
*>          The values computed by the tests described above.
*>          The values are currently limited to 1/ulp, to avoid
*>          overflow.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          If 0, then everything ran OK.
*>
*>-----------------------------------------------------------------------
*>
*>       Some Local Variables and Parameters:
*>       ---- ----- --------- --- ----------
*>       ZERO, ONE       Real 0 and 1.
*>       MAXTYP          The number of types defined.
*>       NTEST           The number of tests performed, or which can
*>                       be performed so far, for the current matrix.
*>       NTESTT          The total number of tests performed so far.
*>       NMAX            Largest value in NN.
*>       NMATS           The number of matrices generated so far.
*>       NERRS           The number of tests which have exceeded THRESH
*>                       so far.
*>       COND, IMODE     Values to be passed to the matrix generators.
*>       ANORM           Norm of A; passed to matrix generators.
*>
*>       OVFL, UNFL      Overflow and underflow thresholds.
*>       ULP, ULPINV     Finest relative precision and its inverse.
*>       RTOVFL, RTUNFL  Square roots of the previous 2 values.
*>               The following four arrays decode JTYPE:
*>       KTYPE(j)        The general type (1-10) for type "j".
*>       KMODE(j)        The MODE value to be passed to the matrix
*>                       generator for type "j".
*>       KMAGN(j)        The order of magnitude ( O(1),
*>                       O(overflow^(1/2) ), O(underflow^(1/2) )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_eig
*
*  =====================================================================
      SUBROUTINE dchkbb( NSIZES, MVAL, NVAL, NWDTHS, KK, NTYPES, DOTYPE,
     $                   nrhs, iseed, thresh, nounit, a, lda, ab, ldab,
     $                   bd, be, q, ldq, p, ldp, c, ldc, cc, work,
     $                   lwork, result, info )
*
*  -- LAPACK test routine (input) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDAB, LDC, LDP, LDQ, LWORK, NOUNIT,
     $                   nrhs, nsizes, ntypes, nwdths
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            ISEED( 4 ), KK( * ), MVAL( * ), NVAL( * )
      DOUBLE PRECISION   A( lda, * ), AB( ldab, * ), BD( * ), BE( * ),
     $                   c( ldc, * ), cc( ldc, * ), p( ldp, * ),
     $                   q( ldq, * ), result( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter                ( zero = 0.0d0, one = 1.0d0 )
      INTEGER            MAXTYP
      parameter                ( maxtyp = 15 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADMM, BADNN, BADNNB
      INTEGER            I, IINFO, IMODE, ITYPE, J, JCOL, JR, JSIZE,
     $                   jtype, jwidth, k, kl, kmax, ku, m, mmax, mnmax,
     $                   mnmin, mtypes, n, nerrs, nmats, nmax, ntest,
     $                   ntestt
      DOUBLE PRECISION   AMNINV, ANORM, COND, OVFL, RTOVFL, RTUNFL, ULP,
     $                   ulpinv, unfl
*     ..
*     .. Local Arrays ..
      INTEGER            IDUMMA( 1 ), IOLDSD( 4 ), KMAGN( maxtyp ),
     $                   kmode( maxtyp ), ktype( maxtyp )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dbdt01, dbdt02, dgbbrd, dlacpy, dlahd2, dlaset,
     $                   dlasum, dlatmr, dlatms, dort01, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min, sqrt
*     ..
*     .. Data statements ..
      DATA               ktype / 1, 2, 5*4, 5*6, 3*9 /
      DATA               kmagn / 2*1, 3*1, 2, 3, 3*1, 2, 3, 1, 2, 3 /
      DATA               kmode / 2*0, 4, 3, 1, 4, 4, 4, 3, 1, 4, 4, 0,
     $                   0, 0 /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      ntestt = 0
      info = 0
*
*     Important constants
*
      badmm = .false.
      badnn = .false.
      mmax = 1
      nmax = 1
      mnmax = 1
      DO 10 j = 1, nsizes
         mmax = max( mmax, mval( j ) )
         IF( mval( j ).LT.0 )
     $      badmm = .true.
         nmax = max( nmax, nval( j ) )
         IF( nval( j ).LT.0 )
     $      badnn = .true.
         mnmax = max( mnmax, min( mval( j ), nval( j ) ) )
   10 CONTINUE
*
      badnnb = .false.
      kmax = 0
      DO 20 j = 1, nwdths
         kmax = max( kmax, kk( j ) )
         IF( kk( j ).LT.0 )
     $      badnnb = .true.
   20 CONTINUE
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badmm ) THEN
         info = -2
      ELSE IF( badnn ) THEN
         info = -3
      ELSE IF( nwdths.LT.0 ) THEN
         info = -4
      ELSE IF( badnnb ) THEN
         info = -5
      ELSE IF( ntypes.LT.0 ) THEN
         info = -6
      ELSE IF( nrhs.LT.0 ) THEN
         info = -8
      ELSE IF( lda.LT.nmax ) THEN
         info = -13
      ELSE IF( ldab.LT.2*kmax+1 ) THEN
         info = -15
      ELSE IF( ldq.LT.nmax ) THEN
         info = -19
      ELSE IF( ldp.LT.nmax ) THEN
         info = -21
      ELSE IF( ldc.LT.nmax ) THEN
         info = -23
      ELSE IF( ( max( lda, nmax )+1 )*nmax.GT.lwork ) THEN
         info = -26
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DCHKBB', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 .OR. nwdths.EQ.0 )
     $   RETURN
*
*     More Important constants
*
      unfl = dlamch( 'Safe minimum' )
      ovfl = one / unfl
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
      ulpinv = one / ulp
      rtunfl = sqrt( unfl )
      rtovfl = sqrt( ovfl )
*
*     Loop over sizes, widths, types
*
      nerrs = 0
      nmats = 0
*
      DO 160 jsize = 1, nsizes
         m = mval( jsize )
         n = nval( jsize )
         mnmin = min( m, n )
         amninv = one / dble( max( 1, m, n ) )
*
         DO 150 jwidth = 1, nwdths
            k = kk( jwidth )
            IF( k.GE.m .AND. k.GE.n )
     $         GO TO 150
            kl = max( 0, min( m-1, k ) )
            ku = max( 0, min( n-1, k ) )
*
            IF( nsizes.NE.1 ) THEN
               mtypes = min( maxtyp, ntypes )
            ELSE
               mtypes = min( maxtyp+1, ntypes )
            END IF
*
            DO 140 jtype = 1, mtypes
               IF( .NOT.dotype( jtype ) )
     $            GO TO 140
               nmats = nmats + 1
               ntest = 0
*
               DO 30 j = 1, 4
                  ioldsd( j ) = iseed( j )
   30          CONTINUE
*
*              Compute "A".
*
*              Control parameters:
*
*                  KMAGN  KMODE        KTYPE
*              =1  O(1)   clustered 1  zero
*              =2  large  clustered 2  identity
*              =3  small  exponential  (none)
*              =4         arithmetic   diagonal, (w/ singular values)
*              =5         random log   (none)
*              =6         random       nonhermitian, w/ singular values
*              =7                      (none)
*              =8                      (none)
*              =9                      random nonhermitian
*
               IF( mtypes.GT.maxtyp )
     $            GO TO 90
*
               itype = ktype( jtype )
               imode = kmode( jtype )
*
*              Compute norm
*
               GO TO ( 40, 50, 60 )kmagn( jtype )
*
   40          CONTINUE
               anorm = one
               GO TO 70
*
   50          CONTINUE
               anorm = ( rtovfl*ulp )*amninv
               GO TO 70
*
   60          CONTINUE
               anorm = rtunfl*max( m, n )*ulpinv
               GO TO 70
*
   70          CONTINUE
*
               CALL dlaset( 'Full', lda, n, zero, zero, a, lda )
               CALL dlaset( 'Full', ldab, n, zero, zero, ab, ldab )
               iinfo = 0
               cond = ulpinv
*
*              Special Matrices -- Identity & Jordan block
*
*                 Zero
*
               IF( itype.EQ.1 ) THEN
                  iinfo = 0
*
               ELSE IF( itype.EQ.2 ) THEN
*
*                 Identity
*
                  DO 80 jcol = 1, n
                     a( jcol, jcol ) = anorm
   80             CONTINUE
*
               ELSE IF( itype.EQ.4 ) THEN
*
*                 Diagonal Matrix, singular values specified
*
                  CALL dlatms( m, n, 'S', iseed, 'N', work, imode, cond,
     $                         anorm, 0, 0, 'N', a, lda, work( m+1 ),
     $                         iinfo )
*
               ELSE IF( itype.EQ.6 ) THEN
*
*                 Nonhermitian, singular values specified
*
                  CALL dlatms( m, n, 'S', iseed, 'N', work, imode, cond,
     $                         anorm, kl, ku, 'N', a, lda, work( m+1 ),
     $                         iinfo )
*
               ELSE IF( itype.EQ.9 ) THEN
*
*                 Nonhermitian, random entries
*
                  CALL dlatmr( m, n, 'S', iseed, 'N', work, 6, one, one,
     $                         'T', 'N', work( n+1 ), 1, one,
     $                         work( 2*n+1 ), 1, one, 'N', idumma, kl,
     $                         ku, zero, anorm, 'N', a, lda, idumma,
     $                         iinfo )
*
               ELSE
*
                  iinfo = 1
               END IF
*
*              Generate Right-Hand Side
*
               CALL dlatmr( m, nrhs, 'S', iseed, 'N', work, 6, one, one,
     $                      'T', 'N', work( m+1 ), 1, one,
     $                      work( 2*m+1 ), 1, one, 'N', idumma, m, nrhs,
     $                      zero, one, 'NO', c, ldc, idumma, iinfo )
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nounit, fmt = 9999 )'Generator', iinfo, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  RETURN
               END IF
*
   90          CONTINUE
*
*              Copy A to band storage.
*
               DO 110 j = 1, n
                  DO 100 i = max( 1, j-ku ), min( m, j+kl )
                     ab( ku+1+i-j, j ) = a( i, j )
  100             CONTINUE
  110          CONTINUE
*
*              Copy C
*
               CALL dlacpy( 'Full', m, nrhs, c, ldc, cc, ldc )
*
*              Call DGBBRD to compute B, Q and P, and to update C.
*
               CALL dgbbrd( 'B', m, n, nrhs, kl, ku, ab, ldab, bd, be,
     $                      q, ldq, p, ldp, cc, ldc, work, iinfo )
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nounit, fmt = 9999 )'DGBBRD', iinfo, n, jtype,
     $               ioldsd
                  info = abs( iinfo )
                  IF( iinfo.LT.0 ) THEN
                     RETURN
                  ELSE
                     result( 1 ) = ulpinv
                     GO TO 120
                  END IF
               END IF
*
*              Test 1:  Check the decomposition A := Q * B * P'
*                   2:  Check the orthogonality of Q
*                   3:  Check the orthogonality of P
*                   4:  Check the computation of Q' * C
*
               CALL dbdt01( m, n, -1, a, lda, q, ldq, bd, be, p, ldp,
     $                      work, result( 1 ) )
               CALL dort01( 'Columns', m, m, q, ldq, work, lwork,
     $                      result( 2 ) )
               CALL dort01( 'Rows', n, n, p, ldp, work, lwork,
     $                      result( 3 ) )
               CALL dbdt02( m, nrhs, c, ldc, cc, ldc, q, ldq, work,
     $                      result( 4 ) )
*
*              End of Loop -- Check for RESULT(j) > THRESH
*
               ntest = 4
  120          CONTINUE
               ntestt = ntestt + ntest
*
*              Print out tests which fail.
*
               DO 130 jr = 1, ntest
                  IF( result( jr ).GE.thresh ) THEN
                     IF( nerrs.EQ.0 )
     $                  CALL dlahd2( nounit, 'DBB' )
                     nerrs = nerrs + 1
                     WRITE( nounit, fmt = 9998 )m, n, k, ioldsd, jtype,
     $                  jr, result( jr )
                  END IF
  130          CONTINUE
*
  140       CONTINUE
  150    CONTINUE
  160 CONTINUE
*
*     Summary
*
      CALL dlasum( 'DBB', nounit, nerrs, ntestt )
      RETURN
*
 9999 FORMAT( ' DCHKBB: ', a, ' returned INFO=', i5, '.', / 9x, 'M=',
     $      i5, ' N=', i5, ' K=', i5, ', JTYPE=', i5, ', ISEED=(',
     $      3( i5, ',' ), i5, ')' )
 9998 FORMAT( ' M =', i4, ' N=', i4, ', K=', i3, ', seed=',
     $      4( i4, ',' ), ' type ', i2, ', test(', i2, ')=', g10.3 )
*
*     End of DCHKBB
*
      END