pzlarfg.f

Go to the documentation of this file.

      SUBROUTINE pzlarfg( N, ALPHA, IAX, JAX, X, IX, JX, DESCX, INCX,
     $                    TAU )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IAX, INCX, IX, JAX, JX, N
      COMPLEX*16         ALPHA
*     ..
*     .. Array Arguments ..
      INTEGER            DESCX( * )
      COMPLEX*16         TAU( * ), X( * )
*     ..
*
*  Purpose
*  =======
*
*  PZLARFG generates a complex elementary reflector H of order n, such
*  that
*
*     H * sub( X ) = H * ( x(iax,jax) ) = ( alpha ),   H' * H = I.
*                        (      x     )   (   0   )
*
*  where alpha is a real scalar, and sub( X ) is an (N-1)-element
*  complex distributed vector X(IX:IX+N-2,JX) if INCX = 1 and
*  X(IX,JX:JX+N-2) if INCX = DESCX(M_).  H is represented in the form
*
*        H = I - tau * ( 1 ) * ( 1 v' ) ,
*                      ( v )
*
*  where tau is a complex scalar and v is a complex (N-1)-element
*  vector. Note that H is not Hermitian.
*
*  If the elements of sub( X ) are all zero and X(IAX,JAX) is real,
*  then tau = 0 and H is taken to be the unit matrix.
*
*  Otherwise  1 <= real(tau) <= 2 and abs(tau-1) <= 1.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Because vectors may be viewed as a subclass of matrices, a
*  distributed vector is considered to be a distributed matrix.
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The global order of the elementary reflector. N >= 0.
*
*  ALPHA   (local output) COMPLEX*16
*          On exit, alpha is computed in the process scope having the
*          vector sub( X ).
*
*  IAX     (global input) INTEGER
*          The global row index in X of X(IAX,JAX).
*
*  JAX     (global input) INTEGER
*          The global column index in X of X(IAX,JAX).
*
*  X       (local input/local output) COMPLEX*16, pointer into the
*          local memory to an array of dimension (LLD_X,*). This array
*          contains the local pieces of the distributed vector sub( X ).
*          Before entry, the incremented array sub( X ) must contain
*          the vector x. On exit, it is overwritten with the vector v.
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  INCX    (global input) INTEGER
*          The global increment for the elements of X. Only two values
*          of INCX are supported in this version, namely 1 and M_X.
*          INCX must not be zero.
*
*  TAU     (local output) COMPLEX*16, array, dimension  LOCc(JX)
*          if INCX = 1, and LOCr(IX) otherwise. This array contains the
*          Householder scalars related to the Householder vectors.
*          TAU is tied to the distributed matrix X.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            ICTXT, IIAX, INDXTAU, IXCOL, IXROW, J, JJAX,
     $                   knt, mycol, myrow, npcol, nprow
      DOUBLE PRECISION   ALPHI, ALPHR, BETA, RSAFMN, SAFMIN, XNORM, ZR,
     $                   zi
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, infog2l, pdznrm2,
     $                   zgebr2d, zgebs2d, pzscal,
     $                   pzdscal, dladiv
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLAPY3
      EXTERNAL           dlamch, dlapy3
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, dimag, sign
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters.
*
      ictxt = descx( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      IF( incx.EQ.descx( m_ ) ) THEN
*
*        sub( X ) is distributed across a process row.
*
         CALL infog2l( ix, jax, descx, nprow, npcol, myrow, mycol,
     $                 iiax, jjax, ixrow, ixcol )
*
         IF( myrow.NE.ixrow )
     $      RETURN
*
*        Broadcast X(IAX,JAX) across the process row.
*
         IF( mycol.EQ.ixcol ) THEN
            j = iiax+(jjax-1)*descx( lld_ )
            CALL zgebs2d( ictxt, 'Rowwise', ' ', 1, 1, x( j ), 1 )
            alpha = x( j )
         ELSE
            CALL zgebr2d( ictxt, 'Rowwise', ' ', 1, 1, alpha, 1,
     $                    myrow, ixcol )
         END IF
*
         indxtau = iiax
*
      ELSE
*
*        sub( X ) is distributed across a process column.
*
         CALL infog2l( iax, jx, descx, nprow, npcol, myrow, mycol,
     $                 iiax, jjax, ixrow, ixcol )
*
         IF( mycol.NE.ixcol )
     $      RETURN
*
*        Broadcast X(IAX,JAX) across the process column.
*
         IF( myrow.EQ.ixrow ) THEN
            j = iiax+(jjax-1)*descx( lld_ )
            CALL zgebs2d( ictxt, 'Columnwise', ' ', 1, 1, x( j ), 1 )
            alpha = x( j )
         ELSE
            CALL zgebr2d( ictxt, 'Columnwise', ' ', 1, 1, alpha, 1,
     $                    ixrow, mycol )
         END IF
*
         indxtau = jjax
*
      END IF
*
      IF( n.LE.0 ) THEN
         tau( indxtau ) = zero
         RETURN
      END IF
*
      CALL pdznrm2( n-1, xnorm, x, ix, jx, descx, incx )
      alphr = dble( alpha )
      alphi = dimag( alpha )
*
      IF( xnorm.EQ.zero .AND. alphi.EQ.zero ) THEN
*
*        H = I
*
         tau( indxtau ) = zero
*
      ELSE
*
*        General case
*
         beta = -sign( dlapy3( alphr, alphi, xnorm ), alphr )
         safmin = dlamch( 'S' )
         rsafmn = one / safmin
         IF( abs( beta ).LT.safmin ) THEN
*
*           XNORM, BETA may be inaccurate; scale X and recompute them
*
            knt = 0
   10       CONTINUE
            knt = knt + 1
            CALL pzdscal( n-1, rsafmn, x, ix, jx, descx, incx )
            beta = beta*rsafmn
            alphi = alphi*rsafmn
            alphr = alphr*rsafmn
            IF( abs( beta ).LT.safmin )
     $         GO TO 10
*
*           New BETA is at most 1, at least SAFMIN
*
            CALL pdznrm2( n-1, xnorm, x, ix, jx, descx, incx )
            alpha = dcmplx( alphr, alphi )
            beta = -sign( dlapy3( alphr, alphi, xnorm ), alphr )
            tau( indxtau ) = dcmplx( ( beta-alphr ) / beta,
     $                                 -alphi / beta )
            CALL dladiv( one, zero, dble( alpha-beta ),
     $              dimag( alpha-beta ), zr, zi )
            alpha = dcmplx( zr, zi )
            CALL pzscal( n-1, alpha, x, ix, jx, descx, incx )
*
*           If ALPHA is subnormal, it may lose relative accuracy
*
            alpha = beta
            DO 20 j = 1, knt
               alpha = alpha*safmin
   20       CONTINUE
         ELSE
            tau( indxtau ) = dcmplx( ( beta-alphr ) / beta,
     $                               -alphi / beta )
            CALL dladiv( one, zero, dble( alpha-beta ),
     $              dimag( alpha-beta ), zr, zi )
            alpha = dcmplx( zr, zi )
            CALL pzscal( n-1, alpha, x, ix, jx, descx, incx )
            alpha = beta
         END IF
      END IF
*
      RETURN
*
*     End of PZLARFG
*
      END