pzlasizeheevr.f

Go to the documentation of this file.

      SUBROUTINE pzlasizeheevr( WKNOWN, RANGE, N, DESCA, VL, VU, IL, IU,
     $                          ISEED, WIN, MAXSIZE, VECSIZE, VALSIZE )
*
*  -- ScaLAPACK routine (@(MODE)version *TBA*) --
*     University of California, Berkeley and
*     University of Tennessee, Knoxville. 
*     October 21, 2006
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      LOGICAL            WKNOWN
      CHARACTER          RANGE
      INTEGER            IL, IU, MAXSIZE, N, VALSIZE, VECSIZE
      DOUBLE PRECISION   VL, VU
 
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), ISEED( 4 )
      DOUBLE PRECISION   WIN( * )
*     ..
*
*  Purpose
*  =======
*
*  PZLASIZEHEEVR computes the amount of memory needed by PZHEEVR
*  to ensure:
*    1)  Orthogonal Eigenvectors
*    2)  Eigenpairs with small residual norms
*
*  Arguments
*  =========
*
*  WKNOWN  (global input) INTEGER
*          .FALSE.:  WIN does not contain the eigenvalues
*          .TRUE.:   WIN does contain the eigenvalues
*
*  RANGE   (global input) CHARACTER*1
*          = 'A': all eigenvalues will be found.
*          = 'V': all eigenvalues in the interval [VL,VU]
*                 will be found.
*          = 'I': the IL-th through IU-th eigenvalues will be found.
*
*  N       (global input) INTEGER
*          Size of the matrix to be tested.  (global size)
*
*  DESCA   (global input) INTEGER array dimension ( DLEN_ )
*
*  VL      (global input/output ) DOUBLE PRECISION
*          If RANGE='V', the lower bound of the interval to be searched
*          for eigenvalues.  Not referenced if RANGE = 'A' or 'I'.
*          If VL > VU, RANGE='V' and WKNOWN = .TRUE., VL is set
*          to a random value near an entry in WIN
*
*  VU      (global input/output ) DOUBLE PRECISION
*          If RANGE='V', the upper bound of the interval to be searched
*          for eigenvalues.  Not referenced if RANGE = 'A' or 'I'.
*          If VL > VU, RANGE='V' and WKNOWN = .TRUE., VU is set
*          to a random value near an entry in WIN
*
*  IL      (global input/output ) INTEGER
*          If RANGE='I', the index (from smallest to largest) of the
*          smallest eigenvalue to be returned.  IL >= 1.
*          Not referenced if RANGE = 'A' or 'V'.
*          If IL < 0, RANGE='I' and WKNOWN = .TRUE., IL is set
*          to a random value from 1 to N
*
*  IU      (global input/output ) INTEGER
*          If RANGE='I', the index (from smallest to largest) of the
*          largest eigenvalue to be returned.  min(IL,N) <= IU <= N.
*          Not referenced if RANGE = 'A' or 'V'.
*          If IU < 0, RANGE='I' and WKNOWN = .TRUE., IU is set
*          to a random value from IL to N
*
*  ISEED   (global input/output) INTEGER array, dimension (4)
*          On entry, the seed of the random number generator; the array
*          elements must be between 0 and 4095, and ISEED(4) must be
*          odd.
*          On exit, the seed is updated.
*          ISEED is not touched unless IL, IU, VL or VU are modified.
*
*  WIN     (global input) DOUBLE PRECISION array, dimension (N)
*          If WKNOWN=1, WIN contains the eigenvalues of the matrix.
*
*  MAXSIZE (global output) INTEGER
*          Workspace required to guarantee that PZHEEVR will return
*          orthogonal eigenvectors.  IF WKNOWN=0, MAXSIZE is set to a
*          a value which guarantees orthogonality no matter what the
*          spectrum is.  If WKNOWN=1, MAXSIZE is set to a value which
*          guarantees orthogonality on a matrix with eigenvalues given
*          by WIN.
*
*  VECSIZE (global output) INTEGER
*          Workspace required to guarantee that PZHEEVR
*          will compute eigenvectors.
*
*  VALSIZE (global output) INTEGER
*          Workspace required to guarantee that PZHEEVR
*          will compute eigenvalues.
*
*
*     .. Parameters ..
      INTEGER            CTXT_, MB_
      parameter( ctxt_ = 2, mb_ = 5 )
      DOUBLE PRECISION   TWENTY
      parameter( twenty = 20.0d0 )
*     ..
*     .. Local Scalars ..
*
      INTEGER            ILMIN, IUMAX, 
     $                   mq0, mycol, myil, myiu, myrow, nb, neig, nn,
     $                   np0, npcol, nprow
      DOUBLE PRECISION   ANORM, EPS, SAFMIN
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, NUMROC
      DOUBLE PRECISION   DLARAN, PDLAMCH
      EXTERNAL           lsame, iceil, numroc, dlaran, pdlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, int, max
 
*     ..
*     .. Executable Statements ..
*
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
      eps = pdlamch( desca( ctxt_ ), 'Precision' )
      safmin = pdlamch( desca( ctxt_ ), 'Safe Minimum' )
      nb = desca( mb_ )
      nn = max( n, nb, 2 )
      np0 = numroc( nn, nb, 0, 0, nprow )
 
      valsize = 3 + 5*n + max( 12*nn, nb*( np0+1 ) )
 
      IF( wknown ) THEN
         anorm = safmin / eps
         IF( n.GE.1 )
     $      anorm = max( abs( win( 1 ) ), abs( win( n ) ), anorm )
         IF( lsame( range, 'I' ) ) THEN
            IF( il.LT.0 )
     $         il = int( dlaran( iseed )*dble( n ) ) + 1
            IF( iu.LT.0 )
     $         iu = int( dlaran( iseed )*dble( n-il ) ) + il
            IF( n.EQ.0 )
     $         iu = 0
         ELSE IF( lsame( range, 'V' ) ) THEN
            IF( vl.GT.vu ) THEN
               myil = int( dlaran( iseed )*dble( n ) ) + 1
               myiu = int( dlaran( iseed )*dble( n-myil ) ) + myil
               vl = win( myil ) - twenty*eps*abs( win( myil ) )
               vu = win( myiu ) + twenty*eps*abs( win( myiu ) )
               vu = max( vu, vl+eps*twenty*abs( vl )+safmin )
            END IF
         END IF
*
      END IF
      IF( lsame( range, 'V' ) ) THEN
*        We do not know how many eigenvalues will be computed
         ilmin = 1
         iumax = n
      ELSE IF( lsame( range, 'I' ) ) THEN
         ilmin = il
         iumax = iu
      ELSE IF( lsame( range, 'A' ) ) THEN
         ilmin = 1
         iumax = n
      END IF
*
      neig = iumax - ilmin + 1
*
      mq0 = numroc( max( neig, nb, 2 ), nb, 0, 0, npcol )
*
      vecsize = 3 + 5*n + max( 18*nn, np0*mq0+2*nb*nb ) + 
     $          (2 + iceil( neig, nprow*npcol ))*nn
 
      valsize = max(3, valsize)
      vecsize = max(3, vecsize)
      maxsize = vecsize
*
      RETURN
*
*     End of PZLASIZEHEEVR
*
      END