pichekpad.f

Go to the documentation of this file.

      SUBROUTINE pichekpad( ICTXT, MESS, M, N, A, LDA, IPRE, IPOST,
     $                     CHKVAL )
*
*  -- ScaLAPACK tools routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            ICTXT, IPOST, IPRE, LDA, M, N
      INTEGER            CHKVAL
*     ..
*     .. Array Arguments ..
      CHARACTER          MESS*(*)
      INTEGER            A( * )
*     ..
*
*  Purpose
*  =======
*
*  PICHEKPAD checks that the padding around a local array has not
*  been overwritten since the call to PIFILLPAD.  3 types of errors
*  are reported:
*
*  1) Overwrite in pre-guardzone. This indicates a memory overwrite has
*  occurred in the first IPRE elements which form a buffer before the
*  beginning of A.  Therefore, the error message:
*     'Overwrite in  pre-guardzone: loc(  5) =         18.00000'
*  tells you that the 5th element of the IPRE long buffer has been
*  overwritten with the value 18, where it should still have the value
*  of CHKVAL.
*
*  2) Overwrite in post-guardzone. This indicates a memory overwrite has
*  occurred in the last IPOST elements which form a buffer after the end
*  of A. Error reports are refered from the end of A.  Therefore,
*     'Overwrite in post-guardzone: loc( 19) =         24.00000'
*  tells you that the 19th element after the end of A was overwritten
*  with the value 24, where it should still have the value of CHKVAL.
*
*  3) Overwrite in lda-m gap.  Tells you elements between M and LDA were
*  overwritten.  So,
*     'Overwrite in lda-m gap: A( 12,  3) =         22.00000'
*  tells you that the element at the 12th row and 3rd column of A was
*  overwritten with the value of 22, where it should still have the
*  value of CHKVAL.
*
*  Arguments
*  =========
*
*  ICTXT   (global input) INTEGER
*          The BLACS context handle, indicating the global context of
*          the operation. The context itself is global.
*
*  MESS    (local input) CHARACTER*(*)
*          String containing a user-defined message.
*
*  M       (local input) INTEGER
*          The number of rows in the local array A.
*
*  N       (input) INTEGER
*          The number of columns in the local array A.
*
*  A       (local input) @(typec) array of dimension (LDA,N).
*          A location IPRE elements in front of the array to be checked.
*
*  LDA     (local input) INTEGER
*          The leading Dimension of the local array to be checked.
*
*  IPRE    (local input) INTEGER
*          The size of the guard zone before the start of padded array.
*
*  IPOST   (local input) INTEGER
*          The size of guard zone after the padded array.
*
*  CHKVAL  (local input) @(typec)
*          The value the local array was padded with.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, IAM, IDUMM, INFO, J, K, MYCOL, MYROW,
     $                   npcol, nprow
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, igamx2d
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      iam = myrow*npcol + mycol
      info = -1
*
*     Check buffer in front of A
*
      IF( ipre.GT.0 ) THEN
         DO 10 i = 1, ipre
            IF( a( i ).NE.chkval ) THEN
               WRITE( *, fmt = 9998 ) myrow, mycol, mess, ' pre', i,
     $                                a( i )
               info = iam
            END IF
   10    CONTINUE
      ELSE
         WRITE( *, fmt = * ) 'WARNING no pre-guardzone in PICHEKPAD'
      END IF
*
*     Check buffer after A
*
      IF( ipost.GT.0 ) THEN
         j = ipre+lda*n+1
         DO 20 i = j, j+ipost-1
            IF( a( i ).NE.chkval ) THEN
               WRITE( *, fmt = 9998 ) myrow, mycol, mess, 'post',
     $                                i-j+1, a( i )
               info = iam
            END IF
   20    CONTINUE
      ELSE
         WRITE( *, fmt = * )
     $          'WARNING no post-guardzone buffer in PICHEKPAD'
      END IF
*
*     Check all (LDA-M) gaps
*
      IF( lda.GT.m ) THEN
         k = ipre + m + 1
         DO 40 j = 1, n
            DO 30 i = k, k + (lda-m) - 1
               IF( a( i ).NE.chkval ) THEN
                  WRITE( *, fmt = 9997 ) myrow, mycol, mess,
     $               i-ipre-lda*(j-1), j, a( i )
                  info = iam
               END IF
   30       CONTINUE
            k = k + lda
   40    CONTINUE
      END IF
*
      CALL igamx2d( ictxt, 'All', ' ', 1, 1, info, 1, idumm, idumm, -1,
     $              0, 0 )
      IF( iam.EQ.0 .AND. info.GE.0 ) THEN
         WRITE( *, fmt = 9999 ) info / npcol, mod( info, npcol ), mess
      END IF
*
 9999 FORMAT( '{', i5, ',', i5, '}:  Memory overwrite in ', a )
 9998 FORMAT( '{', i5, ',', i5, '}:  ', a, ' memory overwrite in ',
     $        a4, '-guardzone: loc(', i3, ') = ', i8 )
 9997 FORMAT( '{', i5, ',', i5, '}: ', a, ' memory overwrite in ',
     $        'lda-m gap: loc(', i3, ',', i3, ') = ', i8 )
*
      RETURN
*
*     End of PICHEKPAD
*
      END