zchkge.f

Go to the documentation of this file.

*> \brief \b ZCHKGE
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZCHKGE( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NNS,
*                          NSVAL, THRESH, TSTERR, NMAX, A, AFAC, AINV, B,
*                          X, XACT, WORK, RWORK, IWORK, NOUT )
* 
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NM, NMAX, NN, NNB, NNS, NOUT
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), MVAL( * ), NBVAL( * ), NSVAL( * ),
*      $                   NVAL( * )
*       DOUBLE PRECISION   RWORK( * )
*       COMPLEX*16         A( * ), AFAC( * ), AINV( * ), B( * ),
*      $                   WORK( * ), X( * ), XACT( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZCHKGE tests ZGETRF, -TRI, -TRS, -RFS, and -CON.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NM
*> \verbatim
*>          NM is INTEGER
*>          The number of values of M contained in the vector MVAL.
*> \endverbatim
*>
*> \param[in] MVAL
*> \verbatim
*>          MVAL is INTEGER array, dimension (NM)
*>          The values of the matrix row dimension M.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NNB
*> \verbatim
*>          NNB is INTEGER
*>          The number of values of NB contained in the vector NBVAL.
*> \endverbatim
*>
*> \param[in] NBVAL
*> \verbatim
*>          NBVAL is INTEGER array, dimension (NBVAL)
*>          The values of the blocksize NB.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for M or N, used in dimensioning
*>          the work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AFAC
*> \verbatim
*>          AFAC is COMPLEX*16 array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AINV
*> \verbatim
*>          AINV is COMPLEX*16 array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is COMPLEX*16 array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is COMPLEX*16 array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension
*>                      (NMAX*max(3,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension
*>                      (max(2*NMAX,2*NSMAX+NWORK))
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zchkge( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NNS,
     $                   nsval, thresh, tsterr, nmax, a, afac, ainv, b,
     $                   x, xact, work, rwork, iwork, nout )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NM, NMAX, NN, NNB, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), MVAL( * ), NBVAL( * ), NSVAL( * ),
     $                   nval( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   work( * ), x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
      INTEGER            NTYPES
      parameter                ( ntypes = 11 )
      INTEGER            NTESTS
      parameter                ( ntests = 8 )
      INTEGER            NTRAN
      parameter                ( ntran = 3 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, NORM, TRANS, TYPE, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IM, IMAT, IN, INB, INFO, IOFF, IRHS, ITRAN,
     $                   izero, k, kl, ku, lda, lwork, m, mode, n, nb,
     $                   nerrs, nfail, nimat, nrhs, nrun, nt
      DOUBLE PRECISION   AINVNM, ANORM, ANORMI, ANORMO, CNDNUM, DUMMY,
     $                   rcond, rcondc, rcondi, rcondo
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( ntran )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( ntests )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DGET06, ZLANGE
      EXTERNAL           dget06, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, xlaenv, zerrge, zgecon,
     $                   zgerfs, zget01, zget02, zget03, zget04, zget07,
     $                   zgetrf, zgetri, zgetrs, zlacpy, zlarhs, zlaset,
     $                   zlatb4, zlatms
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dcmplx, max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 / ,
     $                   transs / 'N', 'T', 'C' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'GE'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      CALL xlaenv( 1, 1 )
      IF( tsterr )
     $   CALL zerrge( path, nout )
      infot = 0
      CALL xlaenv( 2, 2 )
*
*     Do for each value of M in MVAL
*
      DO 120 im = 1, nm
         m = mval( im )
         lda = max( 1, m )
*
*        Do for each value of N in NVAL
*
         DO 110 in = 1, nn
            n = nval( in )
            xtype = 'N'
            nimat = ntypes
            IF( m.LE.0 .OR. n.LE.0 )
     $         nimat = 1
*
            DO 100 imat = 1, nimat
*
*              Do the tests only if DOTYPE( IMAT ) is true.
*
               IF( .NOT.dotype( imat ) )
     $            GO TO 100
*
*              Skip types 5, 6, or 7 if the matrix size is too small.
*
               zerot = imat.GE.5 .AND. imat.LE.7
               IF( zerot .AND. n.LT.imat-4 )
     $            GO TO 100
*
*              Set up parameters with ZLATB4 and generate a test matrix
*              with ZLATMS.
*
               CALL zlatb4( path, imat, m, n, TYPE, KL, KU, ANORM, MODE,
     $                      cndnum, dist )
*
               srnamt = 'ZLATMS'
               CALL zlatms( m, n, dist, iseed, TYPE, RWORK, MODE,
     $                      cndnum, anorm, kl, ku, 'No packing', a, lda,
     $                      work, info )
*
*              Check error code from ZLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'ZLATMS', info, 0, ' ', m, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
                  GO TO 100
               END IF
*
*              For types 5-7, zero one or more columns of the matrix to
*              test that INFO is returned correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.5 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.6 ) THEN
                     izero = min( m, n )
                  ELSE
                     izero = min( m, n ) / 2 + 1
                  END IF
                  ioff = ( izero-1 )*lda
                  IF( imat.LT.7 ) THEN
                     DO 20 i = 1, m
                        a( ioff+i ) = zero
   20                CONTINUE
                  ELSE
                     CALL zlaset( 'Full', m, n-izero+1, dcmplx( zero ),
     $                            dcmplx( zero ), a( ioff+1 ), lda )
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              These lines, if used in place of the calls in the DO 60
*              loop, cause the code to bomb on a Sun SPARCstation.
*
*               ANORMO = ZLANGE( 'O', M, N, A, LDA, RWORK )
*               ANORMI = ZLANGE( 'I', M, N, A, LDA, RWORK )
*
*              Do for each blocksize in NBVAL
*
               DO 90 inb = 1, nnb
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
*
*                 Compute the LU factorization of the matrix.
*
                  CALL zlacpy( 'Full', m, n, a, lda, afac, lda )
                  srnamt = 'ZGETRF'
                  CALL zgetrf( m, n, afac, lda, iwork, info )
*
*                 Check error code from ZGETRF.
*
                  IF( info.NE.izero )
     $               CALL alaerh( path, 'ZGETRF', info, izero, ' ', m,
     $                            n, -1, -1, nb, imat, nfail, nerrs,
     $                            nout )
                  trfcon = .false.
*
*+    TEST 1
*                 Reconstruct matrix from factors and compute residual.
*
                  CALL zlacpy( 'Full', m, n, afac, lda, ainv, lda )
                  CALL zget01( m, n, a, lda, ainv, lda, iwork, rwork,
     $                         result( 1 ) )
                  nt = 1
*
*+    TEST 2
*                 Form the inverse if the factorization was successful
*                 and compute the residual.
*
                  IF( m.EQ.n .AND. info.EQ.0 ) THEN
                     CALL zlacpy( 'Full', n, n, afac, lda, ainv, lda )
                     srnamt = 'ZGETRI'
                     nrhs = nsval( 1 )
                     lwork = nmax*max( 3, nrhs )
                     CALL zgetri( n, ainv, lda, iwork, work, lwork,
     $                            info )
*
*                    Check error code from ZGETRI.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZGETRI', info, 0, ' ', n, n,
     $                               -1, -1, nb, imat, nfail, nerrs,
     $                               nout )
*
*                    Compute the residual for the matrix times its
*                    inverse.  Also compute the 1-norm condition number
*                    of A.
*
                     CALL zget03( n, a, lda, ainv, lda, work, lda,
     $                            rwork, rcondo, result( 2 ) )
                     anormo = zlange( 'O', m, n, a, lda, rwork )
*
*                    Compute the infinity-norm condition number of A.
*
                     anormi = zlange( 'I', m, n, a, lda, rwork )
                     ainvnm = zlange( 'I', n, n, ainv, lda, rwork )
                     IF( anormi.LE.zero .OR. ainvnm.LE.zero ) THEN
                        rcondi = one
                     ELSE
                        rcondi = ( one / anormi ) / ainvnm
                     END IF
                     nt = 2
                  ELSE
*
*                    Do only the condition estimate if INFO > 0.
*
                     trfcon = .true.
                     anormo = zlange( 'O', m, n, a, lda, rwork )
                     anormi = zlange( 'I', m, n, a, lda, rwork )
                     rcondo = zero
                     rcondi = zero
                  END IF
*
*                 Print information about the tests so far that did not
*                 pass the threshold.
*
                  DO 30 k = 1, nt
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )m, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
   30             CONTINUE
                  nrun = nrun + nt
*
*                 Skip the remaining tests if this is not the first
*                 block size or if M .ne. N.  Skip the solve tests if
*                 the matrix is singular.
*
                  IF( inb.GT.1 .OR. m.NE.n )
     $               GO TO 90
                  IF( trfcon )
     $               GO TO 70
*
                  DO 60 irhs = 1, nns
                     nrhs = nsval( irhs )
                     xtype = 'N'
*
                     DO 50 itran = 1, ntran
                        trans = transs( itran )
                        IF( itran.EQ.1 ) THEN
                           rcondc = rcondo
                        ELSE
                           rcondc = rcondi
                        END IF
*
*+    TEST 3
*                       Solve and compute residual for A * X = B.
*
                        srnamt = 'ZLARHS'
                        CALL zlarhs( path, xtype, ' ', trans, n, n, kl,
     $                               ku, nrhs, a, lda, xact, lda, b,
     $                               lda, iseed, info )
                        xtype = 'C'
*
                        CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
                        srnamt = 'ZGETRS'
                        CALL zgetrs( trans, n, nrhs, afac, lda, iwork,
     $                               x, lda, info )
*
*                       Check error code from ZGETRS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'ZGETRS', info, 0, trans,
     $                                  n, n, -1, -1, nrhs, imat, nfail,
     $                                  nerrs, nout )
