pcsepdriver.f

Go to the documentation of this file.

*
*
      PROGRAM pcsepdriver
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     Parallel COMPLEX Hermitian eigenproblem test driver
*
*     The user should modify TOTMEM to indicate the maximum amount of
*     memory in bytes her system has.  Remember to leave room in memory
*     to discover what the maximum value you can set MEMSIZ to may be
*     required.
*     All arrays used by factorization and solve are allocated out of
*     big array called MEM.
*
*     The full tester requires approximately (5 n + 5 n^2/p + slop)
*     COMPLEX words and 6*n integer words.
*     So, TOTMEM should be set to at least 1.1 * 8 * (5n + 5n^2/p)
*
*     WHAT WE TEST
*     ============
*
*     This routine tests PCHEEVX, the expert driver for the parallel
*     Hermitian eigenvalue problem.  We would like to cover all
*     possible combinations of:  matrix size, process configuration
*     (nprow and npcol), block size (nb), matrix type (??), range
*     of eigenvalue (all, by value, by position), sorting options,
*     and upper vs. lower storage.
*
*     We intend to provide two types of test input files, an
*     installation test and a thorough test.
*
*     We also intend that the reports be meaningful.  Our input file
*     will allow multiple requests where each request is a cross product
*     of the following sets:
*       matrix sizes:                     n
*       process configuration triples:  nprow, npcol, nb
*       matrix types:
*       eigenvalue requests:              all, by value, by position
*       storage (upper vs. lower):        uplo
*
*     TERMS:
*       Request - means a set of tests, which is the cross product of
*       a set of specifications from the input file.
*       Test - one element in the cross product, i.e. a specific input
*       size and type, process configuration, etc.
*
*     .. Parameters ..
*
      INTEGER            totmem, cplxsz, nin
      parameter( totmem = 2000000, cplxsz = 8, nin = 11 )
      INTEGER            memsiz
      parameter( memsiz = totmem / cplxsz )
*     ..
*     .. Local Scalars ..
      CHARACTER          hetero
      CHARACTER*80       summry, usrinfo
      INTEGER            context, iam, info, isieee, maxnodes, nnocheck,
     $                   nout, npassed, nprocs, nskipped, ntests
*     ..
*     .. Local Arrays ..
*
      INTEGER            iseed( 4 )
      COMPLEX            mem( memsiz )
*     ..
*     .. External Functions ..
      REAL               slamch
      EXTERNAL           slamch
*     ..
*     .. External Subroutines ..
*
      EXTERNAL           blacs_exit, blacs_get, blacs_gridexit,
     $                   blacs_gridinit, blacs_pinfo, blacs_setup,
     $                   igamn2d, pcsepreq, pslachkieee, pslasnbt
*     ..
*     .. Executable Statements ..
*
*     Get starting information
*
      CALL blacs_pinfo( iam, nprocs )
*
*
      IF( iam.EQ.0 ) THEN
*
*        Open file and skip data file header
*
         OPEN( unit = nin, file = 'SEP.dat', status = 'OLD' )
         READ( nin, fmt = * )summry
         summry = ' '
*
*        Read in user-supplied info about machine type, compiler, etc.
*
         READ( nin, fmt = 9999 )usrinfo
*
*        Read name and unit number for summary output file
*
         READ( nin, fmt = * )summry
         READ( nin, fmt = * )nout
         IF( nout.NE.0 .AND. nout.NE.6 )
     $      OPEN( nout, file = summry, status = 'UNKNOWN' )
         READ( nin, fmt = * )maxnodes
         READ( nin, fmt = * )hetero
      END IF
*
      IF( nprocs.LT.1 ) THEN
         CALL blacs_setup( iam, maxnodes )
         nprocs = maxnodes
      END IF
*
      CALL blacs_get( -1, 0, context )
      CALL blacs_gridinit( context, 'R', 1, nprocs )
*
      CALL pslasnbt( isieee )
*
      CALL igamn2d( context, 'a', ' ', 1, 1, isieee, 1, 1, 1, -1, -1,
     $              0 )
*
      IF( ( isieee.NE.0 ) ) THEN
         IF( iam.EQ.0 ) THEN
            WRITE( nout, fmt = 9998 )
            WRITE( nout, fmt = 9997 )
            WRITE( nout, fmt = 9996 )
            WRITE( nout, fmt = 9995 )
            WRITE( nout, fmt = 9994 )
            WRITE( nout, fmt = 9993 )
            WRITE( nout, fmt = 9992 )
            WRITE( nout, fmt = 9991 )
            WRITE( nout, fmt = 9990 )
         END IF
*
         CALL pslachkieee( isieee, slamch( 'O' ), slamch( 'U' ) )
*
         CALL igamn2d( context, 'a', ' ', 1, 1, isieee, 1, 1, 1, -1, -1,
     $                 0 )
*
         IF( isieee.EQ.0 ) THEN
            IF( iam.EQ.0 ) THEN
               WRITE( nout, fmt = 9989 )
               WRITE( nout, fmt = 9988 )
               WRITE( nout, fmt = 9987 )
            END IF
            GO TO 20
         END IF
*
         IF( iam.EQ.0 ) THEN
            WRITE( nout, fmt = 9986 )
         END IF
