ScaLAPACK 2.1  2.1
ScaLAPACK: Scalable Linear Algebra PACKage
pzunmrz.f
Go to the documentation of this file.
1  SUBROUTINE pzunmrz( SIDE, TRANS, M, N, K, L, A, IA, JA, DESCA,
2  $ TAU, C, IC, JC, DESCC, WORK, LWORK, INFO )
3 *
4 * -- ScaLAPACK routine (version 1.7) --
5 * University of Tennessee, Knoxville, Oak Ridge National Laboratory,
6 * and University of California, Berkeley.
7 * May 25, 2001
8 *
9 * .. Scalar Arguments ..
10  CHARACTER SIDE, TRANS
11  INTEGER IA, IC, INFO, JA, JC, K, L, LWORK, M, N
12 * ..
13 * .. Array Arguments ..
14  INTEGER DESCA( * ), DESCC( * )
15  COMPLEX*16 A( * ), C( * ), TAU( * ), WORK( * )
16 * ..
17 *
18 * Purpose
19 * =======
20 *
21 * PZUNMRZ overwrites the general complex M-by-N distributed matrix
22 * sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
23 *
24 * SIDE = 'L' SIDE = 'R'
25 * TRANS = 'N': Q * sub( C ) sub( C ) * Q
26 * TRANS = 'C': Q**H * sub( C ) sub( C ) * Q**H
27 *
28 * where Q is a complex unitary distributed matrix defined as the
29 * product of K elementary reflectors
30 *
31 * Q = H(1)' H(2)' . . . H(k)'
32 *
33 * as returned by PZTZRZF. Q is of order M if SIDE = 'L' and of order N
34 * if SIDE = 'R'.
35 *
36 * Notes
37 * =====
38 *
39 * Each global data object is described by an associated description
40 * vector. This vector stores the information required to establish
41 * the mapping between an object element and its corresponding process
42 * and memory location.
43 *
44 * Let A be a generic term for any 2D block cyclicly distributed array.
45 * Such a global array has an associated description vector DESCA.
46 * In the following comments, the character _ should be read as
47 * "of the global array".
48 *
49 * NOTATION STORED IN EXPLANATION
50 * --------------- -------------- --------------------------------------
51 * DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
52 * DTYPE_A = 1.
53 * CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
54 * the BLACS process grid A is distribu-
55 * ted over. The context itself is glo-
56 * bal, but the handle (the integer
57 * value) may vary.
58 * M_A (global) DESCA( M_ ) The number of rows in the global
59 * array A.
60 * N_A (global) DESCA( N_ ) The number of columns in the global
61 * array A.
62 * MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
63 * the rows of the array.
64 * NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
65 * the columns of the array.
66 * RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
67 * row of the array A is distributed.
68 * CSRC_A (global) DESCA( CSRC_ ) The process column over which the
69 * first column of the array A is
70 * distributed.
71 * LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
72 * array. LLD_A >= MAX(1,LOCr(M_A)).
73 *
74 * Let K be the number of rows or columns of a distributed matrix,
75 * and assume that its process grid has dimension p x q.
76 * LOCr( K ) denotes the number of elements of K that a process
77 * would receive if K were distributed over the p processes of its
78 * process column.
79 * Similarly, LOCc( K ) denotes the number of elements of K that a
80 * process would receive if K were distributed over the q processes of
81 * its process row.
82 * The values of LOCr() and LOCc() may be determined via a call to the
83 * ScaLAPACK tool function, NUMROC:
84 * LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
85 * LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
86 * An upper bound for these quantities may be computed by:
87 * LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
88 * LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
89 *
90 * Arguments
91 * =========
92 *
93 * SIDE (global input) CHARACTER
94 * = 'L': apply Q or Q**H from the Left;
95 * = 'R': apply Q or Q**H from the Right.
96 *
97 * TRANS (global input) CHARACTER
98 * = 'N': No transpose, apply Q;
99 * = 'C': Conjugate transpose, apply Q**H.
100 *
101 * M (global input) INTEGER
102 * The number of rows to be operated on i.e the number of rows
103 * of the distributed submatrix sub( C ). M >= 0.
104 *
105 * N (global input) INTEGER
106 * The number of columns to be operated on i.e the number of
107 * columns of the distributed submatrix sub( C ). N >= 0.
108 *
109 * K (global input) INTEGER
110 * The number of elementary reflectors whose product defines the
111 * matrix Q. If SIDE = 'L', M >= K >= 0, if SIDE = 'R',
112 * N >= K >= 0.
113 *
114 * L (global input) INTEGER
115 * The columns of the distributed submatrix sub( A ) containing
116 * the meaningful part of the Householder reflectors.
117 * If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
118 *
119 * A (local input) COMPLEX*16 pointer into the local memory
120 * to an array of dimension (LLD_A,LOCc(JA+M-1)) if SIDE='L',
121 * and (LLD_A,LOCc(JA+N-1)) if SIDE='R', where
122 * LLD_A >= MAX(1,LOCr(IA+K-1)); On entry, the i-th row must
123 * contain the vector which defines the elementary reflector
124 * H(i), IA <= i <= IA+K-1, as returned by PZTZRZF in the
125 * K rows of its distributed matrix argument A(IA:IA+K-1,JA:*).
126 * A(IA:IA+K-1,JA:*) is modified by the routine but restored on
127 * exit.
128 *
129 * IA (global input) INTEGER
130 * The row index in the global array A indicating the first
131 * row of sub( A ).
132 *
133 * JA (global input) INTEGER
134 * The column index in the global array A indicating the
135 * first column of sub( A ).
136 *
137 * DESCA (global and local input) INTEGER array of dimension DLEN_.
138 * The array descriptor for the distributed matrix A.
139 *
140 * TAU (local input) COMPLEX*16, array, dimension LOCc(IA+K-1).
141 * This array contains the scalar factors TAU(i) of the
142 * elementary reflectors H(i) as returned by PZTZRZF.
143 * TAU is tied to the distributed matrix A.
144 *
145 * C (local input/local output) COMPLEX*16 pointer into the
146 * local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
147 * On entry, the local pieces of the distributed matrix sub(C).
148 * On exit, sub( C ) is overwritten by Q*sub( C ) or Q'*sub( C )
149 * or sub( C )*Q' or sub( C )*Q.
150 *
151 * IC (global input) INTEGER
152 * The row index in the global array C indicating the first
153 * row of sub( C ).
154 *
155 * JC (global input) INTEGER
156 * The column index in the global array C indicating the
157 * first column of sub( C ).
158 *
159 * DESCC (global and local input) INTEGER array of dimension DLEN_.
160 * The array descriptor for the distributed matrix C.
161 *
162 * WORK (local workspace/local output) COMPLEX*16 array,
163 * dimension (LWORK)
164 * On exit, WORK(1) returns the minimal and optimal LWORK.
165 *
166 * LWORK (local or global input) INTEGER
167 * The dimension of the array WORK.
168 * LWORK is local input and must be at least
169 * if SIDE = 'L',
170 * LWORK >= MAX( (MB_A*(MB_A-1))/2, ( MpC0 + MAX( MqA0 +
171 * NUMROC( NUMROC( M+IROFFC, MB_A, 0, 0, NPROW ),
172 * MB_A, 0, 0, LCMP ), NqC0 ) )*MB_A ) +
173 * MB_A * MB_A
174 * else if SIDE = 'R',
175 * LWORK >= MAX( (MB_A*(MB_A-1))/2, (MpC0 + NqC0)*MB_A ) +
176 * MB_A * MB_A
177 * end if
178 *
179 * where LCMP = LCM / NPROW with LCM = ICLM( NPROW, NPCOL ),
180 *
181 * IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
182 * IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
183 * MqA0 = NUMROC( M+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
184 *
185 * IROFFC = MOD( IC-1, MB_C ), ICOFFC = MOD( JC-1, NB_C ),
186 * ICROW = INDXG2P( IC, MB_C, MYROW, RSRC_C, NPROW ),
187 * ICCOL = INDXG2P( JC, NB_C, MYCOL, CSRC_C, NPCOL ),
188 * MpC0 = NUMROC( M+IROFFC, MB_C, MYROW, ICROW, NPROW ),
189 * NqC0 = NUMROC( N+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
190 *
191 * ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
192 * MYROW, MYCOL, NPROW and NPCOL can be determined by calling
193 * the subroutine BLACS_GRIDINFO.
194 *
195 * If LWORK = -1, then LWORK is global input and a workspace
196 * query is assumed; the routine only calculates the minimum
197 * and optimal size for all work arrays. Each of these
198 * values is returned in the first entry of the corresponding
199 * work array, and no error message is issued by PXERBLA.
200 *
201 *
202 * INFO (global output) INTEGER
203 * = 0: successful exit
204 * < 0: If the i-th argument is an array and the j-entry had
205 * an illegal value, then INFO = -(i*100+j), if the i-th
206 * argument is a scalar and had an illegal value, then
207 * INFO = -i.
208 *
209 * Alignment requirements
210 * ======================
211 *
212 * The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
213 * must verify some alignment properties, namely the following
214 * expressions should be true:
215 *
216 * If SIDE = 'L',
217 * ( NB_A.EQ.MB_C .AND. ICOFFA.EQ.IROFFC )
218 * If SIDE = 'R',
219 * ( NB_A.EQ.NB_C .AND. ICOFFA.EQ.ICOFFC .AND. IACOL.EQ.ICCOL )
220 *
221 * =====================================================================
222 *
223 * .. Parameters ..
224  INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
225  $ lld_, mb_, m_, nb_, n_, rsrc_
226  parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
227  $ ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
228  $ rsrc_ = 7, csrc_ = 8, lld_ = 9 )
229 * ..
230 * .. Local Scalars ..
231  LOGICAL LEFT, LQUERY, NOTRAN
232  CHARACTER COLBTOP, ROWBTOP, TRANST
233  INTEGER I, I1, I2, I3, IACOL, IB, ICC, ICCOL, ICOFFA,
234  $ icoffc, icrow, ictxt, iinfo, ipw, iroffc, jaa,
235  $ jcc, lcm, lcmp, lwmin, mi, mpc0, mqa0, mycol,
236  $ myrow, ni, npcol, nprow, nq, nqc0
237 * ..
238 * .. Local Arrays ..
239  INTEGER IDUM1( 5 ), IDUM2( 5 )
240 * ..
241 * .. External Subroutines ..
242  EXTERNAL blacs_gridinfo, chk1mat, pchk2mat, pb_topget,
243  $ pb_topset, pxerbla, pzlarzb, pzlarzt,
244  $ pzunmr3
245 * ..
246 * .. External Functions ..
247  LOGICAL LSAME
248  INTEGER ICEIL, ILCM, INDXG2P, NUMROC
249  EXTERNAL iceil, ilcm, indxg2p, lsame, numroc
250 * ..
251 * .. Intrinsic Functions ..
252  INTRINSIC dble, dcmplx, ichar, max, min, mod
253 * ..
254 * .. Executable Statements ..
255 *
256 * Get grid parameters
257 *
258  ictxt = desca( ctxt_ )
259  CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
260 *
261 * Test the input parameters
262 *
263  info = 0
264  IF( nprow.EQ.-1 ) THEN
265  info = -(900+ctxt_)
266  ELSE
267  left = lsame( side, 'L' )
268  notran = lsame( trans, 'N' )
269 *
270 * NQ is the order of Q
271 *
272  IF( left ) THEN
273  nq = m
274  CALL chk1mat( k, 5, m, 3, ia, ja, desca, 10, info )
275  ELSE
276  nq = n
277  CALL chk1mat( k, 5, n, 4, ia, ja, desca, 10, info )
278  END IF
279  CALL chk1mat( m, 3, n, 4, ic, jc, descc, 15, info )
280  IF( info.EQ.0 ) THEN
281  icoffa = mod( ja-1, desca( nb_ ) )
282  iroffc = mod( ic-1, descc( mb_ ) )
283  icoffc = mod( jc-1, descc( nb_ ) )
284  iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
285  $ npcol )
286  icrow = indxg2p( ic, descc( mb_ ), myrow, descc( rsrc_ ),
287  $ nprow )
288  iccol = indxg2p( jc, descc( nb_ ), mycol, descc( csrc_ ),
289  $ npcol )
290  mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow, nprow )
291  nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol, npcol )
292 *
293  IF( left ) THEN
294  mqa0 = numroc( m+icoffa, desca( nb_ ), mycol, iacol,
295  $ npcol )
296  lcm = ilcm( nprow, npcol )
297  lcmp = lcm / nprow
298  lwmin = max( ( desca( mb_ ) * ( desca( mb_ ) - 1 ) )
299  $ / 2, ( mpc0 + max( mqa0 + numroc( numroc(
300  $ m+iroffc, desca( mb_ ), 0, 0, nprow ),
301  $ desca( mb_ ), 0, 0, lcmp ), nqc0 ) ) *
302  $ desca( mb_ ) ) + desca( mb_ ) * desca( mb_ )
303  ELSE
304  lwmin = max( ( desca( mb_ ) * ( desca( mb_ ) - 1 ) ) / 2,
305  $ ( mpc0 + nqc0 ) * desca( mb_ ) ) +
306  $ desca( mb_ ) * desca( mb_ )
307  END IF
308 *
309  work( 1 ) = dcmplx( dble( lwmin ) )
310  lquery = ( lwork.EQ.-1 )
311  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
312  info = -1
313  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
314  info = -2
315  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
316  info = -5
317  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
318  info = -6
319  ELSE IF( left .AND. desca( nb_ ).NE.descc( mb_ ) ) THEN
320  info = -(1000+nb_)
321  ELSE IF( left .AND. icoffa.NE.iroffc ) THEN
322  info = -13
323  ELSE IF( .NOT.left .AND. icoffa.NE.icoffc ) THEN
324  info = -14
325  ELSE IF( .NOT.left .AND. iacol.NE.iccol ) THEN
326  info = -14
327  ELSE IF( .NOT.left .AND. desca( nb_ ).NE.descc( nb_ ) ) THEN
328  info = -(1500+nb_)
329  ELSE IF( ictxt.NE.descc( ctxt_ ) ) THEN
330  info = -(1500+ctxt_)
331  ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
332  info = -17
333  END IF
334  END IF
335  IF( left ) THEN
336  idum1( 1 ) = ichar( 'L' )
337  ELSE
338  idum1( 1 ) = ichar( 'R' )
339  END IF
340  idum2( 1 ) = 1
341  IF( notran ) THEN
342  idum1( 2 ) = ichar( 'N' )
343  ELSE
344  idum1( 2 ) = ichar( 'C' )
345  END IF
346  idum2( 2 ) = 2
347  idum1( 3 ) = k
348  idum2( 3 ) = 5
349  idum1( 4 ) = l
350  idum2( 4 ) = 6
351  IF( lwork.EQ.-1 ) THEN
352  idum1( 5 ) = -1
353  ELSE
354  idum1( 5 ) = 1
355  END IF
356  idum2( 5 ) = 17
357  IF( left ) THEN
358  CALL pchk2mat( k, 5, m, 3, ia, ja, desca, 10, m, 3, n, 4,
359  $ ic, jc, descc, 15, 5, idum1, idum2, info )
360  ELSE
361  CALL pchk2mat( k, 5, n, 4, ia, ja, desca, 10, m, 3, n, 4,
362  $ ic, jc, descc, 15, 5, idum1, idum2, info )
363  END IF
364  END IF
365 *
366  IF( info.NE.0 ) THEN
367  CALL pxerbla( ictxt, 'PZUNMRZ', -info )
368  RETURN
369  ELSE IF( lquery ) THEN
370  RETURN
371  END IF
372 *
373 * Quick return if possible
374 *
375  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
376  $ RETURN
377 *
378  CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
379  CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
380 *
381  IF( ( left .AND. .NOT.notran ) .OR.
382  $ ( .NOT.left .AND. notran ) ) THEN
383  i1 = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+k-1 )
384  $ + 1
385  i2 = ia + k - 1
386  i3 = desca( mb_ )
387  ELSE
388  i1 = max( ( (ia+k-2) / desca( mb_ ) ) * desca( mb_ ) + 1, ia )
389  i2 = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+k-1 )
390  $ + 1
391  i3 = -desca( mb_ )
392  END IF
393 *
394  IF( left ) THEN
395  ni = n
396  jcc = jc
397  jaa = ja + m - l
398  ELSE
399  mi = m
400  icc = ic
401  jaa = ja + n - l
402  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
403  IF( notran ) THEN
404  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'I-ring' )
405  ELSE
406  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'D-ring' )
407  END IF
408  END IF
409 *
410  IF( notran ) THEN
411  transt = 'C'
412  ELSE
413  transt = 'N'
414  END IF
415 *
416  IF( ( left .AND. .NOT.notran ) .OR.
417  $ ( .NOT.left .AND. notran ) ) THEN
418  ib = i1 - ia
419  IF( left ) THEN
420  mi = m
421  ELSE
422  ni = n
423  END IF
424  CALL pzunmr3( side, trans, mi, ni, ib, l, a, ia, ja, desca,
425  $ tau, c, ic, jc, descc, work, lwork, iinfo )
426  END IF
427 *
428  ipw = desca( mb_ )*desca( mb_ ) + 1
429  DO 10 i = i1, i2, i3
430  ib = min( desca( mb_ ), k-i+ia )
431 *
432 * Form the triangular factor of the block reflector
433 * H = H(i+ib-1) . . . H(i+1) H(i)
434 *
435  CALL pzlarzt( 'Backward', 'Rowwise', l, ib, a, i, jaa, desca,
436  $ tau, work, work( ipw ) )
437  IF( left ) THEN
438 *
439 * H or H' is applied to C(ic+i-ia:ic+m-1,jc:jc+n-1)
440 *
441  mi = m - i + ia
442  icc = ic + i - ia
443  ELSE
444 *
445 * H or H' is applied to C(ic:ic+m-1,jc+i-ia:jc+n-1)
446 *
447  ni = n - i + ia
448  jcc = jc + i - ia
449  END IF
450 *
451 * Apply H or H'
452 *
453  CALL pzlarzb( side, transt, 'Backward', 'Rowwise', mi, ni, ib,
454  $ l, a, i, jaa, desca, work, c, icc, jcc, descc,
455  $ work( ipw ) )
456  10 CONTINUE
457 *
458  IF( ( left .AND. .NOT.notran ) .OR.
459  $ ( .NOT.left .AND. notran ) ) THEN
460  ib = i2 - ia
461  IF( left ) THEN
462  mi = m
463  ELSE
464  ni = n
465  END IF
466  CALL pzunmr3( side, trans, mi, ni, ib, l, a, ia, ja, desca,
467  $ tau, c, ic, jc, descc, work, lwork, iinfo )
468  END IF
469 *
470  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
471  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
472 *
473  work( 1 ) = dcmplx( dble( lwmin ) )
474 *
475  RETURN
476 *
477 * End of PZUNMRZ
478 *
479  END
max
#define max(A, B)
Definition: pcgemr.c:180
pzlarzb
subroutine pzlarzb(SIDE, TRANS, DIRECT, STOREV, M, N, K, L, V, IV, JV, DESCV, T, C, IC, JC, DESCC, WORK)
Definition: pzlarzb.f:3
pzunmr3
subroutine pzunmr3(SIDE, TRANS, M, N, K, L, A, IA, JA, DESCA, TAU, C, IC, JC, DESCC, WORK, LWORK, INFO)
Definition: pzunmr3.f:3
pchk2mat
subroutine pchk2mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, MB, MBPOS0, NB, NBPOS0, IB, JB, DESCB, DESCBPOS0, NEXTRA, EX, EXPOS, INFO)
Definition: pchkxmat.f:175
pzunmrz
subroutine pzunmrz(SIDE, TRANS, M, N, K, L, A, IA, JA, DESCA, TAU, C, IC, JC, DESCC, WORK, LWORK, INFO)
Definition: pzunmrz.f:3
chk1mat
subroutine chk1mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, INFO)
Definition: chk1mat.f:3
pxerbla
subroutine pxerbla(ICTXT, SRNAME, INFO)
Definition: pxerbla.f:2
pzlarzt
subroutine pzlarzt(DIRECT, STOREV, N, K, V, IV, JV, DESCV, TAU, T, WORK)
Definition: pzlarzt.f:3
min
#define min(A, B)
Definition: pcgemr.c:181