pslawil.f

Go to the documentation of this file.

      SUBROUTINE pslawil( II, JJ, M, A, DESCA, H44, H33, H43H34, V )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            II, JJ, M
      REAL               H33, H43H34, H44
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               A( * ), V( * )
*     ..
*
*  Purpose
*  =======
*
*  PSLAWIL gets the transform given by H44,H33, & H43H34 into V
*     starting at row M.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  II      (global input) INTEGER
*          Row owner of H(M+2,M+2)
*
*  JJ      (global input) INTEGER
*          Column owner of H(M+2,M+2)
*
*  M       (global input) INTEGER
*          On entry, this is where the transform starts (row M.)
*          Unchanged on exit.
*
*  A       (global input) REAL array, dimension
*          (DESCA(LLD_),*)
*          On entry, the Hessenberg matrix.
*          Unchanged on exit.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*          Unchanged on exit.
*
*  H44
*  H33
*  H43H34  (global input) REAL
*          These three values are for the double shift QR iteration.
*          Unchanged on exit.
*
*  V       (global output) REAL array of size 3.
*          Contains the transform on output.
*
*  Implemented by:  G. Henry, November 17, 1996
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            CONTXT, DOWN, HBL, ICOL, IROW, JSRC, LDA, LEFT,
     $                   MODKM1, MYCOL, MYROW, NPCOL, NPROW, NUM, RIGHT,
     $                   RSRC, UP
      REAL               H11, H12, H21, H22, H33S, H44S, S, V1, V2, V3
