real function scnrm2	(	integer	N,
		complex, dimension(*)	X,
		integer	INCX
	)

SCNRM2

Purpose:

 SCNRM2 returns the euclidean norm of a vector via the function
 name, so that

    SCNRM2 := sqrt( x**H*x )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Further Details:

  -- This version written on 25-October-1982.
     Modified on 14-October-1993 to inline the call to CLASSQ.
     Sven Hammarling, Nag Ltd.

Definition at line 56 of file scnrm2.f.

*
*  -- Reference BLAS level1 routine (version 3.4.0) --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER incx,n
*     ..
*     .. Array Arguments ..
      COMPLEX x(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL one,zero
      parameter(one=1.0e+0,zero=0.0e+0)
*     ..
*     .. Local Scalars ..
      REAL norm,scale,ssq,temp
      INTEGER ix
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC abs,aimag,REAL,sqrt
*     ..
      IF (n.LT.1 .OR. incx.LT.1) THEN
          norm = zero
      ELSE
          scale = zero
          ssq = one
*        The following loop is equivalent to this call to the LAPACK
*        auxiliary routine:
*        CALL CLASSQ( N, X, INCX, SCALE, SSQ )
*
          DO 10 ix = 1,1 + (n-1)*incx,incx
              IF (REAL(x(ix)).NE.zero) then
                  temp = abs(REAL(x(ix)))
                  IF (scale.LT.temp) THEN
                      ssq = one + ssq* (scale/temp)**2
                      scale = temp
                  ELSE
                      ssq = ssq + (temp/scale)**2
                  END IF
              END IF
              IF (aimag(x(ix)).NE.zero) THEN
                  temp = abs(aimag(x(ix)))
                  IF (scale.LT.temp) THEN
                      ssq = one + ssq* (scale/temp)**2
                      scale = temp
                  ELSE
                      ssq = ssq + (temp/scale)**2
                  END IF
              END IF
   10     CONTINUE
          norm = scale*sqrt(ssq)
      END IF
*
      scnrm2 = norm
      RETURN
*
*     End of SCNRM2.
*

Here is the caller graph for this function: