pdtrdinfo.f

Go to the documentation of this file.

      SUBROUTINE pdtrdinfo( SUMMRY, NOUT, UPLO, NMAT, NVAL, LDNVAL, NNB,
     $                      NBVAL, LDNBVAL, NGRIDS, PVAL, LDPVAL, QVAL,
     $                      LDQVAL, THRESH, WORK, IAM, NPROCS )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IAM, LDNBVAL, LDNVAL, LDPVAL, LDQVAL,
     $                   ngrids, nmat, nnb, nprocs, nout
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      CHARACTER*( * )    SUMMRY*(*)
      INTEGER            NBVAL( LDNBVAL ), NVAL( LDNVAL ),
     $                   pval( ldpval ), qval( ldqval ), work( * )
*     ..
*
*  Purpose
*  =======
*
*  PDTRDINFO gets needed startup information for the symmetric
*  tridiagonal reduction and transmits it to all processes.
*
*  Arguments
*  =========
*
*  SUMMRY   (global output) CHARACTER*(*)
*           Name of output (summary) file (if any). Only defined for
*           process 0.
*
*  NOUT     (global output) INTEGER
*           The unit number for output file. NOUT = 6, ouput to screen,
*           NOUT = 0, output to stderr.  Only defined for process 0.
*
*  UPLO     (global output) CHARACTER
*           Specifies whether the upper or lower triangular part of the
*           symmetric matrix A is stored.
*             = 'U':  Upper triangular
*             = 'L':  Lower triangular
*
*  NMAT     (global output) INTEGER
*           The number of different values that can be used for N.
*
*  NVAL     (global output) INTEGER array, dimension (LDNVAL)
*           The values of N (number of columns in matrix) to run the
*           code with.
*
*  LDNVAL   (global input) INTEGER
*           The maximum number of different values that can be used for
*           N, LDNVAL > =  NMAT.
*
*  NNB      (global output) INTEGER
*           The number of different values that can be used for NB.
*
*  NBVAL    (global output) INTEGER array, dimension (LDNBVAL)
*           The values of NB (blocksize) to run the code with.
*
*  LDNBVAL  (global input) INTEGER
*           The maximum number of different values that can be used for
*           NB, LDNBVAL >= NNB.
*
*  NGRIDS   (global output) INTEGER
*           The number of different values that can be used for P & Q.
*
*  PVAL     (global output) INTEGER array, dimension (LDPVAL)
*           The values of P (number of process rows) to run the code
*           with.
*
*  LDPVAL   (global input) INTEGER
*           The maximum number of different values that can be used for
*           P, LDPVAL >= NGRIDS.
*
*  QVAL     (global output) INTEGER array, dimension (LDQVAL)
*           The values of Q (number of process columns) to run the code
*           with.
*
*  LDQVAL   (global input) INTEGER
*           The maximum number of different values that can be used for
*           Q, LDQVAL >= NGRIDS.
*
*  THRESH   (global output) REAL
*           Indicates what error checks shall be run and printed out:
*           = 0 : Perform no error checking
*           > 0 : report all residuals greater than THRESH.
*
*  WORK     (local workspace) INTEGER array, dimension >=
*           MAX( 5, LDNVAL+LDNBVAL+LDPVAL+LDQVAL ).  Used to pack all
*           input arrays in order to send info in one message.
*
*  IAM      (local input) INTEGER
*           My process number.
*
*  NPROCS   (global input) INTEGER
*           The total number of processes.
*
*  Note
*  ====
*
*  For packing the information we assumed that the length in bytes of an
*  integer is equal to the length in bytes of a real single precision.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      INTEGER            NIN
      PARAMETER          ( NIN = 11 )
*     ..
*     .. Local Scalars ..
      CHARACTER*79       USRINFO
      INTEGER            I, ICTXT
      DOUBLE PRECISION   EPS
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_get, blacs_gridexit,
     $                   blacs_gridinit, blacs_setup, icopy, igebr2d,
     $                   igebs2d, sgebr2d, sgebs2d
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           pdlamch, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Process 0 reads the input data, broadcasts to other processes and
*     writes needed information to NOUT
*
      IF( iam.EQ.0 ) THEN
*
*        Open file and skip data file header
*
         OPEN( nin, file='TRD.dat', status='OLD' )
         READ( nin, fmt = * ) summry
         summry = ' '
*
*        Read in user-supplied info about machine type, compiler, etc.
*
         READ( nin, fmt = 9999 ) usrinfo
*
*        Read name and unit number for summary output file
*
         READ( nin, fmt = * ) summry
         READ( nin, fmt = * ) nout
         IF( nout.NE.0 .AND. nout.NE.6 )
     $      OPEN( nout, file = summry, status = 'UNKNOWN' )
*
*        Read and check the parameter values for the tests.
*
*        Get UPLO
*
         READ( nin, fmt = * ) uplo
*
*        Get number of matrices and their dimensions
*
         READ( nin, fmt = * ) nmat
         IF( nmat.LT.1 .OR. nmat.GT.ldnval ) THEN
            WRITE( nout, fmt = 9994 ) 'N', ldnval
            GOTO 20
         END IF
         READ( nin, fmt = * ) ( nval( i ), i = 1, nmat )
*
*        Get values of NB
*
         READ( nin, fmt = * ) nnb
         IF( nnb.LT.1 .OR. nnb.GT.ldnbval ) THEN
            WRITE( nout, fmt = 9994 ) 'NB', ldnbval
            GOTO 20
         END IF
         READ( nin, fmt = * ) ( nbval( i ), i = 1, nnb )
*
*        Get number of grids
*
         READ( nin, fmt = * ) ngrids
         IF( ngrids.LT.1 .OR. ngrids.GT.ldpval ) THEN
            WRITE( nout, fmt = 9994 ) 'Grids', ldpval
            GOTO 20
         ELSE IF( ngrids.GT.ldqval ) THEN
            WRITE( nout, fmt = 9994 ) 'Grids', ldqval
            GOTO 20
         END IF
*
*        Get values of P and Q
*
         READ( nin, fmt = * ) ( pval( i ), i = 1, ngrids )
         READ( nin, fmt = * ) ( qval( i ), i = 1, ngrids )
*
*        Get level of checking
*
         READ( nin, fmt = * ) thresh
*
*        Close input file
*
         CLOSE( nin )
*
*        For pvm only: if virtual machine not set up, allocate it and
*        spawn the correct number of processes.
*
         IF( nprocs.LT.1 ) THEN
            nprocs = 0
            DO 10 i = 1, ngrids
               nprocs = max( nprocs, pval( i )*qval( i ) )
   10       CONTINUE
            CALL blacs_setup( iam, nprocs )
         END IF
*
*        Temporarily define blacs grid to include all processes so
*        information can be broadcast to all processes
*
         CALL blacs_get( -1, 0, ictxt )
         CALL blacs_gridinit( ictxt, 'Row-major', 1, nprocs )
*
*        Compute machine epsilon
*
         eps = pdlamch( ictxt, 'eps' )
*
*        Pack information arrays and broadcast
*
         CALL sgebs2d( ictxt, 'All', ' ', 1, 1, thresh, 1 )
*
         work( 1 ) = nmat
         work( 2 ) = nnb
         work( 3 ) = ngrids
         IF( lsame( uplo, 'L' ) ) THEN
            work( 4 ) = 1
         ELSE
            work( 4 ) = 2
         END IF
         CALL igebs2d( ictxt, 'All', ' ', 4, 1, work, 4 )
*
         i = 1
         CALL icopy( nmat, nval, 1, work( i ), 1 )
         i = i + nmat
         CALL icopy( nnb, nbval, 1, work( i ), 1 )
         i = i + nnb
         CALL icopy( ngrids, pval, 1, work( i ), 1 )
         i = i + ngrids
         CALL icopy( ngrids, qval, 1, work( i ), 1 )
         i = i + ngrids - 1
         CALL igebs2d( ictxt, 'All', ' ', i, 1, work, i )
