pchegs2.f

Go to the documentation of this file.

*
*
      SUBROUTINE pchegs2( IBTYPE, UPLO, N, A, IA, JA, DESCA, B, IB, JB,
     $                    DESCB, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, IB, IBTYPE, INFO, JA, JB, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCB( * )
      COMPLEX            A( * ), B( * )
*     ..
*
*  Purpose
*  =======
*
*  PCHEGS2 reduces a complex Hermitian-definite generalized eigenproblem
*  to standard form.
*
*  In the following sub( A ) denotes A( IA:IA+N-1, JA:JA+N-1 ) and
*  sub( B ) denotes B( IB:IB+N-1, JB:JB+N-1 ).
*
*  If IBTYPE = 1, the problem is sub( A )*x = lambda*sub( B )*x,
*  and sub( A ) is overwritten by inv(U**H)*sub( A )*inv(U) or
*  inv(L)*sub( A )*inv(L**H)
*
*  If IBTYPE = 2 or 3, the problem is sub( A )*sub( B )*x = lambda*x or
*  sub( B )*sub( A )*x = lambda*x, and sub( A ) is overwritten by
*  U*sub( A )*U**H or L**H*sub( A )*L.
*
*  sub( B ) must have been previously factorized as U**H*U or L*L**H by
*  PCPOTRF.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  IBTYPE   (global input) INTEGER
*          = 1: compute inv(U**H)*sub( A )*inv(U) or
*               inv(L)*sub( A )*inv(L**H);
*          = 2 or 3: compute U*sub( A )*U**H or L**H*sub( A )*L.
*
*  UPLO    (global input) CHARACTER
*          = 'U':  Upper triangle of sub( A ) is stored and sub( B ) is
*                  factored as U**H*U;
*          = 'L':  Lower triangle of sub( A ) is stored and sub( B ) is
*                  factored as L*L**H.
*
*  N       (global input) INTEGER
*          The order of the matrices sub( A ) and sub( B ).  N >= 0.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          N-by-N Hermitian distributed matrix sub( A ). If UPLO = 'U',
*          the leading N-by-N upper triangular part of sub( A ) contains
*          the upper triangular part of the matrix, and its strictly
*          lower triangular part is not referenced.  If UPLO = 'L', the
*          leading N-by-N lower triangular part of sub( A ) contains
*          the lower triangular part of the matrix, and its strictly
*          upper triangular part is not referenced.
*
*          On exit, if INFO = 0, the transformed matrix, stored in the
*          same format as sub( A ).
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  B       (local input) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_B, LOCc(JB+N-1)). On entry,
*          this array contains the local pieces of the triangular factor
*          from the Cholesky factorization of sub( B ), as returned by
*          PCPOTRF.
*
*  IB      (global input) INTEGER
*          B's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JB      (global input) INTEGER
*          B's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCB   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix B.
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   mb_, nb_, rsrc_, csrc_, lld_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE, HALF
      parameter( one = 1.0e+0, half = 0.5e+0 )
      COMPLEX            CONE
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            IACOL, IAROW, IBCOL, IBROW, ICOFFA, ICOFFB,
     $                   ictxt, iia, iib, ioffa, ioffb, iroffa, iroffb,
     $                   jja, jjb, k, lda, ldb, mycol, myrow, npcol,
     $                   nprow
      REAL               AKK, BKK
      COMPLEX            CT
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_exit, blacs_gridinfo, caxpy, cher2,
     $                   chk1mat, clacgv, csscal, ctrmv, ctrsv, infog2l,
     $                   pxerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          mod, real
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            INDXG2P
      EXTERNAL           lsame, indxg2p
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters.
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -( 700+ctxt_ )
      ELSE
         upper = lsame( uplo, 'U' )
         CALL chk1mat( n, 3, n, 3, ia, ja, desca, 7, info )
         CALL chk1mat( n, 3, n, 3, ib, jb, descb, 11, info )
         IF( info.EQ.0 ) THEN
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $              nprow )
            ibrow = indxg2p( ib, descb( mb_ ), myrow, descb( rsrc_ ),
     $              nprow )
            iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $              npcol )
            ibcol = indxg2p( jb, descb( nb_ ), mycol, descb( csrc_ ),
     $              npcol )
            iroffa = mod( ia-1, desca( mb_ ) )
            icoffa = mod( ja-1, desca( nb_ ) )
            iroffb = mod( ib-1, descb( mb_ ) )
            icoffb = mod( jb-1, descb( nb_ ) )
            IF( ibtype.LT.1 .OR. ibtype.GT.3 ) THEN
               info = -1
            ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
               info = -2
            ELSE IF( n.LT.0 ) THEN
               info = -3
            ELSE IF( n+icoffa.GT.desca( nb_ ) ) THEN
               info = -3
            ELSE IF( iroffa.NE.0 ) THEN
               info = -5
            ELSE IF( icoffa.NE.0 ) THEN
               info = -6
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -( 700+nb_ )
            ELSE IF( iroffb.NE.0 .OR. ibrow.NE.iarow ) THEN
               info = -9
            ELSE IF( icoffb.NE.0 .OR. ibcol.NE.iacol ) THEN
               info = -10
            ELSE IF( descb( mb_ ).NE.desca( mb_ ) ) THEN
               info = -( 1100+mb_ )
            ELSE IF( descb( nb_ ).NE.desca( nb_ ) ) THEN
               info = -( 1100+nb_ )
            ELSE IF( ictxt.NE.descb( ctxt_ ) ) THEN
               info = -( 1100+ctxt_ )
            END IF
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PCHEGS2', -info )
         CALL blacs_exit( ictxt )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. ( myrow.NE.iarow .OR. mycol.NE.iacol ) )
     $   RETURN