*     ..
*     .. Local Arrays ..
      REAL               BUF( 4 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, sgerv2d, sgesd2d, infog2l
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, mod
*     ..
*     .. Executable Statements ..
*
      hbl = desca( mb_ )
      contxt = desca( ctxt_ )
      lda = desca( lld_ )
      CALL blacs_gridinfo( contxt, nprow, npcol, myrow, mycol )
      left = mod( mycol+npcol-1, npcol )
      right = mod( mycol+1, npcol )
      up = mod( myrow+nprow-1, nprow )
      down = mod( myrow+1, nprow )
      num = nprow*npcol
*
*     On node (II,JJ) collect all DIA,SUP,SUB info from M, M+1
*
      modkm1 = mod( m+1, hbl )
      IF( modkm1.EQ.0 ) THEN
         IF( ( myrow.EQ.ii ) .AND. ( right.EQ.jj ) .AND.
     $       ( npcol.GT.1 ) ) THEN
            CALL infog2l( m+2, m+1, desca, nprow, npcol, myrow, mycol,
     $                    irow, icol, rsrc, jsrc )
            buf( 1 ) = a( ( icol-1 )*lda+irow )
            CALL sgesd2d( contxt, 1, 1, buf, 1, ii, jj )
         END IF
         IF( ( down.EQ.ii ) .AND. ( right.EQ.jj ) .AND. ( num.GT.1 ) )
     $        THEN
            CALL infog2l( m, m, desca, nprow, npcol, myrow, mycol, irow,
     $                    icol, rsrc, jsrc )
            buf( 1 ) = a( ( icol-1 )*lda+irow )
            buf( 2 ) = a( ( icol-1 )*lda+irow+1 )
            buf( 3 ) = a( icol*lda+irow )
            buf( 4 ) = a( icol*lda+irow+1 )
            CALL sgesd2d( contxt, 4, 1, buf, 4, ii, jj )
         END IF
         IF( ( myrow.EQ.ii ) .AND. ( mycol.EQ.jj ) ) THEN
            CALL infog2l( m+2, m+2, desca, nprow, npcol, myrow, mycol,
     $                    irow, icol, rsrc, jsrc )
            IF( npcol.GT.1 ) THEN
               CALL sgerv2d( contxt, 1, 1, v3, 1, myrow, left )
            ELSE
               v3 = a( ( icol-2 )*lda+irow )
            END IF
            IF( num.GT.1 ) THEN
               CALL sgerv2d( contxt, 4, 1, buf, 4, up, left )
               h11 = buf( 1 )
               h21 = buf( 2 )
               h12 = buf( 3 )
               h22 = buf( 4 )
            ELSE
               h11 = a( ( icol-3 )*lda+irow-2 )
               h21 = a( ( icol-3 )*lda+irow-1 )
               h12 = a( ( icol-2 )*lda+irow-2 )
               h22 = a( ( icol-2 )*lda+irow-1 )
            END IF
         END IF
      END IF
      IF( modkm1.EQ.1 ) THEN
         IF( ( down.EQ.ii ) .AND. ( right.EQ.jj ) .AND. ( num.GT.1 ) )
     $        THEN
            CALL infog2l( m, m, desca, nprow, npcol, myrow, mycol, irow,
     $                    icol, rsrc, jsrc )
            CALL sgesd2d( contxt, 1, 1, a( ( icol-1 )*lda+irow ), 1, ii,
     $                    jj )
         END IF
         IF( ( down.EQ.ii ) .AND. ( mycol.EQ.jj ) .AND. ( nprow.GT.1 ) )
     $        THEN
            CALL infog2l( m, m+1, desca, nprow, npcol, myrow, mycol,
     $                    irow, icol, rsrc, jsrc )
            CALL sgesd2d( contxt, 1, 1, a( ( icol-1 )*lda+irow ), 1, ii,
     $                    jj )
         END IF
         IF( ( myrow.EQ.ii ) .AND. ( right.EQ.jj ) .AND.
     $       ( npcol.GT.1 ) ) THEN
            CALL infog2l( m+1, m, desca, nprow, npcol, myrow, mycol,
     $                    irow, icol, rsrc, jsrc )
            CALL sgesd2d( contxt, 1, 1, a( ( icol-1 )*lda+irow ), 1, ii,
     $                    jj )
         END IF
         IF( ( myrow.EQ.ii ) .AND. ( mycol.EQ.jj ) ) THEN
            CALL infog2l( m+2, m+2, desca, nprow, npcol, myrow, mycol,
     $                    irow, icol, rsrc, jsrc )
            IF( num.GT.1 ) THEN
               CALL sgerv2d( contxt, 1, 1, h11, 1, up, left )
            ELSE
               h11 = a( ( icol-3 )*lda+irow-2 )
            END IF
            IF( nprow.GT.1 ) THEN
               CALL sgerv2d( contxt, 1, 1, h12, 1, up, mycol )
            ELSE
               h12 = a( ( icol-2 )*lda+irow-2 )
            END IF
            IF( npcol.GT.1 ) THEN
               CALL sgerv2d( contxt, 1, 1, h21, 1, myrow, left )
            ELSE
               h21 = a( ( icol-3 )*lda+irow-1 )
            END IF
            h22 = a( ( icol-2 )*lda+irow-1 )
            v3 = a( ( icol-2 )*lda+irow )
         END IF
      END IF
      IF( ( myrow.NE.ii ) .OR. ( mycol.NE.jj ) )
     $   RETURN
*
      IF( modkm1.GT.1 ) THEN
         CALL infog2l( m+2, m+2, desca, nprow, npcol, myrow, mycol,
     $                 irow, icol, rsrc, jsrc )
         h11 = a( ( icol-3 )*lda+irow-2 )
         h21 = a( ( icol-3 )*lda+irow-1 )
         h12 = a( ( icol-2 )*lda+irow-2 )
         h22 = a( ( icol-2 )*lda+irow-1 )
         v3 = a( ( icol-2 )*lda+irow )
      END IF
*
      h44s = h44 - h11
      h33s = h33 - h11
      v1 = ( h33s*h44s-h43h34 ) / h21 + h12
      v2 = h22 - h11 - h33s - h44s
      s = abs( v1 ) + abs( v2 ) + abs( v3 )
      v1 = v1 / s
      v2 = v2 / s
      v3 = v3 / s
      v( 1 ) = v1
      v( 2 ) = v2
      v( 3 ) = v3
*
      RETURN
*
*     End of PSLAWIL
*
      END