LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine dporfsx ( character  UPLO,
character  EQUED,
integer  N,
integer  NRHS,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( ldaf, * )  AF,
integer  LDAF,
double precision, dimension( * )  S,
double precision, dimension( ldb, * )  B,
integer  LDB,
double precision, dimension( ldx, * )  X,
integer  LDX,
double precision  RCOND,
double precision, dimension( * )  BERR,
integer  N_ERR_BNDS,
double precision, dimension( nrhs, * )  ERR_BNDS_NORM,
double precision, dimension( nrhs, * )  ERR_BNDS_COMP,
integer  NPARAMS,
double precision, dimension( * )  PARAMS,
double precision, dimension( * )  WORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

DPORFSX

Download DPORFSX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
    DPORFSX improves the computed solution to a system of linear
    equations when the coefficient matrix is symmetric positive
    definite, and provides error bounds and backward error estimates
    for the solution.  In addition to normwise error bound, the code
    provides maximum componentwise error bound if possible.  See
    comments for ERR_BNDS_NORM and ERR_BNDS_COMP for details of the
    error bounds.

    The original system of linear equations may have been equilibrated
    before calling this routine, as described by arguments EQUED and S
    below. In this case, the solution and error bounds returned are
    for the original unequilibrated system.
     Some optional parameters are bundled in the PARAMS array.  These
     settings determine how refinement is performed, but often the
     defaults are acceptable.  If the defaults are acceptable, users
     can pass NPARAMS = 0 which prevents the source code from accessing
     the PARAMS argument.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
       = 'U':  Upper triangle of A is stored;
       = 'L':  Lower triangle of A is stored.
[in]EQUED
          EQUED is CHARACTER*1
     Specifies the form of equilibration that was done to A
     before calling this routine. This is needed to compute
     the solution and error bounds correctly.
       = 'N':  No equilibration
       = 'Y':  Both row and column equilibration, i.e., A has been
               replaced by diag(S) * A * diag(S).
               The right hand side B has been changed accordingly.
[in]N
          N is INTEGER
     The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right hand sides, i.e., the number of columns
     of the matrices B and X.  NRHS >= 0.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
     The symmetric matrix A.  If UPLO = 'U', the leading N-by-N
     upper triangular part of A contains the upper triangular part
     of the matrix A, and the strictly lower triangular part of A
     is not referenced.  If UPLO = 'L', the leading N-by-N lower
     triangular part of A contains the lower triangular part of
     the matrix A, and the strictly upper triangular part of A is
     not referenced.
[in]LDA
          LDA is INTEGER
     The leading dimension of the array A.  LDA >= max(1,N).
[in]AF
          AF is DOUBLE PRECISION array, dimension (LDAF,N)
     The triangular factor U or L from the Cholesky factorization
     A = U**T*U or A = L*L**T, as computed by DPOTRF.
[in]LDAF
          LDAF is INTEGER
     The leading dimension of the array AF.  LDAF >= max(1,N).
[in,out]S
          S is DOUBLE PRECISION array, dimension (N)
     The row scale factors for A.  If EQUED = 'Y', A is multiplied on
     the left and right by diag(S).  S is an input argument if FACT =
     'F'; otherwise, S is an output argument.  If FACT = 'F' and EQUED
     = 'Y', each element of S must be positive.  If S is output, each
     element of S is a power of the radix. If S is input, each element
     of S should be a power of the radix to ensure a reliable solution
     and error estimates. Scaling by powers of the radix does not cause
     rounding errors unless the result underflows or overflows.
     Rounding errors during scaling lead to refining with a matrix that
     is not equivalent to the input matrix, producing error estimates
     that may not be reliable.
[in]B
          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
     The right hand side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]X
          X is DOUBLE PRECISION array, dimension (LDX,NRHS)
     On entry, the solution matrix X, as computed by DGETRS.
     On exit, the improved solution matrix X.
[in]LDX
          LDX is INTEGER
     The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is DOUBLE PRECISION
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[out]BERR
          BERR is DOUBLE PRECISION array, dimension (NRHS)
     Componentwise relative backward error.  This is the
     componentwise relative backward error of each solution vector X(j)
     (i.e., the smallest relative change in any element of A or B that
     makes X(j) an exact solution).
