dmatadd.f

Go to the documentation of this file.

      SUBROUTINE dmatadd( M, N, ALPHA, A, LDA, BETA, C, LDC )
*
*  -- ScaLAPACK tools routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDC, M, N
      DOUBLE PRECISION   ALPHA, BETA
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), C( LDC, * )
*     ..
*
*  Purpose
*  =======
*
*  DMATADD performs the following local matrix-matrix operation
*
*               C := alpha * A + beta * C,
*
*  where alpha and beta are scalars, and A and C are m by n arrays.
*
*  Arguments
*  =========
*
*  M       (local input) INTEGER
*          The number of rows of the array A. M >= 0.
*
*  N       (local input) INTEGER
*          The number of columns of the array A. N >= 0.
*
*  ALPHA   (local input) DOUBLE PRECISION
*          The scalar ALPHA.
*
*  A       (local input) DOUBLE PRECISION
*          Array, dimension (LDA,*), the array A.
*
*  LDA     (local input) INTEGER
*          The leading dimension of the array A, LDA >= MAX(1, M)
*
*  BETA    (local input) DOUBLE PRECISION
*          The scalar BETA.
*
*  C       (local input/local output) DOUBLE PRECISION
*          Array, dimension (LDC,*), the array C.
*
*  LDC     (local input) INTEGER
*          The leading dimension of the array C, LDC >= MAX(1, M)
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one  = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      IF( (m.EQ.0).OR.(n.EQ.0).OR.((alpha.EQ.zero).AND.(beta.EQ.one)) )
     $   RETURN
*
      IF( n.EQ.1 ) THEN
         IF( beta.EQ.zero ) THEN
            IF( alpha.EQ.zero ) THEN
               DO 10 i = 1, m
                  c( i, 1 ) = zero
   10          CONTINUE
            ELSE
               DO 20  i = 1, m
                  c( i, 1 ) = alpha*a( i, 1 )
   20          CONTINUE
            END IF
         ELSE
            IF( alpha.EQ.one ) THEN
               IF( beta.EQ.one ) THEN
                  DO 30 i = 1, m
                     c( i, 1 ) = a( i, 1 ) + c( i, 1 )
   30             CONTINUE
               ELSE
                  DO 40 i = 1, m
                     c( i, 1 ) = a( i, 1 ) + beta*c( i, 1 )
   40             CONTINUE
               END IF
            ELSE IF( beta.EQ.one ) THEN
               DO 50 i = 1, m
                  c( i, 1 ) = alpha*a( i, 1 ) + c( i, 1 )
   50          CONTINUE
            ELSE
               DO 60 i = 1, m
                  c( i, 1 ) = alpha*a( i, 1 ) + beta*c( i, 1 )
   60          CONTINUE
            END IF
         END IF
      ELSE
         IF( beta.EQ.zero ) THEN
            IF( alpha.EQ.zero ) THEN
               DO 80 j = 1, n
                  DO 70 i = 1, m
                     c( i, j ) = zero
   70             CONTINUE
   80          CONTINUE
            ELSE
               DO 100 j = 1, n
                  DO 90 i = 1, m
                     c( i, j ) = alpha * a( i, j )
   90             CONTINUE
  100          CONTINUE
            END IF
         ELSE
            IF( alpha.EQ.one ) THEN
               IF( beta.EQ.one ) THEN
                  DO 120 j = 1, n
                     DO 110 i = 1, m
                        c( i, j ) = a( i, j ) + c( i, j )
  110                CONTINUE
  120             CONTINUE
               ELSE
                  DO 140 j = 1, n
                     DO 130 i = 1, m
                        c( i, j ) = a( i, j ) + beta * c( i, j )
  130                CONTINUE
  140             CONTINUE
               END IF
            ELSE IF( beta.EQ.one ) THEN
               DO 160 j = 1, n
                  DO 150 i = 1, m
                     c( i, j ) = c( i, j ) + alpha * a( i, j )
  150             CONTINUE
  160          CONTINUE
            ELSE
               DO 180 j = 1, n
                  DO 170 i = 1, m
                     c( i, j ) = alpha * a( i, j ) + beta * c( i, j )
  170             CONTINUE
  180          CONTINUE
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of DMATADD
*
      END