sdrvgt.f

Go to the documentation of this file.

*> \brief \b SDRVGT
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SDRVGT( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, A, AF,
*                          B, X, XACT, WORK, RWORK, IWORK, NOUT )
* 
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NN, NOUT, NRHS
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), NVAL( * )
*       REAL               A( * ), AF( * ), B( * ), RWORK( * ), WORK( * ),
*      $                   X( * ), XACT( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SDRVGT tests SGTSV and -SVX.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, NRHS >= 0.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is REAL array, dimension (NMAX*4)
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is REAL array, dimension (NMAX*4)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension
*>                      (NMAX*max(3,NRHS))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension
*>                      (max(NMAX,2*NRHS))
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE sdrvgt( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, A, AF,
     $                   b, x, xact, work, rwork, iwork, nout )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NN, NOUT, NRHS
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NVAL( * )
      REAL               A( * ), AF( * ), B( * ), RWORK( * ), WORK( * ),
     $                   x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter                ( one = 1.0e+0, zero = 0.0e+0 )
      INTEGER            NTYPES
      parameter                ( ntypes = 12 )
      INTEGER            NTESTS
      parameter                ( ntests = 6 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, FACT, TRANS, TYPE
      CHARACTER*3        PATH
      INTEGER            I, IFACT, IMAT, IN, INFO, ITRAN, IX, IZERO, J,
     $                   k, k1, kl, koff, ku, lda, m, mode, n, nerrs,
     $                   nfail, nimat, nrun, nt
      REAL               AINVNM, ANORM, ANORMI, ANORMO, COND, RCOND,
     $                   rcondc, rcondi, rcondo
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( 3 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( ntests ), Z( 3 )
*     ..
*     .. External Functions ..
      REAL               SASUM, SGET06, SLANGT
      EXTERNAL           sasum, sget06, slangt
*     ..
*     .. External Subroutines ..
      EXTERNAL           aladhd, alaerh, alasvm, scopy, serrvx, sget04,
     $                   sgtsv, sgtsvx, sgtt01, sgtt02, sgtt05, sgttrf,
     $                   sgttrs, slacpy, slagtm, slarnv, slaset, slatb4,
     $                   slatms, sscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 0, 0, 0, 1 / , transs / 'N', 'T',
     $                   'C' /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'GT'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL serrvx( path, nout )
      infot = 0
*
      DO 140 in = 1, nn
*
*        Do for each value of N in NVAL.
*
         n = nval( in )
         m = max( n-1, 0 )
         lda = max( 1, n )
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 130 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 130
*
*           Set up parameters with SLATB4.
*
            CALL slatb4( path, imat, n, n, TYPE, KL, KU, ANORM, MODE,
     $                   cond, dist )
*
            zerot = imat.GE.8 .AND. imat.LE.10
            IF( imat.LE.6 ) THEN
*
*              Types 1-6:  generate matrices of known condition number.
*
               koff = max( 2-ku, 3-max( 1, n ) )
               srnamt = 'SLATMS'
               CALL slatms( n, n, dist, iseed, TYPE, RWORK, MODE, COND,
     $                      anorm, kl, ku, 'Z', af( koff ), 3, work,
     $                      info )
*
*              Check the error code from SLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'SLATMS', info, 0, ' ', n, n, kl,
     $                         ku, -1, imat, nfail, nerrs, nout )
                  GO TO 130
               END IF
               izero = 0
*
               IF( n.GT.1 ) THEN
                  CALL scopy( n-1, af( 4 ), 3, a, 1 )
                  CALL scopy( n-1, af( 3 ), 3, a( n+m+1 ), 1 )
               END IF
               CALL scopy( n, af( 2 ), 3, a( m+1 ), 1 )
            ELSE
*
*              Types 7-12:  generate tridiagonal matrices with
*              unknown condition numbers.
*
               IF( .NOT.zerot .OR. .NOT.dotype( 7 ) ) THEN
*
*                 Generate a matrix with elements from [-1,1].
*
                  CALL slarnv( 2, iseed, n+2*m, a )
                  IF( anorm.NE.one )
     $               CALL sscal( n+2*m, anorm, a, 1 )
               ELSE IF( izero.GT.0 ) THEN
*
*                 Reuse the last matrix by copying back the zeroed out
*                 elements.
*
                  IF( izero.EQ.1 ) THEN
                     a( n ) = z( 2 )
                     IF( n.GT.1 )
     $                  a( 1 ) = z( 3 )
                  ELSE IF( izero.EQ.n ) THEN
                     a( 3*n-2 ) = z( 1 )
                     a( 2*n-1 ) = z( 2 )
                  ELSE
                     a( 2*n-2+izero ) = z( 1 )
                     a( n-1+izero ) = z( 2 )
                     a( izero ) = z( 3 )
                  END IF
               END IF
*
*              If IMAT > 7, set one column of the matrix to 0.
*
               IF( .NOT.zerot ) THEN
                  izero = 0
               ELSE IF( imat.EQ.8 ) THEN
                  izero = 1
                  z( 2 ) = a( n )
                  a( n ) = zero
                  IF( n.GT.1 ) THEN
                     z( 3 ) = a( 1 )
                     a( 1 ) = zero
                  END IF
               ELSE IF( imat.EQ.9 ) THEN
                  izero = n
                  z( 1 ) = a( 3*n-2 )
                  z( 2 ) = a( 2*n-1 )
                  a( 3*n-2 ) = zero
                  a( 2*n-1 ) = zero
               ELSE
                  izero = ( n+1 ) / 2
                  DO 20 i = izero, n - 1
                     a( 2*n-2+i ) = zero
                     a( n-1+i ) = zero
                     a( i ) = zero
   20             CONTINUE
                  a( 3*n-2 ) = zero
                  a( 2*n-1 ) = zero
               END IF
            END IF
*
            DO 120 ifact = 1, 2
               IF( ifact.EQ.1 ) THEN
                  fact = 'F'
               ELSE
                  fact = 'N'
               END IF
*
*              Compute the condition number for comparison with
*              the value returned by SGTSVX.
*
               IF( zerot ) THEN
                  IF( ifact.EQ.1 )
     $               GO TO 120
                  rcondo = zero
                  rcondi = zero
*
               ELSE IF( ifact.EQ.1 ) THEN
                  CALL scopy( n+2*m, a, 1, af, 1 )
*
*                 Compute the 1-norm and infinity-norm of A.
*
                  anormo = slangt( '1', n, a, a( m+1 ), a( n+m+1 ) )
                  anormi = slangt( 'I', n, a, a( m+1 ), a( n+m+1 ) )
*
*                 Factor the matrix A.
*
                  CALL sgttrf( n, af, af( m+1 ), af( n+m+1 ),
     $                         af( n+2*m+1 ), iwork, info )
*
*                 Use SGTTRS to solve for one column at a time of
*                 inv(A), computing the maximum column sum as we go.
*
                  ainvnm = zero
                  DO 40 i = 1, n
                     DO 30 j = 1, n
                        x( j ) = zero
   30                CONTINUE
                     x( i ) = one
                     CALL sgttrs( 'No transpose', n, 1, af, af( m+1 ),
     $                            af( n+m+1 ), af( n+2*m+1 ), iwork, x,
     $                            lda, info )
                     ainvnm = max( ainvnm, sasum( n, x, 1 ) )
   40             CONTINUE
*
*                 Compute the 1-norm condition number of A.
*
                  IF( anormo.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondo = one
                  ELSE
                     rcondo = ( one / anormo ) / ainvnm
                  END IF
*
*                 Use SGTTRS to solve for one column at a time of
*                 inv(A'), computing the maximum column sum as we go.
*
                  ainvnm = zero
                  DO 60 i = 1, n
                     DO 50 j = 1, n
                        x( j ) = zero
   50                CONTINUE
                     x( i ) = one
                     CALL sgttrs( 'Transpose', n, 1, af, af( m+1 ),
     $                            af( n+m+1 ), af( n+2*m+1 ), iwork, x,
     $                            lda, info )
                     ainvnm = max( ainvnm, sasum( n, x, 1 ) )
   60             CONTINUE
*
*                 Compute the infinity-norm condition number of A.
*
                  IF( anormi.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondi = one
                  ELSE
                     rcondi = ( one / anormi ) / ainvnm
                  END IF
               END IF
*
               DO 110 itran = 1, 3
                  trans = transs( itran )
                  IF( itran.EQ.1 ) THEN
                     rcondc = rcondo
                  ELSE
                     rcondc = rcondi
                  END IF
*
*                 Generate NRHS random solution vectors.
*
                  ix = 1
                  DO 70 j = 1, nrhs
                     CALL slarnv( 2, iseed, n, xact( ix ) )
                     ix = ix + lda
   70             CONTINUE
*
*                 Set the right hand side.
*
                  CALL slagtm( trans, n, nrhs, one, a, a( m+1 ),
     $                         a( n+m+1 ), xact, lda, zero, b, lda )
*
                  IF( ifact.EQ.2 .AND. itran.EQ.1 ) THEN
*
*                    --- Test SGTSV  ---
*
*                    Solve the system using Gaussian elimination with
*                    partial pivoting.
*
                     CALL scopy( n+2*m, a, 1, af, 1 )
                     CALL slacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'SGTSV '
                     CALL sgtsv( n, nrhs, af, af( m+1 ), af( n+m+1 ), x,
     $                           lda, info )
*
*                    Check error code from SGTSV .
*
                     IF( info.NE.izero )
     $                  CALL alaerh( path, 'SGTSV ', info, izero, ' ',
     $                               n, n, 1, 1, nrhs, imat, nfail,
     $                               nerrs, nout )
                     nt = 1
                     IF( izero.EQ.0 ) THEN
*
*                       Check residual of computed solution.
*
                        CALL slacpy( 'Full', n, nrhs, b, lda, work,
     $                               lda )
                        CALL sgtt02( trans, n, nrhs, a, a( m+1 ),
     $                               a( n+m+1 ), x, lda, work, lda,
     $                               result( 2 ) )
*
*                       Check solution from generated exact solution.
*
                        CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 3 ) )
                        nt = 3
                     END IF
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 80 k = 2, nt
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL aladhd( nout, path )
                           WRITE( nout, fmt = 9999 )'SGTSV ', n, imat,
     $                        k, result( k )
                           nfail = nfail + 1
                        END IF
   80                CONTINUE
                     nrun = nrun + nt - 1
                  END IF
*
*                 --- Test SGTSVX ---
*
                  IF( ifact.GT.1 ) THEN
*
*                    Initialize AF to zero.
*
                     DO 90 i = 1, 3*n - 2
                        af( i ) = zero
   90                CONTINUE
                  END IF
                  CALL slaset( 'Full', n, nrhs, zero, zero, x, lda )
*
*                 Solve the system and compute the condition number and
*                 error bounds using SGTSVX.
*
                  srnamt = 'SGTSVX'
                  CALL sgtsvx( fact, trans, n, nrhs, a, a( m+1 ),
     $                         a( n+m+1 ), af, af( m+1 ), af( n+m+1 ),
     $                         af( n+2*m+1 ), iwork, b, lda, x, lda,
     $                         rcond, rwork, rwork( nrhs+1 ), work,
     $                         iwork( n+1 ), info )
*
*                 Check the error code from SGTSVX.
*
                  IF( info.NE.izero )
     $               CALL alaerh( path, 'SGTSVX', info, izero,
     $                            fact // trans, n, n, 1, 1, nrhs, imat,
     $                            nfail, nerrs, nout )
*
                  IF( ifact.GE.2 ) THEN
*
*                    Reconstruct matrix from factors and compute
*                    residual.
*
                     CALL sgtt01( n, a, a( m+1 ), a( n+m+1 ), af,
     $                            af( m+1 ), af( n+m+1 ), af( n+2*m+1 ),
     $                            iwork, work, lda, rwork, result( 1 ) )
                     k1 = 1
                  ELSE
                     k1 = 2
                  END IF
*
                  IF( info.EQ.0 ) THEN
                     trfcon = .false.
*
*                    Check residual of computed solution.
*
                     CALL slacpy( 'Full', n, nrhs, b, lda, work, lda )
                     CALL sgtt02( trans, n, nrhs, a, a( m+1 ),
     $                            a( n+m+1 ), x, lda, work, lda,
     $                            result( 2 ) )
*
*                    Check solution from generated exact solution.
*
                     CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 3 ) )
*
*                    Check the error bounds from iterative refinement.
*
                     CALL sgtt05( trans, n, nrhs, a, a( m+1 ),
     $                            a( n+m+1 ), b, lda, x, lda, xact, lda,
     $                            rwork, rwork( nrhs+1 ), result( 4 ) )
                     nt = 5
                  END IF
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 100 k = k1, nt
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL aladhd( nout, path )
                        WRITE( nout, fmt = 9998 )'SGTSVX', fact, trans,
     $                     n, imat, k, result( k )
                        nfail = nfail + 1
                     END IF
  100             CONTINUE
*
*                 Check the reciprocal of the condition number.
*
                  result( 6 ) = sget06( rcond, rcondc )
                  IF( result( 6 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL aladhd( nout, path )
                     WRITE( nout, fmt = 9998 )'SGTSVX', fact, trans, n,
     $                  imat, k, result( k )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + nt - k1 + 2
*
  110          CONTINUE
  120       CONTINUE
  130    CONTINUE
  140 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasvm( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 1x, a, ', N =', i5, ', type ', i2, ', test ', i2,
     $      ', ratio = ', g12.5 )
 9998 FORMAT( 1x, a, ', FACT=''', a1, ''', TRANS=''', a1, ''', N =',
     $      i5, ', type ', i2, ', test ', i2, ', ratio = ', g12.5 )
      RETURN
*
*     End of SDRVGT
*
      END