pcget22.f

Go to the documentation of this file.

      SUBROUTINE pcget22( TRANSA, TRANSE, TRANSW, N, A, DESCA, E, DESCE,
     $                    W, WORK, DESCW, RWORK, RESULT )
*
*  -- ScaLAPACK testing routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     August 14, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          TRANSA, TRANSE, TRANSW
      INTEGER            N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCE( * ), DESCW( * )
      REAL               RESULT( 2 ), RWORK( * )
      COMPLEX            A( * ), E( * ), W( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCGET22 does an eigenvector check.
*
*  The basic test is:
*
*     RESULT(1) = | A E  -  E W | / ( |A| |E| ulp )
*
*  using the 1-norm.  It also tests the normalization of E:
*
*     RESULT(2) = max | m-norm(E(j)) - 1 | / ( n ulp )
*                  j
*
*  where E(j) is the j-th eigenvector, and m-norm is the max-norm of a
*  vector.  The max-norm of a complex n-vector x in this case is the
*  maximum of |re(x(i)| + |im(x(i)| over i = 1, ..., n.
*
*  Arguments
*  ==========
*
*  TRANSA  (input) CHARACTER*1
*          Specifies whether or not A is transposed.
*          = 'N':  No transpose
*          = 'T':  Transpose
*          = 'C':  Conjugate transpose
*
*  TRANSE  (input) CHARACTER*1
*          Specifies whether or not E is transposed.
*          = 'N':  No transpose, eigenvectors are in columns of E
*          = 'T':  Transpose, eigenvectors are in rows of E
*          = 'C':  Conjugate transpose, eigenvectors are in rows of E
*
*  TRANSW  (input) CHARACTER*1
*          Specifies whether or not W is transposed.
*          = 'N':  No transpose
*          = 'T':  Transpose, same as TRANSW = 'N'
*          = 'C':  Conjugate transpose, use -WI(j) instead of WI(j)
*
*  N       (input) INTEGER
*          The order of the matrix A.  N >= 0.
*
*  A       (input) COMPLEX array, dimension (*)
*          The matrix whose eigenvectors are in E.
*
*  DESCA   (input) INTEGER array, dimension(*)
*
*  E       (input) COMPLEX array, dimension (*)
*          The matrix of eigenvectors. If TRANSE = 'N', the eigenvectors
*          are stored in the columns of E, if TRANSE = 'T' or 'C', the
*          eigenvectors are stored in the rows of E.
*
*  DESCE   (input) INTEGER array, dimension(*)
*
*  W       (input) COMPLEX array, dimension (N)
*          The eigenvalues of A.
*
*  WORK    (workspace) COMPLEX array, dimension (*)
*  DESCW   (input) INTEGER array, dimension(*)
*
*  RWORK   (workspace) REAL array, dimension (N)
*
*  RESULT  (output) REAL array, dimension (2)
*          RESULT(1) = | A E  -  E W | / ( |A| |E| ulp )
*          RESULT(2) = max | m-norm(E(j)) - 1 | / ( n ulp )
*                       j
*  Further Details
*  ===============
*
*  Contributed by Mark Fahey, June, 2000
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   mb_, nb_, rsrc_, csrc_, lld_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          NORMA, NORME
      INTEGER            ICOL, II, IROW, ITRNSE, ITRNSW, J, JCOL, JJ,
     $                   jrow, jvec, lda, lde, ldw, mb, mycol, myrow,
     $                   nb, npcol, nprow, contxt, ra, ca, rsrc, csrc
      REAL               ANORM, ENORM, ENRMAX, ENRMIN, ERRNRM, TEMP1,
     $                   ulp, unfl
      COMPLEX            CDUM, WTEMP
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               PSLAMCH, PCLANGE
      EXTERNAL           lsame, pslamch, pclange
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, sgamn2d, sgamx2d, infog2l,
     $                   pcaxpy, pcgemm, pclaset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real, conjg, aimag, max, min
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( real( cdum ) ) + abs( aimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
*     Initialize RESULT (in case N=0)
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 )
     $   RETURN
*
      contxt = desca( ctxt_ )
      rsrc = desca( rsrc_ )
      csrc = desca( csrc_ )
      nb = desca( nb_ )
      mb = desca( mb_ )
      lda = desca( lld_ )
      lde = desce( lld_ )
      ldw = descw( lld_ )
      CALL blacs_gridinfo( contxt, nprow, npcol, myrow, mycol )
*
      unfl = pslamch( contxt, 'Safe minimum' )
      ulp = pslamch( contxt, 'Precision' )
*
      itrnse = 0
      itrnsw = 0
      norma = 'O'
      norme = 'O'
*
      IF( lsame( transa, 'T' ) .OR. lsame( transa, 'C' ) ) THEN
         norma = 'I'
      END IF
*
      IF( lsame( transe, 'T' ) ) THEN
         itrnse = 1
         norme = 'I'
      ELSE IF( lsame( transe, 'C' ) ) THEN
         itrnse = 2
         norme = 'I'
      END IF
*
      IF( lsame( transw, 'C' ) ) THEN
         itrnsw = 1
      END IF
*
*     Normalization of E:
*
      enrmin = one / ulp
      enrmax = zero
      IF( itrnse.EQ.0 ) THEN
         DO 20 jvec = 1, n
            temp1 = zero
            DO 10 j = 1, n
               CALL infog2l( j, jvec, desce, nprow, npcol, myrow, mycol,
     $                       irow, icol, ii, jj )
               IF( ( myrow.EQ.ii ) .AND. ( mycol.EQ.jj ) ) THEN
                  temp1 = max( temp1, cabs1( e( ( icol-1 )*lde+
     $                    irow ) ) )
               END IF
   10       CONTINUE
            IF( mycol.EQ.jj ) THEN
               CALL sgamx2d( contxt, 'Col', ' ', 1, 1, temp1, 1, ra, ca,
     $                       -1, -1, -1 )
               enrmin = min( enrmin, temp1 )
               enrmax = max( enrmax, temp1 )
            END IF
   20    CONTINUE
         CALL sgamx2d( contxt, 'Row', ' ', 1, 1, enrmax, 1, ra, ca, -1,
     $                 -1, -1 )
         CALL sgamn2d( contxt, 'Row', ' ', 1, 1, enrmin, 1, ra, ca, -1,
     $                 -1, -1 )
      ELSE
         DO 40 j = 1, n
            temp1 = zero
            DO 30 jvec = 1, n
               CALL infog2l( j, jvec, desce, nprow, npcol, myrow, mycol,
     $                       irow, icol, ii, jj )
               IF( ( myrow.EQ.ii ) .AND. ( mycol.EQ.jj ) ) THEN
                  temp1 = max( temp1, cabs1( e( ( icol-1 )*lde+
     $                    irow ) ) )
               END IF
   30       CONTINUE
            IF( myrow.EQ.ii ) THEN
               CALL sgamx2d( contxt, 'Row', ' ', 1, 1, temp1, 1, ra, ca,
     $                       -1, -1, -1 )
               enrmin = min( enrmin, temp1 )
               enrmax = max( enrmax, temp1 )
            END IF
   40    CONTINUE
         CALL sgamx2d( contxt, 'Row', ' ', 1, 1, enrmax, 1, ra, ca, -1,
     $                 -1, -1 )
         CALL sgamn2d( contxt, 'Row', ' ', 1, 1, enrmin, 1, ra, ca, -1,
     $                 -1, -1 )
      END IF
*
*     Norm of A:
*
      anorm = max( pclange( norma, n, n, a, 1, 1, desca, rwork ), unfl )
*
*     Norm of E:
*
      enorm = max( pclange( norme, n, n, e, 1, 1, desce, rwork ), ulp )
*
*     Norm of error:
*
*     Error =  AE - EW
*
      CALL pclaset( 'Full', n, n, czero, czero, work, 1, 1, descw )
*
      DO 60 jcol = 1, n
         IF( itrnsw.EQ.0 ) THEN
            wtemp = w( jcol )
         ELSE
            wtemp = conjg( w( jcol ) )
         END IF
*
         IF( itrnse.EQ.0 ) THEN
            CALL pcaxpy( n, wtemp, e, 1, jcol, desce, 1, work, 1, jcol,
     $                   descw, 1 )
         ELSE IF( itrnse.EQ.1 ) THEN
            CALL pcaxpy( n, wtemp, e, jcol, 1, desce, n, work, 1, jcol,
     $                   descw, 1 )
         ELSE
            CALL pcaxpy( n, conjg( wtemp ), e, jcol, 1, desce, n, work,
     $                   1, jcol, descw, 1 )
            DO 50 jrow = 1, n
               CALL infog2l( jrow, jcol, descw, nprow, npcol, myrow,
     $                       mycol, irow, icol, ii, jj )
               IF( ( myrow.EQ.ii ) .AND. ( mycol.EQ.jj ) ) THEN
                  work( ( jcol-1 )*ldw+jrow )
     $               = conjg( work( ( jcol-1 )*ldw+jrow ) )
               END IF
   50       CONTINUE
         END IF
   60 CONTINUE
*
      CALL pcgemm( transa, transe, n, n, n, cone, a, 1, 1, desca, e, 1,
     $             1, desce, -cone, work, 1, 1, descw )
*
      errnrm = pclange( 'One', n, n, work, 1, 1, descw, rwork ) / enorm
*
*     Compute RESULT(1) (avoiding under/overflow)
*
      IF( anorm.GT.errnrm ) THEN
         result( 1 ) = ( errnrm / anorm ) / ulp
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( errnrm, anorm ) / anorm ) / ulp
         ELSE
            result( 1 ) = min( errnrm / anorm, one ) / ulp
         END IF
      END IF
*
*     Compute RESULT(2) : the normalization error in E.
*
      result( 2 ) = max( abs( enrmax-one ), abs( enrmin-one ) ) /
     $              ( real( n )*ulp )
*
      RETURN
*
*     End of PCGET22
*
      END