*
*     Compute local information
*
      lda = desca( lld_ )
      ldb = descb( lld_ )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iib, jjb,
     $              ibrow, ibcol )
*
      IF( ibtype.EQ.1 ) THEN
*
         IF( upper ) THEN
*
            ioffa = iia + jja*lda
            ioffb = iib + jjb*ldb
*
*           Compute inv(U')*sub( A )*inv(U)
*
            DO 10 k = 1, n
*
*              Update the upper triangle of
*              A(ia+k-1:ia+n-a,ia+k-1:ia+n-1)
*
               akk = real( a( ioffa-lda ) )
               bkk = real( b( ioffb-ldb ) )
               akk = akk / bkk**2
               a( ioffa-lda ) = akk
               IF( k.LT.n ) THEN
                  CALL csscal( n-k, one / bkk, a( ioffa ), lda )
                  ct = -half*akk
                  CALL clacgv( n-k, a( ioffa ), lda )
                  CALL clacgv( n-k, b( ioffb ), ldb )
                  CALL caxpy( n-k, ct, b( ioffb ), ldb, a( ioffa ),
     $                        lda )
                  CALL cher2( uplo, n-k, -cone, a( ioffa ), lda,
     $                        b( ioffb ), ldb, a( ioffa+1 ), lda )
                  CALL caxpy( n-k, ct, b( ioffb ), ldb, a( ioffa ),
     $                        lda )
                  CALL clacgv( n-k, b( ioffb ), ldb )
                  CALL ctrsv( uplo, 'Conjugate transpose', 'Non-unit',
     $                        n-k, b( ioffb+1 ), ldb, a( ioffa ), lda )
                  CALL clacgv( n-k, a( ioffa ), lda )
               END IF
*
*              A( IOFFA ) -> A( K, K+1 )
*              B( IOFFB ) -> B( K, K+1 )
*
               ioffa = ioffa + lda + 1
               ioffb = ioffb + ldb + 1
*
   10       CONTINUE
*
         ELSE
*
            ioffa = iia + 1 + ( jja-1 )*lda
            ioffb = iib + 1 + ( jjb-1 )*ldb
*
*           Compute inv(L)*sub( A )*inv(L')
*
            DO 20 k = 1, n
*
*              Update the lower triangle of
*              A(ia+k-1:ia+n-a,ia+k-1:ia+n-1)
*
               akk = real( a( ioffa-1 ) )
               bkk = real( b( ioffb-1 ) )
               akk = akk / bkk**2
               a( ioffa-1 ) = akk
*
               IF( k.LT.n ) THEN
                  CALL csscal( n-k, one / bkk, a( ioffa ), 1 )
                  ct = -half*akk
                  CALL caxpy( n-k, ct, b( ioffb ), 1, a( ioffa ), 1 )
                  CALL cher2( uplo, n-k, -cone, a( ioffa ), 1,
     $                        b( ioffb ), 1, a( ioffa+lda ), lda )
                  CALL caxpy( n-k, ct, b( ioffb ), 1, a( ioffa ), 1 )
                  CALL ctrsv( uplo, 'No transpose', 'Non-unit', n-k,
     $                        b( ioffb+ldb ), ldb, a( ioffa ), 1 )
               END IF
*
*              A( IOFFA ) -> A( K+1, K )
*              B( IOFFB ) -> B( K+1, K )
*
               ioffa = ioffa + lda + 1
               ioffb = ioffb + ldb + 1
*
   20       CONTINUE
*
         END IF
*
      ELSE
*
         IF( upper ) THEN
*
            ioffa = iia + ( jja-1 )*lda
            ioffb = iib + ( jjb-1 )*ldb
*
*           Compute U*sub( A )*U'
*
            DO 30 k = 1, n
*
*              Update the upper triangle of A(ia:ia+k-1,ja:ja+k-1)
*
               akk = real( a( ioffa+k-1 ) )
               bkk = real( b( ioffb+k-1 ) )
               CALL ctrmv( uplo, 'No transpose', 'Non-unit', k-1,
     $                     b( iib+( jjb-1 )*ldb ), ldb, a( ioffa ), 1 )
               ct = half*akk
               CALL caxpy( k-1, ct, b( ioffb ), 1, a( ioffa ), 1 )
               CALL cher2( uplo, k-1, cone, a( ioffa ), 1, b( ioffb ),
     $                     1, a( iia+( jja-1 )*lda ), lda )
               CALL caxpy( k-1, ct, b( ioffb ), 1, a( ioffa ), 1 )
               CALL csscal( k-1, bkk, a( ioffa ), 1 )
               a( ioffa+k-1 ) = akk*bkk**2
*
*              A( IOFFA ) -> A( 1, K )
*              B( IOFFB ) -> B( 1, K )
*
               ioffa = ioffa + lda
               ioffb = ioffb + ldb
*
   30       CONTINUE
*
         ELSE
*
            ioffa = iia + ( jja-1 )*lda
            ioffb = iib + ( jjb-1 )*ldb
*
*           Compute L'*sub( A )*L
*
            DO 40 k = 1, n
*
*              Update the lower triangle of A(ia:ia+k-1,ja:ja+k-1)
*
               akk = real( a( ioffa+( k-1 )*lda ) )
               bkk = real( b( ioffb+( k-1 )*ldb ) )
               CALL clacgv( k-1, a( ioffa ), lda )
               CALL ctrmv( uplo, 'Conjugate transpose', 'Non-unit', k-1,
     $                     b( iib+( jjb-1 )*ldb ), ldb, a( ioffa ),
     $                     lda )
               ct = half*akk
               CALL clacgv( k-1, b( ioffb ), ldb )
               CALL caxpy( k-1, ct, b( ioffb ), ldb, a( ioffa ), lda )
               CALL cher2( uplo, k-1, cone, a( ioffa ), lda, b( ioffb ),
     $                     ldb, a( iia+( jja-1 )*lda ), lda )
               CALL caxpy( k-1, ct, b( ioffb ), ldb, a( ioffa ), lda )
               CALL clacgv( k-1, b( ioffb ), ldb )
               CALL csscal( k-1, bkk, a( ioffa ), lda )
               CALL clacgv( k-1, a( ioffa ), lda )
               a( ioffa+( k-1 )*lda ) = akk*bkk**2
*
*              A( IOFFA ) -> A( K, 1 )
*              B( IOFFB ) -> B( K, 1 )
*
               ioffa = ioffa + 1
               ioffb = ioffb + 1
*
   40       CONTINUE
*
         END IF
*
      END IF
*
      RETURN
*
*     End of PCHEGS2
*
      END