dgbbrd.f

Go to the documentation of this file.

*> \brief \b DGBBRD
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download DGBBRD + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgbbrd.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgbbrd.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgbbrd.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DGBBRD( VECT, M, N, NCC, KL, KU, AB, LDAB, D, E, Q,
*                          LDQ, PT, LDPT, C, LDC, WORK, INFO )
* 
*       .. Scalar Arguments ..
*       CHARACTER          VECT
*       INTEGER            INFO, KL, KU, LDAB, LDC, LDPT, LDQ, M, N, NCC
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   AB( LDAB, * ), C( LDC, * ), D( * ), E( * ),
*      $                   PT( LDPT, * ), Q( LDQ, * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DGBBRD reduces a real general m-by-n band matrix A to upper
*> bidiagonal form B by an orthogonal transformation: Q**T * A * P = B.
*>
*> The routine computes B, and optionally forms Q or P**T, or computes
*> Q**T*C for a given matrix C.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] VECT
*> \verbatim
*>          VECT is CHARACTER*1
*>          Specifies whether or not the matrices Q and P**T are to be
*>          formed.
*>          = 'N': do not form Q or P**T;
*>          = 'Q': form Q only;
*>          = 'P': form P**T only;
*>          = 'B': form both.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NCC
*> \verbatim
*>          NCC is INTEGER
*>          The number of columns of the matrix C.  NCC >= 0.
*> \endverbatim
*>
*> \param[in] KL
*> \verbatim
*>          KL is INTEGER
*>          The number of subdiagonals of the matrix A. KL >= 0.
*> \endverbatim
*>
*> \param[in] KU
*> \verbatim
*>          KU is INTEGER
*>          The number of superdiagonals of the matrix A. KU >= 0.
*> \endverbatim
*>
*> \param[in,out] AB
*> \verbatim
*>          AB is DOUBLE PRECISION array, dimension (LDAB,N)
*>          On entry, the m-by-n band matrix A, stored in rows 1 to
*>          KL+KU+1. The j-th column of A is stored in the j-th column of
*>          the array AB as follows:
*>          AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(m,j+kl).
*>          On exit, A is overwritten by values generated during the
*>          reduction.
*> \endverbatim
*>
*> \param[in] LDAB
*> \verbatim
*>          LDAB is INTEGER
*>          The leading dimension of the array A. LDAB >= KL+KU+1.
*> \endverbatim
*>
*> \param[out] D
*> \verbatim
*>          D is DOUBLE PRECISION array, dimension (min(M,N))
*>          The diagonal elements of the bidiagonal matrix B.
*> \endverbatim
*>
*> \param[out] E
*> \verbatim
*>          E is DOUBLE PRECISION array, dimension (min(M,N)-1)
*>          The superdiagonal elements of the bidiagonal matrix B.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is DOUBLE PRECISION array, dimension (LDQ,M)
*>          If VECT = 'Q' or 'B', the m-by-m orthogonal matrix Q.
*>          If VECT = 'N' or 'P', the array Q is not referenced.
*> \endverbatim
*>
*> \param[in] LDQ
*> \verbatim
*>          LDQ is INTEGER
*>          The leading dimension of the array Q.
*>          LDQ >= max(1,M) if VECT = 'Q' or 'B'; LDQ >= 1 otherwise.
*> \endverbatim
*>
*> \param[out] PT
*> \verbatim
*>          PT is DOUBLE PRECISION array, dimension (LDPT,N)
*>          If VECT = 'P' or 'B', the n-by-n orthogonal matrix P'.
*>          If VECT = 'N' or 'Q', the array PT is not referenced.
*> \endverbatim
*>
*> \param[in] LDPT
*> \verbatim
*>          LDPT is INTEGER
*>          The leading dimension of the array PT.
*>          LDPT >= max(1,N) if VECT = 'P' or 'B'; LDPT >= 1 otherwise.
*> \endverbatim
*>
*> \param[in,out] C
*> \verbatim
*>          C is DOUBLE PRECISION array, dimension (LDC,NCC)
*>          On entry, an m-by-ncc matrix C.
*>          On exit, C is overwritten by Q**T*C.
*>          C is not referenced if NCC = 0.
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*>          LDC is INTEGER
*>          The leading dimension of the array C.
*>          LDC >= max(1,M) if NCC > 0; LDC >= 1 if NCC = 0.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (2*max(M,N))
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup doubleGBcomputational
*
*  =====================================================================
      SUBROUTINE dgbbrd( VECT, M, N, NCC, KL, KU, AB, LDAB, D, E, Q,
     $                   ldq, pt, ldpt, c, ldc, work, info )
