subroutine dpocon	(	character	UPLO,
		integer	N,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision	ANORM,
		double precision	RCOND,
		double precision, dimension( * )	WORK,
		integer, dimension( * )	IWORK,
		integer	INFO
	)

DPOCON

Download DPOCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DPOCON estimates the reciprocal of the condition number (in the
 1-norm) of a real symmetric positive definite matrix using the
 Cholesky factorization A = U**T*U or A = L*L**T computed by DPOTRF.

 An estimate is obtained for norm(inv(A)), and the reciprocal of the
 condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The triangular factor U or L from the Cholesky factorization A = U**T*U or A = L*L**T, as computed by DPOTRF.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	ANORM	ANORM is DOUBLE PRECISION The 1-norm (or infinity-norm) of the symmetric matrix A.
[out]	RCOND	RCOND is DOUBLE PRECISION The reciprocal of the condition number of the matrix A, computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an estimate of the 1-norm of inv(A) computed in this routine.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (3*N)
[out]	IWORK	IWORK is INTEGER array, dimension (N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 123 of file dpocon.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, lda, n
      DOUBLE PRECISION   anorm, rcond
*     ..
*     .. Array Arguments ..
      INTEGER            iwork( * )
      DOUBLE PRECISION   a( lda, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      CHARACTER          normin
      INTEGER            ix, kase
      DOUBLE PRECISION   ainvnm, scale, scalel, scaleu, smlnum
*     ..
*     .. Local Arrays ..
      INTEGER            isave( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            idamax
      DOUBLE PRECISION   dlamch
      EXTERNAL           lsame, idamax, dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlacn2, dlatrs, drscl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      ELSE IF( anorm.LT.zero ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPOCON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      rcond = zero
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      ELSE IF( anorm.EQ.zero ) THEN
         RETURN
      END IF
*
      smlnum = dlamch( 'Safe minimum' )
*
*     Estimate the 1-norm of inv(A).
*
      kase = 0
      normin = 'N'
   10 CONTINUE
      CALL dlacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
      IF( kase.NE.0 ) THEN
         IF( upper ) THEN
*
*           Multiply by inv(U**T).
*
            CALL dlatrs( 'Upper', 'Transpose', 'Non-unit', normin, n, a,
     $                   lda, work, scalel, work( 2*n+1 ), info )
            normin = 'Y'
*
*           Multiply by inv(U).
*
            CALL dlatrs( 'Upper', 'No transpose', 'Non-unit', normin, n,
     $                   a, lda, work, scaleu, work( 2*n+1 ), info )
         ELSE
*
*           Multiply by inv(L).
*
            CALL dlatrs( 'Lower', 'No transpose', 'Non-unit', normin, n,
     $                   a, lda, work, scalel, work( 2*n+1 ), info )
            normin = 'Y'
*
*           Multiply by inv(L**T).
*
            CALL dlatrs( 'Lower', 'Transpose', 'Non-unit', normin, n, a,
     $                   lda, work, scaleu, work( 2*n+1 ), info )
         END IF
*
*        Multiply by 1/SCALE if doing so will not cause overflow.
*
         scale = scalel*scaleu
         IF( scale.NE.one ) THEN
            ix = idamax( n, work, 1 )
            IF( scale.LT.abs( work( ix ) )*smlnum .OR. scale.EQ.zero )
     $         GO TO 20
            CALL drscl( n, scale, work, 1 )
         END IF
         GO TO 10
      END IF
*
*     Compute the estimate of the reciprocal condition number.
*
      IF( ainvnm.NE.zero )
     $   rcond = ( one / ainvnm ) / anorm
*
   20 CONTINUE
      RETURN
*
*     End of DPOCON
*

Here is the call graph for this function:

Here is the caller graph for this function: