ScaLAPACK 2.1  2.1
ScaLAPACK: Scalable Linear Algebra PACKage
pzgeqrf.f
Go to the documentation of this file.
1  SUBROUTINE pzgeqrf( M, N, A, IA, JA, DESCA, TAU, WORK, LWORK,
2  $ INFO )
3 *
4 * -- ScaLAPACK routine (version 1.7) --
5 * University of Tennessee, Knoxville, Oak Ridge National Laboratory,
6 * and University of California, Berkeley.
7 * May 25, 2001
8 *
9 * .. Scalar Arguments ..
10  INTEGER IA, INFO, JA, LWORK, M, N
11 * ..
12 * .. Array Arguments ..
13  INTEGER DESCA( * )
14  COMPLEX*16 A( * ), TAU( * ), WORK( * )
15 * ..
16 *
17 * Purpose
18 * =======
19 *
20 * PZGEQRF computes a QR factorization of a complex distributed M-by-N
21 * matrix sub( A ) = A(IA:IA+M-1,JA:JA+N-1) = Q * R.
22 *
23 * Notes
24 * =====
25 *
26 * Each global data object is described by an associated description
27 * vector. This vector stores the information required to establish
28 * the mapping between an object element and its corresponding process
29 * and memory location.
30 *
31 * Let A be a generic term for any 2D block cyclicly distributed array.
32 * Such a global array has an associated description vector DESCA.
33 * In the following comments, the character _ should be read as
34 * "of the global array".
35 *
36 * NOTATION STORED IN EXPLANATION
37 * --------------- -------------- --------------------------------------
38 * DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
39 * DTYPE_A = 1.
40 * CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
41 * the BLACS process grid A is distribu-
42 * ted over. The context itself is glo-
43 * bal, but the handle (the integer
44 * value) may vary.
45 * M_A (global) DESCA( M_ ) The number of rows in the global
46 * array A.
47 * N_A (global) DESCA( N_ ) The number of columns in the global
48 * array A.
49 * MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
50 * the rows of the array.
51 * NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
52 * the columns of the array.
53 * RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
54 * row of the array A is distributed.
55 * CSRC_A (global) DESCA( CSRC_ ) The process column over which the
56 * first column of the array A is
57 * distributed.
58 * LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
59 * array. LLD_A >= MAX(1,LOCr(M_A)).
60 *
61 * Let K be the number of rows or columns of a distributed matrix,
62 * and assume that its process grid has dimension p x q.
63 * LOCr( K ) denotes the number of elements of K that a process
64 * would receive if K were distributed over the p processes of its
65 * process column.
66 * Similarly, LOCc( K ) denotes the number of elements of K that a
67 * process would receive if K were distributed over the q processes of
68 * its process row.
69 * The values of LOCr() and LOCc() may be determined via a call to the
70 * ScaLAPACK tool function, NUMROC:
71 * LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
72 * LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
73 * An upper bound for these quantities may be computed by:
74 * LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
75 * LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
76 *
77 * Arguments
78 * =========
79 *
80 * M (global input) INTEGER
81 * The number of rows to be operated on, i.e. the number of rows
82 * of the distributed submatrix sub( A ). M >= 0.
83 *
84 * N (global input) INTEGER
85 * The number of columns to be operated on, i.e. the number of
86 * columns of the distributed submatrix sub( A ). N >= 0.
87 *
88 * A (local input/local output) COMPLEX*16 pointer into the
89 * local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
90 * On entry, the local pieces of the M-by-N distributed matrix
91 * sub( A ) which is to be factored. On exit, the elements on
92 * and above the diagonal of sub( A ) contain the min(M,N) by N
93 * upper trapezoidal matrix R (R is upper triangular if M >= N);
94 * the elements below the diagonal, with the array TAU,
95 * represent the unitary matrix Q as a product of elementary
96 * reflectors (see Further Details).
97 *
98 * IA (global input) INTEGER
99 * The row index in the global array A indicating the first
100 * row of sub( A ).
101 *
102 * JA (global input) INTEGER
103 * The column index in the global array A indicating the
104 * first column of sub( A ).
105 *
106 * DESCA (global and local input) INTEGER array of dimension DLEN_.
107 * The array descriptor for the distributed matrix A.
108 *
109 * TAU (local output) COMPLEX*16, array, dimension
110 * LOCc(JA+MIN(M,N)-1). This array contains the scalar factors
111 * TAU of the elementary reflectors. TAU is tied to the
112 * distributed matrix A.
113 *
114 * WORK (local workspace/local output) COMPLEX*16 array,
115 * dimension (LWORK)
116 * On exit, WORK(1) returns the minimal and optimal LWORK.
117 *
118 * LWORK (local or global input) INTEGER
119 * The dimension of the array WORK.
120 * LWORK is local input and must be at least
121 * LWORK >= NB_A * ( Mp0 + Nq0 + NB_A ), where
122 *
123 * IROFF = MOD( IA-1, MB_A ), ICOFF = MOD( JA-1, NB_A ),
124 * IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
125 * IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
126 * Mp0 = NUMROC( M+IROFF, MB_A, MYROW, IAROW, NPROW ),
127 * Nq0 = NUMROC( N+ICOFF, NB_A, MYCOL, IACOL, NPCOL ),
128 *
129 * and NUMROC, INDXG2P are ScaLAPACK tool functions;
130 * MYROW, MYCOL, NPROW and NPCOL can be determined by calling
131 * the subroutine BLACS_GRIDINFO.
132 *
133 * If LWORK = -1, then LWORK is global input and a workspace
134 * query is assumed; the routine only calculates the minimum
135 * and optimal size for all work arrays. Each of these
136 * values is returned in the first entry of the corresponding
137 * work array, and no error message is issued by PXERBLA.
138 *
139 * INFO (global output) INTEGER
140 * = 0: successful exit
141 * < 0: If the i-th argument is an array and the j-entry had
142 * an illegal value, then INFO = -(i*100+j), if the i-th
143 * argument is a scalar and had an illegal value, then
144 * INFO = -i.
145 *
146 * Further Details
147 * ===============
148 *
149 * The matrix Q is represented as a product of elementary reflectors
150 *
151 * Q = H(ja) H(ja+1) . . . H(ja+k-1), where k = min(m,n).
152 *
153 * Each H(i) has the form
154 *
155 * H(j) = I - tau * v * v'
156 *
157 * where tau is a complex scalar, and v is a complex vector with
158 * v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in
159 * A(ia+i:ia+m-1,ja+i-1), and tau in TAU(ja+i-1).
160 *
161 * =====================================================================
162 *
163 * .. Parameters ..
164  INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
165  $ lld_, mb_, m_, nb_, n_, rsrc_
166  parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
167  $ ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
168  $ rsrc_ = 7, csrc_ = 8, lld_ = 9 )
169 * ..
170 * .. Local Scalars ..
171  LOGICAL LQUERY
172  CHARACTER COLBTOP, ROWBTOP
173  INTEGER I, IACOL, IAROW, ICOFF, ICTXT, IINFO, IPW, J,
174  $ jb, jn, k, lwmin, mp0, mycol, myrow, npcol,
175  $ nprow, nq0
176 * ..
177 * .. Local Arrays ..
178  INTEGER IDUM1( 1 ), IDUM2( 1 )
179 * ..
180 * .. External Subroutines ..
181  EXTERNAL blacs_gridinfo, chk1mat, pchk1mat, pb_topget,
182  $ pb_topset, pxerbla, pzgeqr2, pzlarfb,
183  $ pzlarft
184 * ..
185 * .. External Functions ..
186  INTEGER ICEIL, INDXG2P, NUMROC
187  EXTERNAL iceil, indxg2p, numroc
188 * ..
189 * .. Intrinsic Functions ..
190  INTRINSIC dble, dcmplx, min, mod
191 * ..
192 * .. Executable Statements ..
193 *
194 * Get grid parameters
195 *
196  ictxt = desca( ctxt_ )
197  CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
198 *
199 * Test the input parameters
200 *
201  info = 0
202  IF( nprow.EQ.-1 ) THEN
203  info = -(600+ctxt_)
204  ELSE
205  CALL chk1mat( m, 1, n, 2, ia, ja, desca, 6, info )
206  IF( info.EQ.0 ) THEN
207  icoff = mod( ja-1, desca( nb_ ) )
208  iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
209  $ nprow )
210  iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
211  $ npcol )
212  mp0 = numroc( m+mod( ia-1, desca( mb_ ) ), desca( mb_ ),
213  $ myrow, iarow, nprow )
214  nq0 = numroc( n+icoff, desca( nb_ ), mycol, iacol, npcol )
215  lwmin = desca( nb_ ) * ( mp0 + nq0 + desca( nb_ ) )
216 *
217  work( 1 ) = dcmplx( dble( lwmin ) )
218  lquery = ( lwork.EQ.-1 )
219  IF( lwork.LT.lwmin .AND. .NOT.lquery )
220  $ info = -9
221  END IF
222  IF( lwork.EQ.-1 ) THEN
223  idum1( 1 ) = -1
224  ELSE
225  idum1( 1 ) = 1
226  END IF
227  idum2( 1 ) = 9
228  CALL pchk1mat( m, 1, n, 2, ia, ja, desca, 6, 1, idum1, idum2,
229  $ info )
230  END IF
231 *
232  IF( info.NE.0 ) THEN
233  CALL pxerbla( ictxt, 'PZGEQRF', -info )
234  RETURN
235  ELSE IF( lquery ) THEN
236  RETURN
237  END IF
238 *
239 * Quick return if possible
240 *
241  IF( m.EQ.0 .OR. n.EQ.0 )
242  $ RETURN
243 *
244  k = min( m, n )
245  ipw = desca( nb_ ) * desca( nb_ ) + 1
246  CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
247  CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
248  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'I-ring' )
249  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
250 *
251 * Handle the first block of columns separately
252 *
253  jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+k-1 )
254  jb = jn - ja + 1
255 *
256 * Compute the QR factorization of the first block A(ia:ia+m-1,ja:jn)
257 *
258  CALL pzgeqr2( m, jb, a, ia, ja, desca, tau, work, lwork, iinfo )
259 *
260  IF( ja+jb.LE.ja+n-1 ) THEN
261 *
262 * Form the triangular factor of the block reflector
263 * H = H(ja) H(ja+1) . . . H(jn)
264 *
265  CALL pzlarft( 'Forward', 'Columnwise', m, jb, a, ia, ja, desca,
266  $ tau, work, work( ipw ) )
267 *
268 * Apply H' to A(ia:ia+m-1,ja+jb:ja+n-1) from the left
269 *
270  CALL pzlarfb( 'Left', 'Conjugate transpose', 'Forward',
271  $ 'Columnwise', m, n-jb, jb, a, ia, ja, desca,
272  $ work, a, ia, ja+jb, desca, work( ipw ) )
273  END IF
274 *
275 * Loop over the remaining blocks of columns
276 *
277  DO 10 j = jn+1, ja+k-1, desca( nb_ )
278  jb = min( k-j+ja, desca( nb_ ) )
279  i = ia + j - ja
280 *
281 * Compute the QR factorization of the current block
282 * A(i:ia+m-1,j:j+jb-1)
283 *
284  CALL pzgeqr2( m-j+ja, jb, a, i, j, desca, tau, work, lwork,
285  $ iinfo )
286 *
287  IF( j+jb.LE.ja+n-1 ) THEN
288 *
289 * Form the triangular factor of the block reflector
290 * H = H(j) H(j+1) . . . H(j+jb-1)
291 *
292  CALL pzlarft( 'Forward', 'Columnwise', m-j+ja, jb, a, i, j,
293  $ desca, tau, work, work( ipw ) )
294 *
295 * Apply H' to A(i:ia+m-1,j+jb:ja+n-1) from the left
296 *
297  CALL pzlarfb( 'Left', 'Conjugate transpose', 'Forward',
298  $ 'Columnwise', m-j+ja, n-j-jb+ja, jb, a, i, j,
299  $ desca, work, a, i, j+jb, desca, work( ipw ) )
300  END IF
301 *
302  10 CONTINUE
303 *
304  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
305  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
306 *
307  work( 1 ) = dcmplx( dble( lwmin ) )
308 *
309  RETURN
310 *
311 * End of PZGEQRF
312 *
313  END
pzgeqrf
subroutine pzgeqrf(M, N, A, IA, JA, DESCA, TAU, WORK, LWORK, INFO)
Definition: pzgeqrf.f:3
pzlarfb
subroutine pzlarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, IV, JV, DESCV, T, C, IC, JC, DESCC, WORK)
Definition: pzlarfb.f:3
pzgeqr2
subroutine pzgeqr2(M, N, A, IA, JA, DESCA, TAU, WORK, LWORK, INFO)
Definition: pzgeqr2.f:3
pchk1mat
subroutine pchk1mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, NEXTRA, EX, EXPOS, INFO)
Definition: pchkxmat.f:3
chk1mat
subroutine chk1mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, INFO)
Definition: chk1mat.f:3
pzlarft
subroutine pzlarft(DIRECT, STOREV, N, K, V, IV, JV, DESCV, TAU, T, WORK)
Definition: pzlarft.f:3
pxerbla
subroutine pxerbla(ICTXT, SRNAME, INFO)
Definition: pxerbla.f:2
min
#define min(A, B)
Definition: pcgemr.c:181