*
                        CALL zlacpy( 'Full', n, nrhs, b, lda, work,
     $                               lda )
                        CALL zget02( trans, n, n, nrhs, a, lda, x, lda,
     $                               work, lda, rwork, result( 3 ) )
*
*+    TEST 4
*                       Check solution from generated exact solution.
*
                        CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 4 ) )
*
*+    TESTS 5, 6, and 7
*                       Use iterative refinement to improve the
*                       solution.
*
                        srnamt = 'ZGERFS'
                        CALL zgerfs( trans, n, nrhs, a, lda, afac, lda,
     $                               iwork, b, lda, x, lda, rwork,
     $                               rwork( nrhs+1 ), work,
     $                               rwork( 2*nrhs+1 ), info )
*
*                       Check error code from ZGERFS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'ZGERFS', info, 0, trans,
     $                                  n, n, -1, -1, nrhs, imat, nfail,
     $                                  nerrs, nout )
*
                        CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 5 ) )
                        CALL zget07( trans, n, nrhs, a, lda, b, lda, x,
     $                               lda, xact, lda, rwork, .true.,
     $                               rwork( nrhs+1 ), result( 6 ) )
*
*                       Print information about the tests that did not
*                       pass the threshold.
*
                        DO 40 k = 3, 7
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL alahd( nout, path )
                              WRITE( nout, fmt = 9998 )trans, n, nrhs,
     $                           imat, k, result( k )
                              nfail = nfail + 1
                           END IF
   40                   CONTINUE
                        nrun = nrun + 5
   50                CONTINUE
   60             CONTINUE
