zppt03.f

Go to the documentation of this file.

*> \brief \b ZPPT03
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZPPT03( UPLO, N, A, AINV, WORK, LDWORK, RWORK, RCOND,
*                          RESID )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            LDWORK, N
*       DOUBLE PRECISION   RCOND, RESID
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   RWORK( * )
*       COMPLEX*16         A( * ), AINV( * ), WORK( LDWORK, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZPPT03 computes the residual for a Hermitian packed matrix times its
*> inverse:
*>    norm( I - A*AINV ) / ( N * norm(A) * norm(AINV) * EPS ),
*> where EPS is the machine epsilon.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          Hermitian matrix A is stored:
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows and columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (N*(N+1)/2)
*>          The original Hermitian matrix A, stored as a packed
*>          triangular matrix.
*> \endverbatim
*>
*> \param[in] AINV
*> \verbatim
*>          AINV is COMPLEX*16 array, dimension (N*(N+1)/2)
*>          The (Hermitian) inverse of the matrix A, stored as a packed
*>          triangular matrix.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (LDWORK,N)
*> \endverbatim
*>
*> \param[in] LDWORK
*> \verbatim
*>          LDWORK is INTEGER
*>          The leading dimension of the array WORK.  LDWORK >= max(1,N).
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (N)
*> \endverbatim
*>
*> \param[out] RCOND
*> \verbatim
*>          RCOND is DOUBLE PRECISION
*>          The reciprocal of the condition number of A, computed as
*>          ( 1/norm(A) ) / norm(AINV).
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*>          RESID is DOUBLE PRECISION
*>          norm(I - A*AINV) / ( N * norm(A) * norm(AINV) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zppt03( UPLO, N, A, AINV, WORK, LDWORK, RWORK, RCOND,
     $                   resid )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            ldwork, n
      DOUBLE PRECISION   rcond, resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( * ), ainv( * ), work( ldwork, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         czero, cone
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, jj
      DOUBLE PRECISION   ainvnm, anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, zlange, zlanhp
      EXTERNAL           lsame, dlamch, zlange, zlanhp
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dconjg
*     ..
*     .. External Subroutines ..
      EXTERNAL           zcopy, zhpmv
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         return
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlanhp( '1', uplo, n, a, rwork )
      ainvnm = zlanhp( '1', uplo, n, ainv, rwork )
      IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
         rcond = zero
         resid = one / eps
         return
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     UPLO = 'U':
*     Copy the leading N-1 x N-1 submatrix of AINV to WORK(1:N,2:N) and
*     expand it to a full matrix, then multiply by A one column at a
*     time, moving the result one column to the left.
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Copy AINV
*
         jj = 1
         DO 20 j = 1, n - 1
            CALL zcopy( j, ainv( jj ), 1, work( 1, j+1 ), 1 )
            DO 10 i = 1, j - 1
               work( j, i+1 ) = dconjg( ainv( jj+i-1 ) )
   10       continue
            jj = jj + j
   20    continue
         jj = ( ( n-1 )*n ) / 2 + 1
         DO 30 i = 1, n - 1
            work( n, i+1 ) = dconjg( ainv( jj+i-1 ) )
   30    continue
*
*        Multiply by A
*
         DO 40 j = 1, n - 1
            CALL zhpmv( 'Upper', n, -cone, a, work( 1, j+1 ), 1, czero,
     $                  work( 1, j ), 1 )
   40    continue
         CALL zhpmv( 'Upper', n, -cone, a, ainv( jj ), 1, czero,
     $               work( 1, n ), 1 )
*
*     UPLO = 'L':
*     Copy the trailing N-1 x N-1 submatrix of AINV to WORK(1:N,1:N-1)
*     and multiply by A, moving each column to the right.
*
      ELSE
*
*        Copy AINV
*
         DO 50 i = 1, n - 1
            work( 1, i ) = dconjg( ainv( i+1 ) )
   50    continue
         jj = n + 1
         DO 70 j = 2, n
            CALL zcopy( n-j+1, ainv( jj ), 1, work( j, j-1 ), 1 )
            DO 60 i = 1, n - j
               work( j, j+i-1 ) = dconjg( ainv( jj+i ) )
   60       continue
            jj = jj + n - j + 1
   70    continue
*
*        Multiply by A
*
         DO 80 j = n, 2, -1
            CALL zhpmv( 'Lower', n, -cone, a, work( 1, j-1 ), 1, czero,
     $                  work( 1, j ), 1 )
   80    continue
         CALL zhpmv( 'Lower', n, -cone, a, ainv( 1 ), 1, czero,
     $               work( 1, 1 ), 1 )
*
      END IF
*
*     Add the identity matrix to WORK .
*
      DO 90 i = 1, n
         work( i, i ) = work( i, i ) + cone
   90 continue
*
*     Compute norm(I - A*AINV) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = zlange( '1', n, n, work, ldwork, rwork )
*
      resid = ( ( resid*rcond ) / eps ) / dble( n )
*
      return
*
*     End of ZPPT03
*
      END