ScaLAPACK 2.1  2.1
ScaLAPACK: Scalable Linear Algebra PACKage
pdorgl2.f
Go to the documentation of this file.
1  SUBROUTINE pdorgl2( M, N, K, A, IA, JA, DESCA, TAU, WORK, LWORK,
2  $ INFO )
3 *
4 * -- ScaLAPACK routine (version 1.7) --
5 * University of Tennessee, Knoxville, Oak Ridge National Laboratory,
6 * and University of California, Berkeley.
7 * May 25, 2001
8 *
9 * .. Scalar Arguments ..
10  INTEGER IA, INFO, JA, K, LWORK, M, N
11 * ..
12 * .. Array Arguments ..
13  INTEGER DESCA( * )
14  DOUBLE PRECISION A( * ), TAU( * ), WORK( * )
15 * ..
16 *
17 * Purpose
18 * =======
19 *
20 * PDORGL2 generates an M-by-N real distributed matrix Q denoting
21 * A(IA:IA+M-1,JA:JA+N-1) with orthonormal rows, which is defined as
22 * the first M rows of a product of K elementary reflectors of order N
23 *
24 * Q = H(k) . . . H(2) H(1)
25 *
26 * as returned by PDGELQF.
27 *
28 * Notes
29 * =====
30 *
31 * Each global data object is described by an associated description
32 * vector. This vector stores the information required to establish
33 * the mapping between an object element and its corresponding process
34 * and memory location.
35 *
36 * Let A be a generic term for any 2D block cyclicly distributed array.
37 * Such a global array has an associated description vector DESCA.
38 * In the following comments, the character _ should be read as
39 * "of the global array".
40 *
41 * NOTATION STORED IN EXPLANATION
42 * --------------- -------------- --------------------------------------
43 * DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
44 * DTYPE_A = 1.
45 * CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
46 * the BLACS process grid A is distribu-
47 * ted over. The context itself is glo-
48 * bal, but the handle (the integer
49 * value) may vary.
50 * M_A (global) DESCA( M_ ) The number of rows in the global
51 * array A.
52 * N_A (global) DESCA( N_ ) The number of columns in the global
53 * array A.
54 * MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
55 * the rows of the array.
56 * NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
57 * the columns of the array.
58 * RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
59 * row of the array A is distributed.
60 * CSRC_A (global) DESCA( CSRC_ ) The process column over which the
61 * first column of the array A is
62 * distributed.
63 * LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
64 * array. LLD_A >= MAX(1,LOCr(M_A)).
65 *
66 * Let K be the number of rows or columns of a distributed matrix,
67 * and assume that its process grid has dimension p x q.
68 * LOCr( K ) denotes the number of elements of K that a process
69 * would receive if K were distributed over the p processes of its
70 * process column.
71 * Similarly, LOCc( K ) denotes the number of elements of K that a
72 * process would receive if K were distributed over the q processes of
73 * its process row.
74 * The values of LOCr() and LOCc() may be determined via a call to the
75 * ScaLAPACK tool function, NUMROC:
76 * LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
77 * LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
78 * An upper bound for these quantities may be computed by:
79 * LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
80 * LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
81 *
82 * Arguments
83 * =========
84 *
85 * M (global input) INTEGER
86 * The number of rows to be operated on i.e the number of rows
87 * of the distributed submatrix Q. M >= 0.
88 *
89 * N (global input) INTEGER
90 * The number of columns to be operated on i.e the number of
91 * columns of the distributed submatrix Q. N >= M >= 0.
92 *
93 * K (global input) INTEGER
94 * The number of elementary reflectors whose product defines the
95 * matrix Q. M >= K >= 0.
96 *
97 * A (local input/local output) DOUBLE PRECISION pointer into the
98 * local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
99 * On entry, the i-th row must contain the vector which defines
100 * the elementary reflector H(i), IA <= i <= IA+K-1, as
101 * returned by PDGELQF in the K rows of its distributed matrix
102 * argument A(IA:IA+K-1,JA:*). On exit, this array contains the
103 * local pieces of the M-by-N distributed matrix Q.
104 *
105 * IA (global input) INTEGER
106 * The row index in the global array A indicating the first
107 * row of sub( A ).
108 *
109 * JA (global input) INTEGER
110 * The column index in the global array A indicating the
111 * first column of sub( A ).
112 *
113 * DESCA (global and local input) INTEGER array of dimension DLEN_.
114 * The array descriptor for the distributed matrix A.
115 *
116 * TAU (local input) DOUBLE PRECISION array, dimension LOCr(IA+K-1).
117 * This array contains the scalar factors TAU(i) of the
118 * elementary reflectors H(i) as returned by PDGELQF.
119 * TAU is tied to the distributed matrix A.
120 *
121 * WORK (local workspace/local output) DOUBLE PRECISION array,
122 * dimension (LWORK)
123 * On exit, WORK(1) returns the minimal and optimal LWORK.
124 *
125 * LWORK (local or global input) INTEGER
126 * The dimension of the array WORK.
127 * LWORK is local input and must be at least
128 * LWORK >= NqA0 + MAX( 1, MpA0 ), where
129 *
130 * IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
131 * IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
132 * IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
133 * MpA0 = NUMROC( M+IROFFA, MB_A, MYROW, IAROW, NPROW ),
134 * NqA0 = NUMROC( N+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
135 *
136 * INDXG2P and NUMROC are ScaLAPACK tool functions;
137 * MYROW, MYCOL, NPROW and NPCOL can be determined by calling
138 * the subroutine BLACS_GRIDINFO.
139 *
140 * If LWORK = -1, then LWORK is global input and a workspace
141 * query is assumed; the routine only calculates the minimum
142 * and optimal size for all work arrays. Each of these
143 * values is returned in the first entry of the corresponding
144 * work array, and no error message is issued by PXERBLA.
145 *
146 *
147 * INFO (local output) INTEGER
148 * = 0: successful exit
149 * < 0: If the i-th argument is an array and the j-entry had
150 * an illegal value, then INFO = -(i*100+j), if the i-th
151 * argument is a scalar and had an illegal value, then
152 * INFO = -i.
153 *
154 * =====================================================================
155 *
156 * .. Parameters ..
157  INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
158  $ lld_, mb_, m_, nb_, n_, rsrc_
159  parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
160  $ ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
161  $ rsrc_ = 7, csrc_ = 8, lld_ = 9 )
162  DOUBLE PRECISION ONE, ZERO
163  parameter( one = 1.0d+0, zero = 0.0d+0 )
164 * ..
165 * .. Local Scalars ..
166  LOGICAL LQUERY
167  CHARACTER COLBTOP, ROWBTOP
168  INTEGER IACOL, IAROW, I, ICTXT, II, J, KP, LWMIN, MPA0,
169  $ mycol, myrow, npcol, nprow, nqa0
170  DOUBLE PRECISION TAUI
171 * ..
172 * .. External Subroutines ..
173  EXTERNAL blacs_abort, blacs_gridinfo, chk1mat, pdelset,
174  $ pdlarf, pdlaset, pdscal, pb_topget,
175  $ pb_topset, pxerbla
176 * ..
177 * .. External Functions ..
178  INTEGER INDXG2L, INDXG2P, NUMROC
179  EXTERNAL indxg2l, indxg2p, numroc
180 * ..
181 * .. Intrinsic Functions ..
182  INTRINSIC dble, max, min, mod
183 * ..
184 * .. Executable Statements ..
185 *
186 * Get grid parameters
187 *
188  ictxt = desca( ctxt_ )
189  CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
190 *
191 * Test the input parameters
192 *
193  info = 0
194  IF( nprow.EQ.-1 ) THEN
195  info = -(700+ctxt_)
196  ELSE
197  CALL chk1mat( m, 1, n, 2, ia, ja, desca, 7, info )
198  IF( info.EQ.0 ) THEN
199  iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
200  $ nprow )
201  iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
202  $ npcol )
203  mpa0 = numroc( m+mod( ia-1, desca( mb_ ) ), desca( mb_ ),
204  $ myrow, iarow, nprow )
205  nqa0 = numroc( n+mod( ja-1, desca( nb_ ) ), desca( nb_ ),
206  $ mycol, iacol, npcol )
207  lwmin = nqa0 + max( 1, mpa0 )
208 *
209  work( 1 ) = dble( lwmin )
210  lquery = ( lwork.EQ.-1 )
211  IF( n.LT.m ) THEN
212  info = -2
213  ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
214  info = -3
215  ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
216  info = -10
217  END IF
218  END IF
219  END IF
220  IF( info.NE.0 ) THEN
221  CALL pxerbla( ictxt, 'PDORGL2', -info )
222  CALL blacs_abort( ictxt, 1 )
223  RETURN
224  ELSE IF( lquery ) THEN
225  RETURN
226  END IF
227 *
228 * Quick return if possible
229 *
230  IF( m.LE.0 )
231  $ RETURN
232 *
233  CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
234  CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
235  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
236  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'D-ring' )
237 *
238  IF( k.LT.m ) THEN
239 *
240 * Initialise rows ia+k:ia+m-1 to rows of the unit matrix
241 *
242  CALL pdlaset( 'All', m-k, k, zero, zero, a, ia+k, ja, desca )
243  CALL pdlaset( 'All', m-k, n-k, zero, one, a, ia+k, ja+k,
244  $ desca )
245 *
246  END IF
247 *
248  taui = zero
249  kp = numroc( ia+k-1, desca( mb_ ), myrow, desca( rsrc_ ), nprow )
250 *
251  DO 10 i = ia+k-1, ia, -1
252 *
253 * Apply H(i) to A(i:ia+m-1,ja+i-ia:ja+n-1) from the right
254 *
255  j = ja + i - ia
256  ii = indxg2l( i, desca( mb_ ), myrow, desca( rsrc_ ), nprow )
257  iarow = indxg2p( i, desca( mb_ ), myrow, desca( rsrc_ ),
258  $ nprow )
259  IF( myrow.EQ.iarow )
260  $ taui = tau( min( ii, kp ) )
261  IF( j.LT.ja+n-1 ) THEN
262  IF( i.LT.ia+m-1 ) THEN
263  CALL pdelset( a, i, j, desca, one )
264  CALL pdlarf( 'Right', m-i+ia-1, n-j+ja, a, i, j, desca,
265  $ desca( m_ ), tau, a, i+1, j, desca, work )
266  END IF
267  CALL pdscal( n-j+ja-1, -taui, a, i, j+1, desca,
268  $ desca( m_ ) )
269  END IF
270  CALL pdelset( a, i, j, desca, one-taui )
271 *
272 * Set A(i,ja:j-1) to zero
273 *
274  CALL pdlaset( 'All', 1, j-ja, zero, zero, a, i, ja, desca )
275 *
276  10 CONTINUE
277 *
278  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
279  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
280 *
281  work( 1 ) = dble( lwmin )
282 *
283  RETURN
284 *
285 * End of PDORGL2
286 *
287  END
pdlarf
subroutine pdlarf(SIDE, M, N, V, IV, JV, DESCV, INCV, TAU, C, IC, JC, DESCC, WORK)
Definition: pdlarf.f:3
max
#define max(A, B)
Definition: pcgemr.c:180
pdorgl2
subroutine pdorgl2(M, N, K, A, IA, JA, DESCA, TAU, WORK, LWORK, INFO)
Definition: pdorgl2.f:3
pdlaset
subroutine pdlaset(UPLO, M, N, ALPHA, BETA, A, IA, JA, DESCA)
Definition: pdblastst.f:6862
chk1mat
subroutine chk1mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, INFO)
Definition: chk1mat.f:3
pxerbla
subroutine pxerbla(ICTXT, SRNAME, INFO)
Definition: pxerbla.f:2
pdelset
subroutine pdelset(A, IA, JA, DESCA, ALPHA)
Definition: pdelset.f:2
min
#define min(A, B)
Definition: pcgemr.c:181