*
      END IF
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9999 )
     $      'SCALAPACK Hermitian Eigendecomposition routines.'
         WRITE( nout, fmt = 9999 )usrinfo
         WRITE( nout, fmt = 9999 )' '
         WRITE( nout, fmt = 9999 )'Running tests of the parallel ' //
     $      'Hermitian eigenvalue routine:  PCHEEVX.'
         WRITE( nout, fmt = 9999 )'The following scaled residual ' //
     $      'checks will be computed:'
         WRITE( nout, fmt = 9999 )' ||AQ - QL|| ' //
     $      '/ ((abstol + ||A|| * eps) * N)'
         WRITE( nout, fmt = 9999 )' ||Q^T*Q - I|| ' // '/ (N * eps)'
         WRITE( nout, fmt = 9999 )
         WRITE( nout, fmt = 9999 )'An explanation of the ' //
     $      'input/output parameters follows:'
         WRITE( nout, fmt = 9999 )'RESULT   : passed; or ' //
     $      'an indication of which eigen request test failed'
         WRITE( nout, fmt = 9999 )
     $      'N        : The number of rows and columns ' //
     $      'of the matrix A.'
         WRITE( nout, fmt = 9999 )
     $      'P        : The number of process rows.'
         WRITE( nout, fmt = 9999 )
     $      'Q        : The number of process columns.'
         WRITE( nout, fmt = 9999 )
     $      'NB       : The size of the square blocks' //
     $      ' the matrix A is split into.'
         WRITE( nout, fmt = 9999 )
     $      'THRESH   : If a residual value is less ' //
     $      'than THRESH, RESULT is flagged as PASSED.'
         WRITE( nout, fmt = 9999 )
     $      '         : the QTQ norm is allowed to exceed THRESH' //
     $      ' for those eigenvectors'
         WRITE( nout, fmt = 9999 )'         :  which could not be ' //
     $      'reorthogonalized for lack of workspace.'
         WRITE( nout, fmt = 9999 )
     $      'TYP      : matrix type (see pCSEPtst.f).'
         WRITE( nout, fmt = 9999 )'SUB      : Subtests ' //
     $      '(see pCSEPtst).f'
         WRITE( nout, fmt = 9999 )'CHK      : ||AQ - QL|| ' //
     $      '/ ((abstol + ||A|| * eps) * N)'
         WRITE( nout, fmt = 9999 )'QTQ      : ||Q^T*Q - I||/ (N * eps)'
         WRITE( nout, fmt = 9999 )
     $      '         : when the adjusted QTQ exceeds THRESH',
     $      ' the adjusted QTQ norm is printed'
         WRITE( nout, fmt = 9999 )
     $      '         : otherwise the true QTQ norm is printed'
         WRITE( nout, fmt = 9999 )
     $      'If NT>1, CHK and QTQ are the max over all ' //
     $      'eigen request tests'
         WRITE( nout, fmt = 9999 )' '
      END IF
*
      ntests = 0
      npassed = 0
      nskipped = 0
      nnocheck = 0
*
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9979 )
         WRITE( nout, fmt = 9978 )
      END IF
*
   10 CONTINUE
*
      iseed( 1 ) = 139
      iseed( 2 ) = 1139
      iseed( 3 ) = 2139
      iseed( 4 ) = 3139
*
      CALL pcsepreq( nin, mem, memsiz, nout, iseed, ntests, nskipped,
     $               nnocheck, npassed, info )
      IF( info.EQ.0 )
     $   GO TO 10
*
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9985 )ntests
         WRITE( nout, fmt = 9984 )npassed
         WRITE( nout, fmt = 9983 )nnocheck
         WRITE( nout, fmt = 9982 )nskipped
         WRITE( nout, fmt = 9981 )ntests - npassed - nskipped -
     $      nnocheck
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9980 )
      END IF
*
*     Uncomment this line on SUN systems to avoid the useless print out
*
*      CALL IEEE_FLAGS( 'clear', 'exception', 'underflow', '')
*
*
*
   20 CONTINUE
      IF( iam.EQ.0 ) THEN
         CLOSE ( nin )
         IF( nout.NE.6 .AND. nout.NE.0 )
     $      CLOSE ( nout )
      END IF
*
      CALL blacs_gridexit( context )
*
      CALL blacs_exit( 0 )
      stop
*
*
 9999 FORMAT( a )
 9998 FORMAT( ' I am about to check to make sure that overflow' )
 9997 FORMAT( ' is handled in the ieee default manner.  If this' )
 9996 FORMAT( ' is the last output you see, you should assume' )
 9995 FORMAT( ' that overflow caused a floating point exception.' )
 9994 FORMAT( ' In that case, we recommend that you add -DNO_IEEE' )
 9993 FORMAT( ' to the CDEFS line in SLmake.inc.' )
 9992 FORMAT( ' Alternatively, you could set CDEFS in SLmake.inc ' )
 9991 FORMAT( ' to enable the default ieee behaviour, However, this' )
 9990 FORMAT( ' may result in good or very bad performance.' )
 9989 FORMAT( ' Either signed zeroes or signed infinities ' )
 9988 FORMAT( ' work incorrectly or your system.  Change your' )
 9987 FORMAT( ' SLmake.inc as suggested above.' )
*
 9986 FORMAT( ' Your system appears to handle ieee overflow.' )
*
 9985 FORMAT( 'Finished ', i6, ' tests, with the following results:' )
 9984 FORMAT( i5, ' tests completed and passed residual checks.' )
 9983 FORMAT( i5, ' tests completed without checking.' )
 9982 FORMAT( i5, ' tests skipped for lack of memory.' )
 9981 FORMAT( i5, ' tests completed and failed.' )
 9980 FORMAT( 'END OF TESTS.' )
 9979 FORMAT( '     N  NB   P   Q TYP SUB   WALL      CPU  ',
     $      '    CHK       QTQ    CHECK' )
 9978 FORMAT( ' ----- --- --- --- --- --- -------- --------',
     $      ' --------- --------- -----' )
*
*     End of PCSEPDRIVER
*
      END