[in]N_ERR_BNDS
          N_ERR_BNDS is INTEGER
     Number of error bounds to return for each right hand side
     and each type (normwise or componentwise).  See ERR_BNDS_NORM and
     ERR_BNDS_COMP below.
[out]ERR_BNDS_NORM
          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * dlamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * dlamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * dlamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[out]ERR_BNDS_COMP
          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * dlamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * dlamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * dlamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[in]NPARAMS
          NPARAMS is INTEGER
     Specifies the number of parameters set in PARAMS.  If .LE. 0, the
     PARAMS array is never referenced and default values are used.
[in,out]PARAMS
          PARAMS is DOUBLE PRECISION array, dimension (NPARAMS)
     Specifies algorithm parameters.  If an entry is .LT. 0.0, then
     that entry will be filled with default value used for that
     parameter.  Only positions up to NPARAMS are accessed; defaults
     are used for higher-numbered parameters.

       PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
            refinement or not.
         Default: 1.0D+0
            = 0.0 : No refinement is performed, and no error bounds are
                    computed.
            = 1.0 : Use the double-precision refinement algorithm,
                    possibly with doubled-single computations if the
                    compilation environment does not support DOUBLE
                    PRECISION.
              (other values are reserved for future use)

       PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
            computations allowed for refinement.
         Default: 10
         Aggressive: Set to 100 to permit convergence using approximate
                     factorizations or factorizations other than LU. If
                     the factorization uses a technique other than
                     Gaussian elimination, the guarantees in
                     err_bnds_norm and err_bnds_comp may no longer be
                     trustworthy.

       PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
            will attempt to find a solution with small componentwise
            relative error in the double-precision algorithm.  Positive
            is true, 0.0 is false.
         Default: 1.0 (attempt componentwise convergence)
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (4*N)
[out]IWORK
          IWORK is INTEGER array, dimension (N)
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit. The solution to every right-hand side is
         guaranteed.
       < 0:  If INFO = -i, the i-th argument had an illegal value
       > 0 and <= N:  U(INFO,INFO) is exactly zero.  The factorization
         has been completed, but the factor U is exactly singular, so
         the solution and error bounds could not be computed. RCOND = 0
         is returned.
       = N+J: The solution corresponding to the Jth right-hand side is
         not guaranteed. The solutions corresponding to other right-
         hand sides K with K > J may not be guaranteed as well, but
         only the first such right-hand side is reported. If a small
         componentwise error is not requested (PARAMS(3) = 0.0) then
         the Jth right-hand side is the first with a normwise error
         bound that is not guaranteed (the smallest J such
         that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
         the Jth right-hand side is the first with either a normwise or
         componentwise error bound that is not guaranteed (the smallest
         J such that either ERR_BNDS_NORM(J,1) = 0.0 or
         ERR_BNDS_COMP(J,1) = 0.0). See the definition of
         ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
         about all of the right-hand sides check ERR_BNDS_NORM or
         ERR_BNDS_COMP.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
April 2012

Definition at line 396 of file dporfsx.f.

396 *
397 * -- LAPACK computational routine (version 3.4.1) --
398 * -- LAPACK is a software package provided by Univ. of Tennessee, --
399 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
400 * April 2012
401 *
402 * .. Scalar Arguments ..
403  CHARACTER uplo, equed
404  INTEGER info, lda, ldaf, ldb, ldx, n, nrhs, nparams,
405  $ n_err_bnds
406  DOUBLE PRECISION rcond
407 * ..
408 * .. Array Arguments ..
409  INTEGER iwork( * )
410  DOUBLE PRECISION a( lda, * ), af( ldaf, * ), b( ldb, * ),
411  $ x( ldx, * ), work( * )
412  DOUBLE PRECISION s( * ), params( * ), berr( * ),
413  $ err_bnds_norm( nrhs, * ),
414  $ err_bnds_comp( nrhs, * )
415 * ..
416 *
417 * ==================================================================
418 *
419 * .. Parameters ..
420  DOUBLE PRECISION zero, one
421  parameter ( zero = 0.0d+0, one = 1.0d+0 )
422  DOUBLE PRECISION itref_default, ithresh_default
423  DOUBLE PRECISION componentwise_default, rthresh_default
424  DOUBLE PRECISION dzthresh_default
425  parameter ( itref_default = 1.0d+0 )
426  parameter ( ithresh_default = 10.0d+0 )
427  parameter ( componentwise_default = 1.0d+0 )
428  parameter ( rthresh_default = 0.5d+0 )
429  parameter ( dzthresh_default = 0.25d+0 )
430  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
431  $ la_linrx_cwise_i
432  parameter ( la_linrx_itref_i = 1,
433  $ la_linrx_ithresh_i = 2 )
434  parameter ( la_linrx_cwise_i = 3 )
435  INTEGER la_linrx_trust_i, la_linrx_err_i,
436  $ la_linrx_rcond_i
437  parameter ( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
438  parameter ( la_linrx_rcond_i = 3 )
439 * ..
440 * .. Local Scalars ..
441  CHARACTER(1) norm
442  LOGICAL rcequ
443  INTEGER j, prec_type, ref_type
444  INTEGER n_norms
445  DOUBLE PRECISION anorm, rcond_tmp
446  DOUBLE PRECISION illrcond_thresh, err_lbnd, cwise_wrong
447  LOGICAL ignore_cwise
448  INTEGER ithresh
449  DOUBLE PRECISION rthresh, unstable_thresh
450 * ..
451 * .. External Subroutines ..
453 * ..
454 * .. Intrinsic Functions ..
455  INTRINSIC max, sqrt
456 * ..
457 * .. External Functions ..
458  EXTERNAL lsame, blas_fpinfo_x, ilatrans, ilaprec
459  EXTERNAL dlamch, dlansy, dla_porcond
460  DOUBLE PRECISION dlamch, dlansy, dla_porcond
461  LOGICAL lsame
462  INTEGER blas_fpinfo_x
463  INTEGER ilatrans, ilaprec
464 * ..
465 * .. Executable Statements ..
466 *
467 * Check the input parameters.
468 *
469  info = 0
470  ref_type = int( itref_default )
471  IF ( nparams .GE. la_linrx_itref_i ) THEN
472  IF ( params( la_linrx_itref_i ) .LT. 0.0d+0 ) THEN
473  params( la_linrx_itref_i ) = itref_default
474  ELSE
475  ref_type = params( la_linrx_itref_i )
476  END IF
477  END IF
478 *
479 * Set default parameters.
480 *
481  illrcond_thresh = dble( n ) * dlamch( 'Epsilon' )
482  ithresh = int( ithresh_default )
483  rthresh = rthresh_default
484  unstable_thresh = dzthresh_default
485  ignore_cwise = componentwise_default .EQ. 0.0d+0
486 *
487  IF ( nparams.GE.la_linrx_ithresh_i ) THEN
488  IF ( params( la_linrx_ithresh_i ).LT.0.0d+0 ) THEN
489  params( la_linrx_ithresh_i ) = ithresh
490  ELSE
491  ithresh = int( params( la_linrx_ithresh_i ) )
492  END IF
493  END IF
494  IF ( nparams.GE.la_linrx_cwise_i ) THEN
495  IF ( params( la_linrx_cwise_i ).LT.0.0d+0 ) THEN
496  IF ( ignore_cwise ) THEN
497  params( la_linrx_cwise_i ) = 0.0d+0
498  ELSE
499  params( la_linrx_cwise_i ) = 1.0d+0
500  END IF
501  ELSE
502  ignore_cwise = params( la_linrx_cwise_i ) .EQ. 0.0d+0
503  END IF
504  END IF
505  IF ( ref_type .EQ. 0 .OR. n_err_bnds .EQ. 0 ) THEN
506  n_norms = 0
507  ELSE IF ( ignore_cwise ) THEN
508  n_norms = 1
509  ELSE
510  n_norms = 2
511  END IF
512 *
513  rcequ = lsame( equed, 'Y' )
514 *
515 * Test input parameters.
516 *
517  IF (.NOT.lsame(uplo, 'U') .AND. .NOT.lsame(uplo, 'L')) THEN
518  info = -1
519  ELSE IF( .NOT.rcequ .AND. .NOT.lsame( equed, 'N' ) ) THEN
520  info = -2
521  ELSE IF( n.LT.0 ) THEN
522  info = -3
523  ELSE IF( nrhs.LT.0 ) THEN
524  info = -4
525  ELSE IF( lda.LT.max( 1, n ) ) THEN
526  info = -6
527  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
528  info = -8
529  ELSE IF( ldb.LT.max( 1, n ) ) THEN
530  info = -11
531  ELSE IF( ldx.LT.max( 1, n ) ) THEN
532  info = -13
533  END IF
534  IF( info.NE.0 ) THEN
535  CALL xerbla( 'DPORFSX', -info )
536  RETURN
537  END IF
538 *
539 * Quick return if possible.
540 *
541  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
542  rcond = 1.0d+0
543  DO j = 1, nrhs
544  berr( j ) = 0.0d+0
545  IF ( n_err_bnds .GE. 1 ) THEN
546  err_bnds_norm( j, la_linrx_trust_i ) = 1.0d+0
547  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
548  END IF
549  IF ( n_err_bnds .GE. 2 ) THEN
550  err_bnds_norm( j, la_linrx_err_i ) = 0.0d+0
551  err_bnds_comp( j, la_linrx_err_i ) = 0.0d+0
552  END IF
553  IF ( n_err_bnds .GE. 3 ) THEN
554  err_bnds_norm( j, la_linrx_rcond_i ) = 1.0d+0
555  err_bnds_comp( j, la_linrx_rcond_i ) = 1.0d+0
556  END IF
557  END DO
558  RETURN
559  END IF
560 *
561 * Default to failure.
562 *
563  rcond = 0.0d+0
564  DO j = 1, nrhs
565  berr( j ) = 1.0d+0
566  IF ( n_err_bnds .GE. 1 ) THEN
567  err_bnds_norm( j, la_linrx_trust_i ) = 1.0d+0
568  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
569  END IF
570  IF ( n_err_bnds .GE. 2 ) THEN
571  err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
572  err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
573  END IF
574  IF ( n_err_bnds .GE. 3 ) THEN
575  err_bnds_norm( j, la_linrx_rcond_i ) = 0.0d+0
576  err_bnds_comp( j, la_linrx_rcond_i ) = 0.0d+0
577  END IF
578  END DO
579 *
580 * Compute the norm of A and the reciprocal of the condition
581 * number of A.
582 *
583  norm = 'I'
584  anorm = dlansy( norm, uplo, n, a, lda, work )
585  CALL dpocon( uplo, n, af, ldaf, anorm, rcond, work,
586  $ iwork, info )
587 *
588 * Perform refinement on each right-hand side
589 *
590  IF ( ref_type .NE. 0 ) THEN
591 
592  prec_type = ilaprec( 'E' )
593 
594  CALL dla_porfsx_extended( prec_type, uplo, n,
595  $ nrhs, a, lda, af, ldaf, rcequ, s, b,
596  $ ldb, x, ldx, berr, n_norms, err_bnds_norm, err_bnds_comp,
597  $ work( n+1 ), work( 1 ), work( 2*n+1 ), work( 1 ), rcond,
598  $ ithresh, rthresh, unstable_thresh, ignore_cwise,
599  $ info )
600  END IF
601 
602  err_lbnd = max( 10.0d+0, sqrt( dble( n ) ) ) * dlamch( 'Epsilon' )
603  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 1 ) THEN
604 *
605 * Compute scaled normwise condition number cond(A*C).
606 *
607  IF ( rcequ ) THEN
608  rcond_tmp = dla_porcond( uplo, n, a, lda, af, ldaf,
609  $ -1, s, info, work, iwork )
610  ELSE
611  rcond_tmp = dla_porcond( uplo, n, a, lda, af, ldaf,
612  $ 0, s, info, work, iwork )
613  END IF
614  DO j = 1, nrhs
615 *
616 * Cap the error at 1.0.
617 *
618  IF ( n_err_bnds .GE. la_linrx_err_i
619  $ .AND. err_bnds_norm( j, la_linrx_err_i ) .GT. 1.0d+0 )
620  $ err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
621 *
622 * Threshold the error (see LAWN).
623 *
624  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
625  err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
626  err_bnds_norm( j, la_linrx_trust_i ) = 0.0d+0
627  IF ( info .LE. n ) info = n + j
628  ELSE IF ( err_bnds_norm( j, la_linrx_err_i ) .LT. err_lbnd )
629  $ THEN
630  err_bnds_norm( j, la_linrx_err_i ) = err_lbnd
631  err_bnds_norm( j, la_linrx_trust_i ) = 1.0d+0
632  END IF
633 *
634 * Save the condition number.
635 *
636  IF (n_err_bnds .GE. la_linrx_rcond_i) THEN
637  err_bnds_norm( j, la_linrx_rcond_i ) = rcond_tmp
638  END IF
639  END DO
640  END IF
641 
642  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 2 ) THEN
643 *
644 * Compute componentwise condition number cond(A*diag(Y(:,J))) for
645 * each right-hand side using the current solution as an estimate of
646 * the true solution. If the componentwise error estimate is too
647 * large, then the solution is a lousy estimate of truth and the
648 * estimated RCOND may be too optimistic. To avoid misleading users,
649 * the inverse condition number is set to 0.0 when the estimated
650 * cwise error is at least CWISE_WRONG.
651 *
652  cwise_wrong = sqrt( dlamch( 'Epsilon' ) )
653  DO j = 1, nrhs
654  IF (err_bnds_comp( j, la_linrx_err_i ) .LT. cwise_wrong )
655  $ THEN
656  rcond_tmp = dla_porcond( uplo, n, a, lda, af, ldaf, 1,
657  $ x( 1, j ), info, work, iwork )
658  ELSE
659  rcond_tmp = 0.0d+0
660  END IF
661 *
662 * Cap the error at 1.0.
663 *
664  IF ( n_err_bnds .GE. la_linrx_err_i
665  $ .AND. err_bnds_comp( j, la_linrx_err_i ) .GT. 1.0d+0 )
666  $ err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
667 *
668 * Threshold the error (see LAWN).
669 *
670  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
671  err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
672  err_bnds_comp( j, la_linrx_trust_i ) = 0.0d+0
673  IF ( params( la_linrx_cwise_i ) .EQ. 1.0d+0
674  $ .AND. info.LT.n + j ) info = n + j
675  ELSE IF ( err_bnds_comp( j, la_linrx_err_i )
676  $ .LT. err_lbnd ) THEN
677  err_bnds_comp( j, la_linrx_err_i ) = err_lbnd
678  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
679  END IF
680 *
681 * Save the condition number.
682 *
683  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
684  err_bnds_comp( j, la_linrx_rcond_i ) = rcond_tmp
685  END IF
686 
687  END DO
688  END IF
689 *
690  RETURN
691 *
692 * End of DPORFSX
693 *
integer function ilatrans(TRANS)
ILATRANS
Definition: ilatrans.f:60
double precision function dla_porcond(UPLO, N, A, LDA, AF, LDAF, CMODE, C, INFO, WORK, IWORK)
DLA_PORCOND estimates the Skeel condition number for a symmetric positive-definite matrix...
Definition: dla_porcond.f:144
double precision function dlansy(NORM, UPLO, N, A, LDA, WORK)
DLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric matrix.
Definition: dlansy.f:124
subroutine dla_porfsx_extended(PREC_TYPE, UPLO, N, NRHS, A, LDA, AF, LDAF, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
DLA_PORFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric or H...
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine dpocon(UPLO, N, A, LDA, ANORM, RCOND, WORK, IWORK, INFO)
DPOCON
Definition: dpocon.f:123
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
integer function ilaprec(PREC)
ILAPREC
Definition: ilaprec.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: