subroutine clarge	(	integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		integer, dimension( 4 )	ISEED,
		complex, dimension( * )	WORK,
		integer	INFO
	)

CLARGE

Purpose:

 CLARGE pre- and post-multiplies a complex general n by n matrix A
 with a random unitary matrix: A = U*D*U'.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the original n by n matrix A. On exit, A is overwritten by U*A*U' for some random unitary matrix U.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= N.
[in,out]	ISEED	ISEED is INTEGER array, dimension (4) On entry, the seed of the random number generator; the array elements must be between 0 and 4095, and ISEED(4) must be odd. On exit, the seed is updated.
[out]	WORK	WORK is COMPLEX array, dimension (2*N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 89 of file clarge.f.

*
*  -- LAPACK auxiliary routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, n
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 )
      COMPLEX            a( lda, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            zero, one
      parameter                ( zero = ( 0.0e+0, 0.0e+0 ),
     $                   one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i
      REAL               wn
      COMPLEX            tau, wa, wb
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, cgerc, clarnv, cscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, real
*     ..
*     .. External Functions ..
      REAL               scnrm2
      EXTERNAL           scnrm2
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -3
      END IF
      IF( info.LT.0 ) THEN
         CALL xerbla( 'CLARGE', -info )
         RETURN
      END IF
*
*     pre- and post-multiply A by random unitary matrix
*
      DO 10 i = n, 1, -1
*
*        generate random reflection
*
         CALL clarnv( 3, iseed, n-i+1, work )
         wn = scnrm2( n-i+1, work, 1 )
         wa = ( wn / abs( work( 1 ) ) )*work( 1 )
         IF( wn.EQ.zero ) THEN
            tau = zero
         ELSE
            wb = work( 1 ) + wa
            CALL cscal( n-i, one / wb, work( 2 ), 1 )
            work( 1 ) = one
            tau = REAL( wb / wa )
         END IF
*
*        multiply A(i:n,1:n) by random reflection from the left
*
         CALL cgemv( 'Conjugate transpose', n-i+1, n, one, a( i, 1 ),
     $               lda, work, 1, zero, work( n+1 ), 1 )
         CALL cgerc( n-i+1, n, -tau, work, 1, work( n+1 ), 1, a( i, 1 ),
     $               lda )
*
*        multiply A(1:n,i:n) by random reflection from the right
*
         CALL cgemv( 'No transpose', n, n-i+1, one, a( 1, i ), lda,
     $               work, 1, zero, work( n+1 ), 1 )
         CALL cgerc( n, n-i+1, -tau, work( n+1 ), 1, work, 1, a( 1, i ),
     $               lda )
   10 CONTINUE
      RETURN
*
*     End of CLARGE
*

Here is the call graph for this function:

Here is the caller graph for this function: