cdttrsv.f

Go to the documentation of this file.

      SUBROUTINE cdttrsv( UPLO, TRANS, N, NRHS, DL, D, DU,
     $                   B, LDB, INFO )
*
*  -- ScaLAPACK auxiliary routine (version 2.0) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*
*     Written by Andrew J. Cleary, University of Tennessee.
*     August, 1996.
*     Modified from CGTTRS:
*  -- LAPACK routine (preliminary version) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO, TRANS
      INTEGER            INFO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      COMPLEX            B( LDB, * ), D( * ), DL( * ), DU( * )
*     ..
*
*  Purpose
*  =======
*
*  CDTTRSV solves one of the systems of equations
*     L * X = B,  L**T * X = B,  or  L**H * X = B,
*     U * X = B,  U**T * X = B,  or  U**H * X = B,
*  with factors of the tridiagonal matrix A from the LU factorization
*  computed by CDTTRF.
*
*  Arguments
*  =========
*
*  UPLO    (input) CHARACTER*1
*          Specifies whether to solve with L or U.
*
*  TRANS   (input) CHARACTER
*          Specifies the form of the system of equations:
*          = 'N':  A * X = B     (No transpose)
*          = 'T':  A**T * X = B  (Transpose)
*          = 'C':  A**H * X = B  (Conjugate transpose)
*
*  N       (input) INTEGER
*          The order of the matrix A.  N >= 0.
*
*  NRHS    (input) INTEGER
*          The number of right hand sides, i.e., the number of columns
*          of the matrix B.  NRHS >= 0.
*
*  DL      (input) COMPLEX array, dimension (N-1)
*          The (n-1) multipliers that define the matrix L from the
*          LU factorization of A.
*
*  D       (input) COMPLEX array, dimension (N)
*          The n diagonal elements of the upper triangular matrix U from
*          the LU factorization of A.
*
*  DU      (input) COMPLEX array, dimension (N-1)
*          The (n-1) elements of the first superdiagonal of U.
*
*  B       (input/output) COMPLEX array, dimension (LDB,NRHS)
*          On entry, the right hand side matrix B.
*          On exit, B is overwritten by the solution matrix X.
*
*  LDB     (input) INTEGER
*          The leading dimension of the array B.  LDB >= max(1,N).
*
*  INFO    (output) INTEGER
*          = 0:  successful exit
*          < 0:  if INFO = -i, the i-th argument had an illegal value
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            LOWER, NOTRAN
      INTEGER            I, J
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg, max
*     ..
*     .. Executable Statements ..
*
      info = 0
      notran = lsame( trans, 'N' )
      lower = lsame( uplo, 'L' )
      IF( .NOT.lower .AND. .NOT.lsame( uplo, 'U' ) ) THEN
         info = -1
      ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
     $    lsame( trans, 'C' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( nrhs.LT.0 ) THEN
         info = -4
      ELSE IF( ldb.LT.max( n, 1 ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CDTTRSV', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
      IF( notran ) THEN
*
      IF( lower ) THEN
*        Solve L*X = B, overwriting B with X.
*
         DO 35 j = 1, nrhs
*
*           Solve L*x = b.
*
            DO 10 i = 1, n - 1
                  b( i+1, j ) = b( i+1, j ) - dl( i )*b( i, j )
   10       CONTINUE
   35    CONTINUE
*
      ELSE
*        Solve U*x = b.
*
         DO 30 j = 1, nrhs
            b( n, j ) = b( n, j ) / d( n )
            IF( n.GT.1 )
     $         b( n-1, j ) = ( b( n-1, j )-du( n-1 )*b( n, j ) ) /
     $                       d( n-1 )
            DO 20 i = n - 2, 1, -1
               b( i, j ) = ( b( i, j )-du( i )*b( i+1, j ) ) / d( i )
   20       CONTINUE
   30    CONTINUE
*
      ENDIF
*
      ELSE  IF( lsame( trans, 'T' ) ) THEN
*
         IF( .NOT. lower ) THEN
*        Solve U**T * X = B, overwriting B with X.
*
         DO 65 j = 1, nrhs
*
*           Solve U**T * x = b.
*
            b( 1, j ) = b( 1, j ) / d( 1 )
            IF( n.GT.1 )
     $         b( 2, j ) = ( b( 2, j )-du( 1 )*b( 1, j ) ) / d( 2 )
            DO 40 i = 3, n
               b( i, j ) = ( b( i, j )-du( i-1 )*b( i-1, j ) ) / d( i )
   40       CONTINUE
   65    CONTINUE
*
         ELSE
*
*        Solve L**T * X = B, overwriting B with X.
         DO 60 j = 1, nrhs
*
*           Solve L**T * x = b.
*
            DO 50 i = n - 1, 1, -1
                  b( i, j ) = b( i, j ) - dl( i )*b( i+1, j )
   50       CONTINUE
   60    CONTINUE
         ENDIF
      ELSE
*
         IF( .NOT. lower ) THEN
*        Solve U**H * X = B, overwriting B with X.
*
         DO 95 j = 1, nrhs
*
*           Solve U**H * x = b.
*
            b( 1, j ) = b( 1, j ) / conjg( d( 1 ) )
            IF( n.GT.1 )
     $         b( 2, j ) = ( b( 2, j )-conjg( du( 1 ) )*b( 1, j ) ) /
     $                     conjg( d( 2 ) )
            DO 70 i = 3, n
               b( i, j ) = ( b( i, j )
     $                     -conjg( du( i-1 ) )*b( i-1, j ) ) /
     $                     conjg( d( i ) )
   70       CONTINUE
   95    CONTINUE
*
         ELSE
*
*        Solve L**H * X = B, overwriting B with X.
         DO 90 j = 1, nrhs
*
*           Solve L**H * x = b.
*
            DO 80 i = n - 1, 1, -1
                  b( i, j ) = b( i, j ) - conjg( dl( i ) )*b( i+1, j )
   80       CONTINUE
   90    CONTINUE
         ENDIF
      END IF
*
*     End of CDTTRSV
*
      END