*
*        regurgitate input
*
         WRITE( nout, fmt = 9999 )
     $               'ScaLAPACK Reduction Routine to symmetric '//
     $               'tridiagonal form.'
         WRITE( nout, fmt = 9999 ) usrinfo
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9999 )
     $               'Tests of the parallel '//
     $               'real double precision symmetric '//
     $               'tridiagonal'
         WRITE( nout, fmt = 9999 ) 'reduction routines.'
         WRITE( nout, fmt = 9999 )
     $               'The following scaled residual '//
     $               'checks will be computed:'
         WRITE( nout, fmt = 9999 )
     $               ' ||A - QTQ''|| / (||A|| * eps * N)'
         WRITE( nout, fmt = 9999 )
     $               'The matrix A is randomly '//
     $               'generated for each test.'
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9999 )
     $               'An explanation of the input/output '//
     $               'parameters follows:'
         WRITE( nout, fmt = 9999 )
     $               'UPLO     : Whether the ''Upper'' or ''Low'//
     $               'er'' part of A is to be referenced.'
         WRITE( nout, fmt = 9999 )
     $               'TIME     : Indicates whether WALL or '//
     $               'CPU time was used.'
         WRITE( nout, fmt = 9999 )
     $               'N        : The number of rows and columns '//
     $               'of the matrix A.'
         WRITE( nout, fmt = 9999 )
     $               'NB       : The size of the square blocks'//
     $               ' the matrix A is split into.'
         WRITE( nout, fmt = 9999 )
     $               'P        : The number of process rows.'
         WRITE( nout, fmt = 9999 )
     $               'Q        : The number of process columns.'
         WRITE( nout, fmt = 9999 )
     $               'THRESH   : If a residual value is less'//
     $               'than THRESH, CHECK is flagged as PASSED.'
         WRITE( nout, fmt = 9999 )
     $               'TRD time : Time in seconds to reduce the'//
     $               ' matrix to tridiagonal form.'
         WRITE( nout, fmt = 9999 )
     $               'MFLOPS   : Rate of execution for '//
     $               'symmetric tridiagonal reduction.'
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9999 )
     $               'The following parameter values will be used:'
         WRITE( nout, fmt = 9999 )
     $                   '  UPLO :           '//uplo
         WRITE( nout, fmt = 9996 )
     $               'N    ', ( nval( i ), i = 1, min( nmat, 10 ) )
         IF( nmat.GT.10 )
     $      WRITE( nout, fmt = 9997 ) ( nval( i ), i = 11, nmat )
         WRITE( nout, fmt = 9996 )
     $               'NB   ', ( nbval( i ), i = 1, min( nnb, 10 ) )
         IF( nnb.GT.10 )
     $      WRITE( nout, fmt = 9997 ) ( nbval( i ), i = 11, nnb )
         WRITE( nout, fmt = 9996 )
     $               'P    ', ( pval( i ), i = 1, min( ngrids, 10 ) )
         IF( ngrids.GT.10 )
     $      WRITE( nout, fmt = 9997 ) ( pval( i ), i = 11, ngrids )
         WRITE( nout, fmt = 9996 )
     $               'Q    ', ( qval( i ), i = 1, min( ngrids, 10 ) )
         IF( ngrids.GT.10 )
     $      WRITE( nout, fmt = 9997 ) ( qval( i ), i = 11, ngrids )
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9995 ) eps
         WRITE( nout, fmt = 9998 ) thresh
*
      ELSE
*
*        If in pvm, must participate setting up virtual machine
*
         IF( nprocs.LT.1 )
     $      CALL blacs_setup( iam, nprocs )
*
*        Temporarily define blacs grid to include all processes so
*        all processes have needed startup information
*
         CALL blacs_get( -1, 0, ictxt )
         CALL blacs_gridinit( ictxt, 'Row-major', 1, nprocs )
*
*        Compute machine epsilon
*
         eps = pdlamch( ictxt, 'eps' )
*
         CALL sgebr2d( ictxt, 'All', ' ', 1, 1, thresh, 1, 0, 0 )
         CALL igebr2d( ictxt, 'All', ' ', 4, 1, work, 4, 0, 0 )
         nmat   = work( 1 )
         nnb    = work( 2 )
         ngrids = work( 3 )
         IF( work( 4 ).EQ.1 ) THEN
            uplo = 'L'
         ELSE
            uplo = 'U'
         END IF
*
         i = nmat + nnb + 2*ngrids
         CALL igebr2d( ictxt, 'All', ' ', i, 1, work, i, 0, 0 )
         i = 1
         CALL icopy( nmat, work( i ), 1, nval, 1 )
         i = i + nmat
         CALL icopy( nnb, work( i ), 1, nbval, 1 )
         i = i + nnb
         CALL icopy( ngrids, work( i ), 1, pval, 1 )
         i = i + ngrids
         CALL icopy( ngrids, work( i ), 1, qval, 1 )
*
      END IF
*
      CALL blacs_gridexit( ictxt )
*
      RETURN
*
   20 WRITE( nout, fmt = 9993 )
      CLOSE( nin )
      IF( nout.NE.6 .AND. nout.NE.0 )
     $   CLOSE( nout )
      CALL blacs_abort( ictxt, 1 )
*
      stop
*
 9999 FORMAT( a )
 9998 FORMAT( 'Routines pass computational tests if scaled residual ',
     $        'is less than ', g12.5 )
 9997 FORMAT( '              ', 10i6 )
 9996 FORMAT( 2x, a5, '  :    ', 10i6 )
 9995 FORMAT( 'Relative machine precision (eps) is taken to be ',
     $        e18.6 )
 9994 FORMAT( ' Number of values of ',5a, ' is less than 1 or greater ',
     $        'than ', i2 )
 9993 FORMAT( ' Illegal input in file ',40a,'.  Aborting run.' )
*
*     End of PDTRDINFO
*
      END