*
*+    TEST 8
*                    Get an estimate of RCOND = 1/CNDNUM.
*
   70             CONTINUE
                  DO 80 itran = 1, 2
                     IF( itran.EQ.1 ) THEN
                        anorm = anormo
                        rcondc = rcondo
                        norm = 'O'
                     ELSE
                        anorm = anormi
                        rcondc = rcondi
                        norm = 'I'
                     END IF
                     srnamt = 'ZGECON'
                     CALL zgecon( norm, n, afac, lda, anorm, rcond,
     $                            work, rwork, info )
*
*                       Check error code from ZGECON.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZGECON', info, 0, norm, n,
     $                               n, -1, -1, -1, imat, nfail, nerrs,
     $                               nout )
*
*                       This line is needed on a Sun SPARCstation.
*
                     dummy = rcond
*
                     result( 8 ) = dget06( rcond, rcondc )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     IF( result( 8 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9997 )norm, n, imat, 8,
     $                     result( 8 )
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 1
   80             CONTINUE
   90          CONTINUE
  100       CONTINUE
*
  110    CONTINUE
  120 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' M = ', i5, ', N =', i5, ', NB =', i4, ', type ', i2,
     $      ', test(', i2, ') =', g12.5 )
 9998 FORMAT( ' TRANS=''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9997 FORMAT( ' NORM =''', a1, ''', N =', i5, ',', 10x, ' type ', i2,
     $      ', test(', i2, ') =', g12.5 )
      RETURN
*
*     End of ZCHKGE
*
      END