immdda.f

Go to the documentation of this file.

      SUBROUTINE immdda( M, N, ALPHA, A, LDA, BETA, B, LDB )
*
*  -- PBLAS auxiliary routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, M, N
      INTEGER            ALPHA, BETA
*     ..
*     .. Array Arguments ..
      INTEGER            A( LDA, * ), B( LDB, * )
*     ..
*
*  Purpose
*  =======
*
*  IMMDDA performs the following operation:
*
*     A := alpha * A + beta * B,
*
*  where alpha, beta are scalars and A and B are m by n matrices.
*
*  Arguments
*  =========
*
*  M       (local input) INTEGER
*          On entry, M  specifies the number of rows of A and B. M  must
*          be at least zero.
*
*  N       (local input) INTEGER
*          On entry, N  specifies  the  number  of  columns  of A and B.
*          N must be at least zero.
*
*  ALPHA   (local input) INTEGER
*          On entry,  ALPHA  specifies the scalar alpha. When  ALPHA  is
*          supplied as zero then the local entries of the array  A  need
*          not be set on input.
*
*  A       (local input/local output) INTEGER array
*          On entry, A is an array of dimension ( LDA, N ). On exit, the
*          leading m by n part of B has been added to the leading m by n
*          part of A.
*
*  LDA     (local input) INTEGER
*          On entry, LDA specifies the leading dimension of the array A.
*          LDA must be at least max( 1, M ).
*
*  BETA    (local input) INTEGER
*          On entry,  BETA  specifies the scalar beta. When BETA is sup-
*          plied as zero then the local entries of the array B need  not
*          be set on input.
*
*  B       (local input) INTEGER array
*          On entry, B is an array of dimension ( LDB, N ).
*
*  LDB     (local input) INTEGER
*          On entry, LDB specifies the leading dimension of the array B.
*          LDB must be at least max( 1, M ).
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            ONE, ZERO
      parameter( one = 1, zero = 0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
*     ..
*     .. Executable Statements ..
*
      IF( beta.EQ.one ) THEN
         IF( alpha.EQ.zero ) THEN
            DO 20 j = 1, n
               DO 10 i = 1, m
                  a( i, j ) = b( i, j )
   10          CONTINUE
   20       CONTINUE
         ELSE IF( alpha.NE.one ) THEN
            DO 40 j = 1, n
               DO 30 i = 1, m
                  a( i, j ) = b( i, j ) + alpha * a( i, j )
   30          CONTINUE
   40       CONTINUE
         ELSE
            DO 60 j = 1, n
               DO 50 i = 1, m
                  a( i, j ) = b( i, j ) + a( i, j )
   50          CONTINUE
   60       CONTINUE
         END IF
      ELSE IF( beta.NE.zero ) THEN
         IF( alpha.EQ.zero ) THEN
            DO 80 j = 1, n
               DO 70 i = 1, m
                  a( i, j ) = beta * b( i, j )
   70          CONTINUE
   80       CONTINUE
         ELSE IF( alpha.NE.one ) THEN
            DO 100 j = 1, n
               DO 90 i = 1, m
                  a( i, j ) = beta * b( i, j ) + alpha * a( i, j )
   90          CONTINUE
  100       CONTINUE
         ELSE
            DO 120 j = 1, n
               DO 110 i = 1, m
                  a( i, j ) = beta * b( i, j ) + a( i, j )
  110          CONTINUE
  120       CONTINUE
         END IF
      ELSE
         IF( alpha.EQ.zero ) THEN
            DO 140 j = 1, n
               DO 130 i = 1, m
                  a( i, j ) = zero
  130          CONTINUE
  140       CONTINUE
         ELSE IF( alpha.NE.one ) THEN
            DO 160 j = 1, n
               DO 150 i = 1, m
                  a( i, j ) = alpha * a( i, j )
  150          CONTINUE
  160       CONTINUE
         END IF
      END IF
*
      RETURN
*
*     End of IMMDDA
*
      END