pdlasizesqp.f

Go to the documentation of this file.

      SUBROUTINE pdlasizesqp( DESCA, IPREPAD, IPOSTPAD, SIZEMQRLEFT,
     $                        SIZEMQRRIGHT, SIZEQRF, SIZETMS, SIZEQTQ,
     $                        SIZECHK, SIZESYEVX, ISIZESYEVX,
     $                        SIZESYEV, SIZESYEVD, ISIZESYEVD,
     $                        SIZESUBTST, ISIZESUBTST,
     $                        SIZETST, ISIZETST )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     February 23, 2000
*
*     .. Scalar Arguments ..
      INTEGER            IPOSTPAD, IPREPAD, ISIZESUBTST, ISIZESYEVD,
     $                   ISIZESYEVX, ISIZETST, SIZECHK, SIZEMQRLEFT, 
     $                   SIZEMQRRIGHT, SIZEQRF, SIZEQTQ, SIZESUBTST, 
     $                   SIZESYEV, SIZESYEVD, SIZESYEVX, SIZETMS, 
     $                   SIZETST
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
*     ..
*
*  Purpose
*  =======
*
*  PDLASIZESQP computes the amount of memory needed by
*  various SEP test routines, as well as PDYEVX and PDSYEV
*
*  Arguments
*  =========
*
*  DESCA        (global input) INTEGER array dimension ( DLEN_ )
*               Array descriptor as passed to PDSYEVX or PDSYEV
*
*  SIZEMQRLEFT  LWORK for the 1st PDORMQR call in PDLAGSY
*
*  SIZEMQRRIGHT LWORK for the 2nd PDORMQR call in PDLAGSY
*
*  SIZEQRF      LWORK for PDGEQRF in PDLAGSY
*
*  SIZETMS      LWORK for PDLATMS
*
*  SIZEQTQ      LWORK for PDSEPQTQ (nexer complex)
*
*  SIZECHK      LWORK for PDSEPCHK
*
*  SIZESYEVX    LWORK for PDSYEVX
*
*  ISIZESYEVX   LIWORK for PDSYEVX
*
*  SIZESYEV     LWORK for PDSYEV
*
*  SIZESYEVD    LWORK for PSSYEVD
*
*  ISIZESYEVD   LIWORK for PSSYEVD
*
*  SIZESUBTST   LWORK for PDSUBTST
*
*  ISIZESUBTST  LIWORK for PDSUBTST
*
*  SIZETST      LWORK for PDTST
*
*  ISIZETST     LIWORK for PDTST
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      PARAMETER          ( BLOCK_CYCLIC_2D = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            CONTEXTC, CSRC_A, IACOL, IAROW, ICOFFA, IROFFA,
     $                   LCM, LCMQ, LDA, LDC, MQ0, MYCOL, MYPCOLC,
     $                   MYPROWC, MYROW, N, NB, NEIG, NN, NNP, NP,
     $                   NPCOLC, NPROWC, NP0, NPCOL, NPROW, NQ, RSRC_A
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, ILCM, INDXG2P, NUMROC, SL_GRIDRESHAPE
      EXTERNAL           ICEIL, ILCM, INDXG2P, NUMROC, SL_GRIDRESHAPE
*     ..
*     .. Executable Statements ..
*
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, blacs_gridexit
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
      n = desca( m_ )
      nb = desca( mb_ )
      rsrc_a = desca( rsrc_ )
      csrc_a = desca( csrc_ )
*
      lda = desca( lld_ )
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
*
      lcm = ilcm( nprow, npcol )
      lcmq = lcm / npcol
      iroffa = 0
      icoffa = 0
      iarow = indxg2p( 1, nb, myrow, rsrc_a, nprow )
      iacol = indxg2p( 1, nb, mycol, csrc_a, npcol )
      np = numroc( n+iroffa, nb, myrow, iarow, nprow )
      nq = numroc( n+icoffa, nb, mycol, iacol, npcol )
      sizemqrleft = max( ( nb*( nb-1 ) ) / 2, ( np+nq )*nb ) + nb*nb
      sizemqrright = max( ( nb*( nb-1 ) ) / 2,
     $               ( nq+max( np+numroc( numroc( n+icoffa, nb, 0, 0,
     $               npcol ), nb, 0, 0, lcmq ), np ) )*nb ) + nb*nb
      sizeqrf = nb*np + nb*nq + nb*nb
      sizetms = ( lda+1 )*max( 1, nq ) +
     $          max( sizemqrleft, sizemqrright, sizeqrf )
*
      np0 = numroc( n, desca( mb_ ), 0, 0, nprow )
      mq0 = numroc( n, desca( nb_ ), 0, 0, npcol )
      sizeqtq = 2 + max( desca( mb_ ), 2 )*( 2*np0+mq0 )
      sizechk = numroc( n, desca( nb_ ), mycol, 0, npcol )
*
      neig = n
      nn = max( n, nb, 2 )
      np0 = numroc( nn, nb, 0, 0, nprow )
      mq0 = numroc( max( neig, nb, 2 ), nb, 0, 0, npcol )
      sizesyevx = 5*n + max( 5*nn, np0*mq0+2*nb*nb ) +
     $            iceil( neig, nprow*npcol )*nn
      nnp = max( n, nprow*npcol+1, 4 )
      isizesyevx = 6*nnp
*
*     Allow room for the new context created in PDSYEV
*
      contextc = sl_gridreshape( desca( ctxt_ ), 0, 1, 1,
     $                           nprow*npcol, 1 )
      CALL blacs_gridinfo( contextc, nprowc, npcolc, myprowc,
     $                     mypcolc )
      ldc = max( 1, numroc( n, nb, myprowc, 0, nprow*npcol ) )
      sizesyev = 5*n  + max( 2*np0 + mq0 + nb*nn , 2*nn-2 ) + n*ldc
      CALL blacs_gridexit( contextc )
*
      np = numroc( n, nb, myrow, iarow, nprow )
      nq = numroc( n, nb, mycol, iacol, npcol )
      nn = max( n, nb, 2 )
      nnp = 3*n + max( nb*( np+1 ), 3*nb ) 
      sizesyevd = max( nnp, 1+6*n+2*np*nq ) + 2*n
      isizesyevd = 2+7*n+8*npcol
*     
      sizesubtst = max( sizetms, sizeqtq, sizechk, sizesyevx,
     $                  sizemqrleft, sizemqrright, sizesyev ) +
     $                  iprepad + ipostpad
      isizesubtst = isizesyevx + iprepad + ipostpad
*
*
*     Allow room for A, COPYA and Z and DIAG, WIN, WNEW, GAP, WORK
*
      sizetst = 3*( lda*np+iprepad+ipostpad ) +
     $          4*( n+iprepad+ipostpad ) + sizesubtst
*
*     Allow room for IFAIL, ICLUSTR, and IWORK (all in PDSYEVX)
*
      isizetst = n + 2*nprow*npcol + 2*( iprepad+ipostpad ) +
     $           isizesubtst
*
      RETURN
      END