pclasizegsep.f

Go to the documentation of this file.

      SUBROUTINE pclasizegsep( DESCA, IPREPAD, IPOSTPAD, SIZEMQRLEFT,
     $                         SIZEMQRRIGHT, SIZEQRF, SIZETMS, RSIZEQTQ,
     $                         RSIZECHK, SIZEHEEVX, RSIZEHEEVX,
     $                         ISIZEHEEVX, SIZESUBTST, RSIZESUBTST,
     $                         ISIZESUBTST, SIZETST, RSIZETST,
     $                         ISIZETST )
*
*  -- ScaLAPACK test routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     October 15, 1999
*
*     .. Scalar Arguments ..
      INTEGER            IPOSTPAD, IPREPAD, ISIZEHEEVX, ISIZESUBTST,
     $                   ISIZETST, RSIZECHK, RSIZEHEEVX, RSIZEQTQ,
     $                   RSIZESUBTST, RSIZETST, SIZEHEEVX, SIZEMQRLEFT,
     $                   SIZEMQRRIGHT, SIZEQRF, SIZESUBTST, SIZETMS,
     $                   SIZETST
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
*     ..
*
*  Purpose
*  PCLASIZEGSEP computes the amount of memory needed by
*  =======
*
*  PCLASIZEGSEP computes the amount of memory needed by
*    various GSEP test routines, as well as HEGVX itself
*
*  Arguments
*  =========
*
*  DESCA        (global input) INTEGER array dimension ( DLEN_ )
*               Array descriptor as passed to PCHEGVX
*
*  SIZEMQRLEFT  LWORK for the 1st PCUNMQR call in PCLAGHE
*
*  SIZEMQRRIGHT LWORK for the 2nd PCUNMQR call in PCLAGHE
*
*  SIZEQRF      LWORK for PCGEQRF in PCLAGHE
*
*  SIZETMS      LWORK for PCLATMS
*
*  RSIZEQTQ      LWORK for PCSEPQTQ (nexer complex)
*
*  RSIZECHK      LWORK for PCGSEPCHK
*
*  SIZEHEEVX    LWORK for PCHEGVX
*
*  RSIZEHEEVX   LRWORK for PCHEGVX
*
*  ISIZEHEEVX   LIWORK for PCHEGVX
*
*  SIZESUBTST   LWORK for PCSUBTST
*
*  RSIZESUBTST  LRWORK for PCSUBTST
*
*  ISIZESUBTST  LIWORK for PCSUBTST
*
*  SIZETST      LWORK for PCTST
*
*  RSIZETST     LRWORK for PCTST
*
*  ISIZETST     LIWORK for PCTST
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      PARAMETER          ( BLOCK_CYCLIC_2D = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            ANB, CSRC_A, IACOL, IAROW, ICOFFA, ICTXT,
     $                   IROFFA, LCM, LCMQ, LDA, MQ0, MYCOL, MYROW, N,
     $                   NB, NEIG, NHEGST_LWOPT, NHETRD_LWOPT, NN, NNP,
     $                   NP, NP0, NPCOL, NPROW, NPS, NQ, NQ0, RSRC_A,
     $                   SIZECHK, SIZEQTQ, SQNPC
*     ..
*     .. External Functions ..
*
      INTEGER            ICEIL, ILCM, INDXG2P, NUMROC, PJLAENV
      EXTERNAL           ICEIL, ILCM, INDXG2P, NUMROC, PJLAENV
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          DBLE, INT, MAX, SQRT
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek and toolpack/1 happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
      n = desca( m_ )
      nb = desca( mb_ )
      rsrc_a = desca( rsrc_ )
      csrc_a = desca( csrc_ )
*
      lda = desca( lld_ )
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
*
      lcm = ilcm( nprow, npcol )
      lcmq = lcm / npcol
      iroffa = 0
      icoffa = 0
      iarow = indxg2p( 1, nb, myrow, rsrc_a, nprow )
      iacol = indxg2p( 1, nb, mycol, csrc_a, npcol )
      np = numroc( n+iroffa, nb, myrow, iarow, nprow )
      nq = numroc( n+icoffa, nb, mycol, iacol, npcol )
      sizemqrleft = max( ( nb*( nb-1 ) ) / 2, ( np+nq )*nb ) + nb*nb
      sizemqrright = max( ( nb*( nb-1 ) ) / 2,
     $               ( nq+max( np+numroc( numroc( n+icoffa, nb, 0, 0,
     $               npcol ), nb, 0, 0, lcmq ), np ) )*nb ) + nb*nb
      sizeqrf = nb*np + nb*nq + nb*nb
      sizetms = ( lda+1 )*max( 1, nq ) +
     $          max( sizemqrleft, sizemqrright, sizeqrf )
*
      np0 = numroc( n, desca( mb_ ), 0, 0, nprow )
      mq0 = numroc( n, desca( nb_ ), 0, 0, npcol )
      sizeqtq = 0
      sizechk = 0
      rsizeqtq = 0
      rsizechk = numroc( n, desca( nb_ ), mycol, 0, npcol )
*
      neig = n
      nn = max( n, nb, 2 )
      np0 = numroc( nn, nb, 0, 0, nprow )
      mq0 = numroc( max( neig, nb, 2 ), nb, 0, 0, npcol )
      sizeheevx = n + ( np0+mq0+nb )*nb
      rsizeheevx = 4*n + max( 5*nn, np0*mq0 ) +
     $             iceil( neig, nprow*npcol )*nn
      nnp = max( n, nprow*npcol+1, 4 )
      isizeheevx = 6*nnp
*
      ictxt = desca( ctxt_ )
      anb = pjlaenv( ictxt, 3, 'PCHETTRD', 'L', 0, 0, 0, 0 )
      sqnpc = int( sqrt( dble( nprow*npcol ) ) )
      nps = max( numroc( n, 1, 0, 0, sqnpc ), 2*anb )
      nhetrd_lwopt = 2*( anb+1 )*( 4*nps+2 ) + ( nps+2 )*nps
*
      np0 = numroc( n, nb, 0, 0, nprow )
      nq0 = numroc( n, nb, 0, 0, npcol )
      nhegst_lwopt = 2*np0*nb + nq0*nb + nb*nb
      sizeheevx = max( sizeheevx, n+nhetrd_lwopt, nhegst_lwopt )
*
      sizesubtst = max( sizetms, sizeqtq, sizechk, sizeheevx ) +
     $             iprepad + ipostpad
      rsizesubtst = max( rsizeheevx, rsizeqtq, rsizechk ) + iprepad +
     $              ipostpad
      isizesubtst = isizeheevx + iprepad + ipostpad
*
*
*     Allow room for A, COPYA and Z and WORK
*
      sizetst = 3*( lda*np+iprepad+ipostpad ) + sizesubtst
*
*     Room for DIAG, WIN, WNEW, GAP and RWORK
*
      rsizetst = 4*( n+iprepad+ipostpad ) + rsizesubtst
*
*     Allow room for IFAIL, ICLUSTR, and IWORK (all in PCHEGVX)
*
      isizetst = n + 2*nprow*npcol + 2*( iprepad+ipostpad ) +
     $           isizesubtst
*
      RETURN
      END