cpttrsv.f

Go to the documentation of this file.

      SUBROUTINE cpttrsv( UPLO, TRANS, N, NRHS, D, E, B, LDB,
     $                        INFO )
*
*  -- ScaLAPACK auxiliary routine (version 2.0) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*
*     Written by Andrew J. Cleary, University of Tennessee.
*     November, 1996.
*     Modified from CPTTRS:
*  -- LAPACK routine (preliminary version) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO, TRANS
      INTEGER            INFO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               D( * )
      COMPLEX            B( LDB, * ), E( * )
*     ..
*
*  Purpose
*  =======
*
*  CPTTRSV solves one of the triangular systems
*     L * X = B, or  L**H * X = B,
*     U * X = B, or  U**H * X = B,
*  where L or U is the Cholesky factor of a Hermitian positive
*  definite tridiagonal matrix A such that
*  A = U**H*D*U or A = L*D*L**H (computed by CPTTRF).
*
*  Arguments
*  =========
*
*  UPLO    (input) CHARACTER*1
*          Specifies whether the superdiagonal or the subdiagonal
*          of the tridiagonal matrix A is stored and the form of the
*          factorization:
*          = 'U':  E is the superdiagonal of U, and A = U'*D*U;
*          = 'L':  E is the subdiagonal of L, and A = L*D*L'.
*          (The two forms are equivalent if A is real.)
*
*  TRANS   (input) CHARACTER
*          Specifies the form of the system of equations:
*          = 'N':  L * X = B     (No transpose)
*          = 'N':  L * X = B     (No transpose)
*          = 'C':  U**H * X = B  (Conjugate transpose)
*          = 'C':  L**H * X = B  (Conjugate transpose)
*
*  N       (input) INTEGER
*          The order of the tridiagonal matrix A.  N >= 0.
*
*  NRHS    (input) INTEGER
*          The number of right hand sides, i.e., the number of columns
*          of the matrix B.  NRHS >= 0.
*
*  D       (input) REAL array, dimension (N)
*          The n diagonal elements of the diagonal matrix D from the
*          factorization computed by CPTTRF.
*
*  E       (input) COMPLEX array, dimension (N-1)
*          The (n-1) off-diagonal elements of the unit bidiagonal
*          factor U or L from the factorization computed by CPTTRF
*          (see UPLO).
*
*  B       (input/output) COMPLEX array, dimension (LDB,NRHS)
*          On entry, the right hand side matrix B.
*          On exit, the solution matrix X.
*
*  LDB     (input) INTEGER
*          The leading dimension of the array B.  LDB >= max(1,N).
*
*  INFO    (output) INTEGER
*          = 0:  successful exit
*          < 0:  if INFO = -i, the i-th argument had an illegal value
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            NOTRAN, UPPER
      INTEGER            I, J
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg, max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      notran = lsame( trans, 'N' )
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.notran .AND. .NOT.
     $    lsame( trans, 'C' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( nrhs.LT.0 ) THEN
         info = -4
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPTTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
      IF( .NOT.notran ) THEN
*
         DO 30 j = 1, nrhs
*
*           Solve U**T (or H) * x = b.
*
            DO 10 i = 2, n
               b( i, j ) = b( i, j ) - b( i-1, j )*conjg( e( i-1 ) )
   10       CONTINUE
   30    CONTINUE
*
      ELSE
*
         DO 35 j = 1, nrhs
*
*           Solve U * x = b.
*
            DO 20 i = n - 1, 1, -1
               b( i, j ) = b( i, j ) - b( i+1, j )*e( i )
   20       CONTINUE
   35    CONTINUE
      ENDIF
*
      ELSE
*
      IF( notran ) THEN
*
         DO 60 j = 1, nrhs
*
*           Solve L * x = b.
*
            DO 40 i = 2, n
               b( i, j ) = b( i, j ) - b( i-1, j )*e( i-1 )
   40       CONTINUE
   60    CONTINUE
*
      ELSE
*
         DO 65 j = 1, nrhs
*
*           Solve L**H * x = b.
*
            DO 50 i = n - 1, 1, -1
               b( i, j ) = b( i, j ) -
     $                     b( i+1, j )*conjg( e( i ) )
   50       CONTINUE
   65    CONTINUE
      ENDIF
*
      END IF
*
      RETURN
*
*     End of CPTTRS
*
      END