dasymv.f

Go to the documentation of this file.

      SUBROUTINE dasymv( UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y,
     $                   INCY )
*
*  -- PBLAS auxiliary routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        UPLO
      INTEGER            INCX, INCY, LDA, N
      DOUBLE PRECISION   ALPHA, BETA
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  DASYMV performs the following matrix-vector operation
*
*     y := abs( alpha )*abs( A )*abs( x )+ abs( beta*y ),
*
*  where  alpha  and  beta  are real scalars, y is a real vector, x is a
*  vector and A is an n by n symmetric matrix.
*
*  Arguments
*  =========
*
*  UPLO    (input) CHARACTER*1
*          On entry, UPLO  specifies whether the upper or lower triangu-
*          lar part of the array A is to be referenced as follows:
*
*             UPLO = 'U' or 'u'   Only the upper triangular part of A is
*                                 to be referenced.
*             UPLO = 'L' or 'l'   Only the lower triangular part of A is
*                                 to be referenced.
*
*  N       (input) INTEGER
*          On entry, N specifies the order of the matrix A. N must be at
*          least zero.
*
*  ALPHA   (input) DOUBLE PRECISION
*          On entry, ALPHA specifies the real scalar alpha.
*
*  A       (input) DOUBLE PRECISION array
*          On entry,  A  is an array of dimension (LDA,N).  Before entry
*          with UPLO = 'U' or 'u', the leading n by n part of the  array
*          A must contain the upper triangular part of the symmetric ma-
*          trix and the strictly lower triangular part of A is not refe-
*          renced.  When  UPLO = 'L' or 'l',  the leading n by n part of
*          the array  A  must  contain  the lower triangular part of the
*          symmetric matrix and the strictly upper trapezoidal part of A
*          is not referenced.
*
*  LDA     (input) INTEGER
*          On entry, LDA specifies the leading dimension of the array A.
*          LDA must be at least max( 1, N ).
*
*  X       (input) DOUBLE PRECISION array of dimension at least
*          ( 1 + ( n - 1 )*abs( INCX ) ).  Before entry, the incremented
*          array X must contain the vector x.
*
*  INCX    (input) INTEGER
*          On entry, INCX specifies the increment for the elements of X.
*          INCX must not be zero.
*
*  BETA    (input) DOUBLE PRECISION
*          On entry,  BETA  specifies the real scalar beta. When BETA is
*          supplied as zero then Y need not be set on input.
*
*  Y       (input/output) DOUBLE PRECISION array of dimension at least
*          ( 1 + ( n - 1 )*abs( INCY ) ).  Before  entry with  BETA non-
*          zero, the  incremented array  Y must contain the vector y. On
*          exit, the  incremented array  Y is overwritten by the updated
*          vector y.
*
*  INCY    (input) INTEGER
*          On entry, INCY specifies the increment for the elements of Y.
*          INCY must not be zero.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, IX, IY, J, JX, JY, KX, KY
      DOUBLE PRECISION   TALPHA, TEMP0, TEMP1, TEMP2
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF     ( .NOT.lsame( uplo, 'U' ).AND.
     $         .NOT.lsame( uplo, 'L' )      )THEN
         info = 1
      ELSE IF( n.LT.0 )THEN
         info = 2
      ELSE IF( lda.LT.max( 1, n ) )THEN
         info = 5
      ELSE IF( incx.EQ.0 )THEN
         info = 7
      ELSE IF( incy.EQ.0 )THEN
         info = 10
      END IF
      IF( info.NE.0 )THEN
         CALL xerbla( 'DASYMV', info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( ( n.EQ.0 ).OR.( ( alpha.EQ.zero ).AND.( beta.EQ.one ) ) )
     $   RETURN
*
*     Set up the start points in  X  and  Y.
*
      IF( incx.GT.0 ) THEN
         kx = 1
      ELSE
         kx = 1 - ( n - 1 ) * incx
      END IF
      IF( incy.GT.0 )THEN
         ky = 1
      ELSE
         ky = 1 - ( n - 1 ) * incy
      END IF
*
*     Start the operations. In this version the elements of A are
*     accessed sequentially with one pass through the triangular part
*     of A.
*
*     First form  y := abs( beta * y ).
*
      IF( beta.NE.one ) THEN
         IF( incy.EQ.1 ) THEN
            IF( beta.EQ.zero ) THEN
               DO 10, i = 1, n
                  y( i ) = zero
   10          CONTINUE
            ELSE
               DO 20, i = 1, n
                  y( i ) = abs( beta * y( i ) )
   20          CONTINUE
            END IF
         ELSE
            iy = ky
            IF( beta.EQ.zero ) THEN
               DO 30, i = 1, n
                  y( iy ) = zero
                  iy      = iy   + incy
   30          CONTINUE
            ELSE
               DO 40, i = 1, n
                  y( iy ) = abs( beta * y( iy ) )
                  iy      = iy           + incy
   40          CONTINUE
            END IF
         END IF
      END IF
*
      IF( alpha.EQ.zero )
     $   RETURN
*
      talpha = abs( alpha )
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Form  y  when A is stored in upper triangle.
*
         IF( ( incx.EQ.1 ).AND.( incy.EQ.1 ) ) THEN
            DO 60, j = 1, n
               temp1 = talpha * abs( x( j ) )
               temp2 = zero
               DO 50, i = 1, j - 1
                  temp0  = abs( a( i, j ) )
                  y( i ) = y( i ) + temp1 * temp0
                  temp2  = temp2  + temp0 * abs( x( i ) )
   50          CONTINUE
               y( j ) = y( j ) + temp1 * abs( a( j, j ) ) +
     $                  alpha * temp2
*
   60       CONTINUE
*
         ELSE
*
            jx = kx
            jy = ky
*
            DO 80, j = 1, n
               temp1 = talpha * abs( x( jx ) )
               temp2 = zero
               ix    = kx
               iy    = ky
*
               DO 70, i = 1, j - 1
                  temp0   = abs( a( i, j ) )
                  y( iy ) = y( iy ) + temp1 * temp0
                  temp2   = temp2   + temp0 * abs( x( ix ) )
                  ix      = ix      + incx
                  iy      = iy      + incy
   70          CONTINUE
               y( jy ) = y( jy ) + temp1 * abs( a( j, j ) ) +
     $                   alpha * temp2
               jx      = jx      + incx
               jy      = jy      + incy
*
   80       CONTINUE
*
         END IF
*
      ELSE
*
*        Form  y  when A is stored in lower triangle.
*
         IF( ( incx.EQ.1 ).AND.( incy.EQ.1 ) ) THEN
*
            DO 100, j = 1, n
*
               temp1 = talpha * abs( x( j ) )
               temp2  = zero
               y( j ) = y( j ) + temp1 * abs( a( j, j ) )
*
               DO 90, i = j + 1, n
                  temp0  = abs( a( i, j ) )
                  y( i ) = y( i ) + temp1 * temp0
                  temp2  = temp2  + temp0 * abs( x( i ) )
*
   90          CONTINUE
*
               y( j ) = y( j ) + alpha * temp2
*
  100       CONTINUE
*
         ELSE
*
            jx = kx
            jy = ky
*
            DO 120, j = 1, n
               temp1 = talpha * abs( x( jx ) )
               temp2   = zero
               y( jy ) = y( jy ) + temp1 * abs( a( j, j ) )
               ix      = jx
               iy      = jy
*
               DO 110, i = j + 1, n
*
                  ix      = ix      + incx
                  iy      = iy      + incy
                  temp0   = abs( a( i, j ) )
                  y( iy ) = y( iy ) + temp1 * temp0
                  temp2   = temp2   + temp0 * abs( x( ix ) )
*
  110          CONTINUE
*
               y( jy ) = y( jy ) + alpha * temp2
               jx      = jx      + incx
               jy      = jy      + incy
*
  120       CONTINUE
*
         END IF
*
      END IF
*
      RETURN
*
*     End of DASYMV
*
      END