*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          VECT
      INTEGER            INFO, KL, KU, LDAB, LDC, LDPT, LDQ, M, N, NCC
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AB( ldab, * ), C( ldc, * ), D( * ), E( * ),
     $                   pt( ldpt, * ), q( ldq, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            WANTB, WANTC, WANTPT, WANTQ
      INTEGER            I, INCA, J, J1, J2, KB, KB1, KK, KLM, KLU1,
     $                   kun, l, minmn, ml, ml0, mn, mu, mu0, nr, nrt
      DOUBLE PRECISION   RA, RB, RC, RS
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlargv, dlartg, dlartv, dlaset, drot, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      wantb = lsame( vect, 'B' )
      wantq = lsame( vect, 'Q' ) .OR. wantb
      wantpt = lsame( vect, 'P' ) .OR. wantb
      wantc = ncc.GT.0
      klu1 = kl + ku + 1
      info = 0
      IF( .NOT.wantq .AND. .NOT.wantpt .AND. .NOT.lsame( vect, 'N' ) )
     $     THEN
         info = -1
      ELSE IF( m.LT.0 ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( ncc.LT.0 ) THEN
         info = -4
      ELSE IF( kl.LT.0 ) THEN
         info = -5
      ELSE IF( ku.LT.0 ) THEN
         info = -6
      ELSE IF( ldab.LT.klu1 ) THEN
         info = -8
      ELSE IF( ldq.LT.1 .OR. wantq .AND. ldq.LT.max( 1, m ) ) THEN
         info = -12
      ELSE IF( ldpt.LT.1 .OR. wantpt .AND. ldpt.LT.max( 1, n ) ) THEN
         info = -14
      ELSE IF( ldc.LT.1 .OR. wantc .AND. ldc.LT.max( 1, m ) ) THEN
         info = -16
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGBBRD', -info )
         RETURN
      END IF
*
*     Initialize Q and P**T to the unit matrix, if needed
*
      IF( wantq )
     $   CALL dlaset( 'Full', m, m, zero, one, q, ldq )
      IF( wantpt )
     $   CALL dlaset( 'Full', n, n, zero, one, pt, ldpt )
*
*     Quick return if possible.
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
      minmn = min( m, n )
*
      IF( kl+ku.GT.1 ) THEN
*
*        Reduce to upper bidiagonal form if KU > 0; if KU = 0, reduce
*        first to lower bidiagonal form and then transform to upper
*        bidiagonal
*
         IF( ku.GT.0 ) THEN
            ml0 = 1
            mu0 = 2
         ELSE
            ml0 = 2
            mu0 = 1
         END IF
*
*        Wherever possible, plane rotations are generated and applied in
*        vector operations of length NR over the index set J1:J2:KLU1.
*
*        The sines of the plane rotations are stored in WORK(1:max(m,n))
*        and the cosines in WORK(max(m,n)+1:2*max(m,n)).
*
         mn = max( m, n )
         klm = min( m-1, kl )
         kun = min( n-1, ku )
         kb = klm + kun
         kb1 = kb + 1
         inca = kb1*ldab
         nr = 0
         j1 = klm + 2
         j2 = 1 - kun
*
         DO 90 i = 1, minmn
*
*           Reduce i-th column and i-th row of matrix to bidiagonal form
*
            ml = klm + 1
            mu = kun + 1
            DO 80 kk = 1, kb
               j1 = j1 + kb
               j2 = j2 + kb
*
*              generate plane rotations to annihilate nonzero elements
*              which have been created below the band
*
               IF( nr.GT.0 )
     $            CALL dlargv( nr, ab( klu1, j1-klm-1 ), inca,
     $                         work( j1 ), kb1, work( mn+j1 ), kb1 )
*
*              apply plane rotations from the left
*
               DO 10 l = 1, kb
                  IF( j2-klm+l-1.GT.n ) THEN
                     nrt = nr - 1
                  ELSE
                     nrt = nr
                  END IF
                  IF( nrt.GT.0 )
     $               CALL dlartv( nrt, ab( klu1-l, j1-klm+l-1 ), inca,
     $                            ab( klu1-l+1, j1-klm+l-1 ), inca,
     $                            work( mn+j1 ), work( j1 ), kb1 )
   10          CONTINUE
*
               IF( ml.GT.ml0 ) THEN
                  IF( ml.LE.m-i+1 ) THEN
*
*                    generate plane rotation to annihilate a(i+ml-1,i)
*                    within the band, and apply rotation from the left
*
                     CALL dlartg( ab( ku+ml-1, i ), ab( ku+ml, i ),
     $                            work( mn+i+ml-1 ), work( i+ml-1 ),
     $                            ra )
                     ab( ku+ml-1, i ) = ra
                     IF( i.LT.n )
     $                  CALL drot( min( ku+ml-2, n-i ),
     $                             ab( ku+ml-2, i+1 ), ldab-1,
     $                             ab( ku+ml-1, i+1 ), ldab-1,
     $                             work( mn+i+ml-1 ), work( i+ml-1 ) )
                  END IF
                  nr = nr + 1
                  j1 = j1 - kb1
               END IF
*
               IF( wantq ) THEN
*
*                 accumulate product of plane rotations in Q
*
                  DO 20 j = j1, j2, kb1
                     CALL drot( m, q( 1, j-1 ), 1, q( 1, j ), 1,
     $                          work( mn+j ), work( j ) )
   20             CONTINUE
               END IF
*
               IF( wantc ) THEN
*
*                 apply plane rotations to C
*
                  DO 30 j = j1, j2, kb1
                     CALL drot( ncc, c( j-1, 1 ), ldc, c( j, 1 ), ldc,
     $                          work( mn+j ), work( j ) )
   30             CONTINUE
               END IF
*
               IF( j2+kun.GT.n ) THEN
*
*                 adjust J2 to keep within the bounds of the matrix
*
                  nr = nr - 1
                  j2 = j2 - kb1
               END IF
*
               DO 40 j = j1, j2, kb1
*
*                 create nonzero element a(j-1,j+ku) above the band
*                 and store it in WORK(n+1:2*n)
*
                  work( j+kun ) = work( j )*ab( 1, j+kun )
                  ab( 1, j+kun ) = work( mn+j )*ab( 1, j+kun )
   40          CONTINUE
*
*              generate plane rotations to annihilate nonzero elements
*              which have been generated above the band
*
               IF( nr.GT.0 )
     $            CALL dlargv( nr, ab( 1, j1+kun-1 ), inca,
     $                         work( j1+kun ), kb1, work( mn+j1+kun ),
     $                         kb1 )
*
*              apply plane rotations from the right
*
               DO 50 l = 1, kb
                  IF( j2+l-1.GT.m ) THEN
                     nrt = nr - 1
                  ELSE
                     nrt = nr
                  END IF
                  IF( nrt.GT.0 )
     $               CALL dlartv( nrt, ab( l+1, j1+kun-1 ), inca,
     $                            ab( l, j1+kun ), inca,
     $                            work( mn+j1+kun ), work( j1+kun ),
     $                            kb1 )
   50          CONTINUE
*
               IF( ml.EQ.ml0 .AND. mu.GT.mu0 ) THEN
                  IF( mu.LE.n-i+1 ) THEN
*
*                    generate plane rotation to annihilate a(i,i+mu-1)
*                    within the band, and apply rotation from the right
*
                     CALL dlartg( ab( ku-mu+3, i+mu-2 ),
     $                            ab( ku-mu+2, i+mu-1 ),
     $                            work( mn+i+mu-1 ), work( i+mu-1 ),
     $                            ra )
                     ab( ku-mu+3, i+mu-2 ) = ra
                     CALL drot( min( kl+mu-2, m-i ),
     $                          ab( ku-mu+4, i+mu-2 ), 1,
     $                          ab( ku-mu+3, i+mu-1 ), 1,
     $                          work( mn+i+mu-1 ), work( i+mu-1 ) )
                  END IF
                  nr = nr + 1
                  j1 = j1 - kb1
               END IF
*
               IF( wantpt ) THEN
*
*                 accumulate product of plane rotations in P**T
*
                  DO 60 j = j1, j2, kb1
                     CALL drot( n, pt( j+kun-1, 1 ), ldpt,
     $                          pt( j+kun, 1 ), ldpt, work( mn+j+kun ),
     $                          work( j+kun ) )
   60             CONTINUE
               END IF
*
               IF( j2+kb.GT.m ) THEN
*
*                 adjust J2 to keep within the bounds of the matrix
*
                  nr = nr - 1
                  j2 = j2 - kb1
               END IF
*
               DO 70 j = j1, j2, kb1
*
*                 create nonzero element a(j+kl+ku,j+ku-1) below the
*                 band and store it in WORK(1:n)
*
                  work( j+kb ) = work( j+kun )*ab( klu1, j+kun )
                  ab( klu1, j+kun ) = work( mn+j+kun )*ab( klu1, j+kun )
   70          CONTINUE
*
               IF( ml.GT.ml0 ) THEN
                  ml = ml - 1
               ELSE
                  mu = mu - 1
               END IF
   80       CONTINUE
   90    CONTINUE
      END IF
*
      IF( ku.EQ.0 .AND. kl.GT.0 ) THEN
*
*        A has been reduced to lower bidiagonal form
*
*        Transform lower bidiagonal form to upper bidiagonal by applying
*        plane rotations from the left, storing diagonal elements in D
*        and off-diagonal elements in E
*
         DO 100 i = 1, min( m-1, n )
            CALL dlartg( ab( 1, i ), ab( 2, i ), rc, rs, ra )
            d( i ) = ra
            IF( i.LT.n ) THEN
               e( i ) = rs*ab( 1, i+1 )
               ab( 1, i+1 ) = rc*ab( 1, i+1 )
            END IF
            IF( wantq )
     $         CALL drot( m, q( 1, i ), 1, q( 1, i+1 ), 1, rc, rs )
            IF( wantc )
     $         CALL drot( ncc, c( i, 1 ), ldc, c( i+1, 1 ), ldc, rc,
     $                    rs )
  100    CONTINUE
         IF( m.LE.n )
     $      d( m ) = ab( 1, m )
      ELSE IF( ku.GT.0 ) THEN
*
*        A has been reduced to upper bidiagonal form
*
         IF( m.LT.n ) THEN
*
*           Annihilate a(m,m+1) by applying plane rotations from the
*           right, storing diagonal elements in D and off-diagonal
*           elements in E
*
            rb = ab( ku, m+1 )
            DO 110 i = m, 1, -1
               CALL dlartg( ab( ku+1, i ), rb, rc, rs, ra )
               d( i ) = ra
               IF( i.GT.1 ) THEN
                  rb = -rs*ab( ku, i )
                  e( i-1 ) = rc*ab( ku, i )
               END IF
               IF( wantpt )
     $            CALL drot( n, pt( i, 1 ), ldpt, pt( m+1, 1 ), ldpt,
     $                       rc, rs )
  110       CONTINUE
         ELSE
*
*           Copy off-diagonal elements to E and diagonal elements to D
*
            DO 120 i = 1, minmn - 1
               e( i ) = ab( ku, i+1 )
  120       CONTINUE
            DO 130 i = 1, minmn
               d( i ) = ab( ku+1, i )
  130       CONTINUE
         END IF
      ELSE
*
*        A is diagonal. Set elements of E to zero and copy diagonal
*        elements to D.
*
         DO 140 i = 1, minmn - 1
            e( i ) = zero
  140    CONTINUE
         DO 150 i = 1, minmn
            d( i ) = ab( 1, i )
  150    CONTINUE
      END IF
      RETURN
*
*     End of DGBBRD
*
      END