psgehd2.f

Go to the documentation of this file.

      SUBROUTINE psgehd2( N, ILO, IHI, A, IA, JA, DESCA, TAU, WORK,
     $                    LWORK, INFO )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER             IA, IHI, ILO, INFO, JA, LWORK, N
*     ..
*     .. Array Arguments ..
      INTEGER             DESCA( * )
      REAL                A( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PSGEHD2 reduces a real general distributed matrix sub( A )
*  to upper Hessenberg form H by an orthogonal similarity transforma-
*  tion:  Q' * sub( A ) * Q = H, where
*  sub( A ) = A(IA+N-1:IA+N-1,JA+N-1:JA+N-1).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  ILO     (global input) INTEGER
*  IHI     (global input) INTEGER
*          It is assumed that sub( A ) is already upper triangular in
*          rows IA:IA+ILO-2 and IA+IHI:IA+N-1 and columns JA:JA+JLO-2
*          and JA+JHI:JA+N-1. See Further Details. If N > 0,
*          1 <= ILO <= IHI <= N; otherwise set ILO = 1, IHI = N.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the N-by-N
*          general distributed matrix sub( A ) to be reduced. On exit,
*          the upper triangle and the first subdiagonal of sub( A ) are
*          overwritten with the upper Hessenberg matrix H, and the ele-
*          ments below the first subdiagonal, with the array TAU, repre-
*          sent the orthogonal matrix Q as a product of elementary
*          reflectors. See Further Details.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local output) REAL array, dimension LOCc(JA+N-2)
*          The scalar factors of the elementary reflectors (see Further
*          Details). Elements JA:JA+ILO-2 and JA+IHI:JA+N-2 of TAU are
*          set to zero. TAU is tied to the distributed matrix A.
*
*  WORK    (local workspace/local output) REAL array,
*                                                    dimension (LWORK)
*          On exit, WORK( 1 ) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          LWORK >= NB + MAX( NpA0, NB )
*
*          where NB = MB_A = NB_A, IROFFA = MOD( IA-1, NB ),
*          IAROW = INDXG2P( IA, NB, MYROW, RSRC_A, NPROW ),
*          NpA0 = NUMROC( IHI+IROFFA, NB, MYROW, IAROW, NPROW ),
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Further Details
*  ===============
*
*  The matrix Q is represented as a product of (ihi-ilo) elementary
*  reflectors
*
*     Q = H(ilo) H(ilo+1) . . . H(ihi-1).
*
*  Each H(i) has the form
*
*     H(i) = I - tau * v * v'
*
*  where tau is a real scalar, and v is a real vector with
*  v(1:i) = 0, v(i+1) = 1 and v(ihi+1:n) = 0; v(i+2:ihi) is stored on
*  exit in A(ia+ilo+i:ia+ihi-1,ja+ilo+i-2), and tau in TAU(ja+ilo+i-2).
*
*  The contents of A(IA:IA+N-1,JA:JA+N-1) are illustrated by the follo-
*  wing example, with n = 7, ilo = 2 and ihi = 6:
*
*  on entry                         on exit
*
*  ( a   a   a   a   a   a   a )    (  a   a   h   h   h   h   a )
*  (     a   a   a   a   a   a )    (      a   h   h   h   h   a )
*  (     a   a   a   a   a   a )    (      h   h   h   h   h   h )
*  (     a   a   a   a   a   a )    (      v2  h   h   h   h   h )
*  (     a   a   a   a   a   a )    (      v2  v3  h   h   h   h )
*  (     a   a   a   a   a   a )    (      v2  v3  v4  h   h   h )
*  (                         a )    (                          a )
*
*  where a denotes an element of the original matrix sub( A ), h denotes
*  a modified element of the upper Hessenberg matrix H, and vi denotes
*  an element of the vector defining H(ja+ilo+i-2).
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrix sub( A ) must verify some alignment proper-
*  ties, namely the following expression should be true:
*  ( MB_A.EQ.NB_A .AND. IROFFA.EQ.ICOFFA )
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IAROW, ICOFFA, ICTXT, IROFFA, J, K, LWMIN,
     $                   mycol, myrow, npa0, npcol, nprow
      REAL               AII
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_gridinfo, chk1mat, pselset,
     $                   pslarf, pslarfg, pxerbla
*     ..
*     .. External Functions ..
      INTEGER            INDXG2P, NUMROC
      EXTERNAL           indxg2p, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod, real
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(700+ctxt_)
      ELSE
         CALL chk1mat( n, 1, n, 1, ia, ja, desca, 7, info )
         IF( info.EQ.0 ) THEN
            iroffa = mod( ia-1, desca( mb_ ) )
            icoffa = mod( ja-1, desca( nb_ ) )
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            npa0 = numroc( ihi+iroffa, desca( mb_ ), myrow, iarow,
     $                     nprow )
            lwmin = desca( nb_ ) + max( npa0, desca( nb_ ) )
*
            work( 1 ) = real( lwmin )
            lquery = ( lwork.EQ.-1 )
            IF( ilo.LT.1 .OR. ilo.GT.max( 1, n ) ) THEN
               info = -2
            ELSE IF( ihi.LT.min( ilo, n ) .OR. ihi.GT.n ) THEN
               info = -3
            ELSE IF( iroffa.NE.icoffa ) THEN
               info = -6
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -(700+nb_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -10
            END IF
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PSGEHD2', -info )
         CALL blacs_abort( ictxt, 1 )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
      DO 10 k = ilo, ihi-1
         i = ia + k - 1
         j = ja + k - 1
*
*        Compute elementary reflector H(j) to annihilate
*        A(i+2:ihi+ia-1,j)
*
         CALL pslarfg( ihi-k, aii, i+1, j, a, min( i+2, n+ia-1 ), j,
     $                 desca, 1, tau )
         CALL pselset( a, i+1, j, desca, one )
*
*        Apply H(k) to A(ia:ihi+ia-1,j+1:ihi+ja-1) from the right
*
         CALL pslarf( 'Right', ihi, ihi-k, a, i+1, j, desca, 1, tau, a,
     $                ia, j+1, desca, work )
*
*        Apply H(j) to A(i+1:ia+ihi-1,j+1:ja+n-1) from the left
*
         CALL pslarf( 'Left', ihi-k, n-k, a, i+1, j, desca, 1, tau, a,
     $                i+1, j+1, desca, work )
*
         CALL pselset( a, i+1, j, desca, aii )
   10 CONTINUE
*
      work( 1 ) = real( lwmin )
*
      RETURN
*
*     End of PSGEHD2
*
      END