pcseprdriver.f

Go to the documentation of this file.

      PROGRAM pcseprdriver
*
*     Parallel COMPLEX          symmetric eigenproblem test driver for PCSYEVR
*
      IMPLICIT NONE
*
*     The user should modify TOTMEM to indicate the maximum amount of
*     memory in bytes her system has.  Remember to leave room in memory
*     for operating system, the BLACS buffer, etc.  REALSZ
*     indicates the length in bytes on the given platform for a number,
*     real for SINGLE/DOUBLE PRECISION, and complex for COMPLEX/COMPLEX*16.
*     For example, on a standard system, the length of a
*     REAL is 8, and an integer takes up 4 bytes. Some playing around
*     to discover what the maximum value you can set MEMSIZ to may be
*     required.
*     All arrays used by factorization and solve are allocated out of
*     big array called MEM.
*
*     TESTS PERFORMED
*     ===============
*
*     This routine performs tests for combinations of:  matrix size, process 
*     configuration (nprow and npcol), block size (nb), 
*     matrix type, range of eigenvalue (all, by value, by index), 
*     and upper vs. lower storage.
*
*     It returns an error message when heterogeneity is detected.
*
*     The input file allows multiple requests where each one is 
*     of the following sets:
*       matrix sizes:                     n
*       process configuration triples:  nprow, npcol, nb
*       matrix types:
*       eigenvalue requests:              all, by value, by position
*       storage (upper vs. lower):        uplo
*
*     TERMS:
*       Request - means a set of tests, which is the cross product of
*       a set of specifications from the input file.
*       Test - one element in the cross product, i.e. a specific input
*       size and type, process configuration, etc.
*
*     .. Parameters ..
*
      INTEGER            totmem, realsz, nin
      parameter( totmem = 100000000, realsz = 8, nin = 11 )
      INTEGER            memsiz
      parameter( memsiz = totmem / realsz )
*     ..
*     .. Local Scalars ..
      CHARACTER          hetero
      CHARACTER*80       summry, usrinfo
      INTEGER            context, iam, info, isieee, maxnodes, nnocheck,
     $                   nout, npassed, nprocs, nskipped, ntests
*     ..
*     .. Local Arrays ..
*
      INTEGER            iseed( 4 )
      COMPLEX            mem( memsiz )
*     ..
*     .. External Functions ..
      REAL               slamch
      EXTERNAL           slamch
*     ..
*     .. External Subroutines ..
*
      EXTERNAL           blacs_exit, blacs_get, blacs_gridexit, 
     $                   blacs_gridinit, blacs_pinfo, blacs_setup, 
     $                   igamn2d, pslachkieee, pslasnbt, pcseprreq 
*     ..
*     .. Executable Statements ..
*
*     Get starting information
*
      CALL blacs_pinfo( iam, nprocs )
*
*
      IF( iam.EQ.0 ) THEN
*
*        Open file and skip data file header
*
         OPEN( unit = nin, file = 'SEPR.dat', status = 'OLD' )
         READ( nin, fmt = * )summry
         summry = ' '
*
*        Read in user-supplied info about machine type, compiler, etc.
*
         READ( nin, fmt = 9999 )usrinfo
*
*        Read name and unit number for summary output file
*
         READ( nin, fmt = * )summry
         READ( nin, fmt = * )nout
         IF( nout.NE.0 .AND. nout.NE.6 )
     $      OPEN( nout, file = summry, status = 'UNKNOWN' )
         READ( nin, fmt = * )maxnodes
         READ( nin, fmt = * )hetero
      END IF
*
      IF( nprocs.LT.1 ) THEN
         CALL blacs_setup( iam, maxnodes )
         nprocs = maxnodes
      END IF
*
      CALL blacs_get( -1, 0, context )
      CALL blacs_gridinit( context, 'R', 1, nprocs )
*
      CALL pslasnbt( isieee )
*
      CALL igamn2d( context, 'a', ' ', 1, 1, isieee, 1, 1, 1, -1, -1,
     $              0 )
*
      IF( ( isieee.NE.0 ) ) THEN
         IF( iam.EQ.0 ) THEN
            WRITE( nout, fmt = 9997 )
            WRITE( nout, fmt = 9996 )
            WRITE( nout, fmt = 9995 )
         END IF
*
         CALL pslachkieee( isieee, slamch( 'O' ), slamch( 'U' ) )
*
         CALL igamn2d( context, 'a', ' ', 1, 1, isieee, 1, 1, 1, -1, -1,
     $                 0 )
*
         IF( isieee.EQ.0 ) THEN
            GO TO 20
         END IF
*
         IF( iam.EQ.0 ) THEN
            WRITE( nout, fmt = 9986 )
         END IF
*
      END IF
*
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9999 )
     $      'Test ScaLAPACK symmetric eigendecomposition routine.'
         WRITE( nout, fmt = 9999 )usrinfo
         WRITE( nout, fmt = 9999 )' '
         WRITE( nout, fmt = 9999 )'Running tests of the parallel ' //
     $      'symmetric eigenvalue routine:  PCSYEVR.'
         WRITE( nout, fmt = 9999 )'The following scaled residual ' //
     $      'checks will be computed:'
         WRITE( nout, fmt = 9999 )' ||AQ - QL|| ' //
     $      '/ ((abstol + ||A|| * eps) * N)'
         WRITE( nout, fmt = 9999 )' ||Q^T*Q - I|| ' // '/ (N * eps)'
         WRITE( nout, fmt = 9999 )
         WRITE( nout, fmt = 9999 )'An explanation of the ' //
     $      'input/output parameters follows:'
         WRITE( nout, fmt = 9999 )'RESULT   : passed; or ' //
     $      'an indication of which eigen request test failed'
         WRITE( nout, fmt = 9999 )
     $      'N        : The number of rows and columns ' //
     $      'of the matrix A.'
         WRITE( nout, fmt = 9999 )
     $      'P        : The number of process rows.'
         WRITE( nout, fmt = 9999 )
     $      'Q        : The number of process columns.'
         WRITE( nout, fmt = 9999 )
     $      'NB       : The size of the square blocks' //
     $      ' the matrix A is split into.'
         WRITE( nout, fmt = 9999 )
     $      'THRESH   : If a residual value is less ' //
     $      'than THRESH, RESULT = PASSED.'
         WRITE( nout, fmt = 9999 )
     $      'TYP      : matrix type (see PCSEPRTST).'
         WRITE( nout, fmt = 9999 )'SUB      : Subtests (Y/N).'
         WRITE( nout, fmt = 9999 )'WALL     : Wallclock time.'
         WRITE( nout, fmt = 9999 )'CPU      : CPU time.'
         WRITE( nout, fmt = 9999 )'CHK      : ||AQ - QL|| ' //
     $      '/ ((abstol + ||A|| * eps) * N)'
         WRITE( nout, fmt = 9999 )'QTQ      : ||Q^T*Q - I||/ (N * eps)'
         WRITE( nout, fmt = 9999 )
     $      '         : when the adjusted QTQ norm exceeds THRESH',
     $      '           it is printed,'
         WRITE( nout, fmt = 9999 )
     $      '           otherwise the true QTQ norm is printed.'
         WRITE( nout, fmt = 9999 )
     $      '         : If more than one test is done, CHK and QTQ ' 
         WRITE( nout, fmt = 9999 )
     $      '           are the max over all eigentests performed.'
         WRITE( nout, fmt = 9999 )
     $      'TEST     : EVR - testing PCSYEVR'
         WRITE( nout, fmt = 9999 )' '
      END IF
*
      ntests = 0
      npassed = 0
      nskipped = 0
      nnocheck = 0
*
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9979 )
         WRITE( nout, fmt = 9978 )
      END IF
*
   10 CONTINUE
*
      iseed( 1 ) = 139
      iseed( 2 ) = 1139
      iseed( 3 ) = 2139
      iseed( 4 ) = 3139
*
      CALL pcseprreq( hetero, nin, mem, memsiz, nout, iseed, ntests,
     $               nskipped, nnocheck, npassed, info )
      IF( info.EQ.0 )
     $   GO TO 10
*
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9985 )ntests
         WRITE( nout, fmt = 9984 )npassed
         WRITE( nout, fmt = 9983 )nnocheck
         WRITE( nout, fmt = 9982 )nskipped
         WRITE( nout, fmt = 9981 )ntests - npassed - nskipped -
     $      nnocheck
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9980 )
      END IF
*
*     Uncomment this line on SUN systems to avoid the useless print out
*
c      CALL IEEE_FLAGS( 'clear', 'exception', 'underflow', ' ')
*
   20 CONTINUE
      IF( iam.EQ.0 ) THEN
         CLOSE ( nin )
         IF( nout.NE.6 .AND. nout.NE.0 )
     $      CLOSE ( nout )
      END IF
*
      CALL blacs_gridexit( context )
*
      CALL blacs_exit( 0 )
      stop
*
 9999 FORMAT( a )
 9997 FORMAT( 'Check if overflow is handled in ieee default manner.' )
 9996 FORMAT( 'If this is the last output you see, you should assume')
 9995 FORMAT( 'that overflow caused a floating point exception.' )
*
 9986 FORMAT( 'Test ok. The system appears to handle ieee overflow.' )
*
 9985 FORMAT( 'Finished ', i6, ' tests, with the following results:' )
 9984 FORMAT( i5, ' tests completed and passed residual checks.' )
 9983 FORMAT( i5, ' tests completed without checking.' )
 9982 FORMAT( i5, ' tests skipped for lack of memory.' )
 9981 FORMAT( i5, ' tests completed and failed.' )
 9980 FORMAT( 'END OF TESTS.' )
 9979 FORMAT( '     N  NB   P   Q TYP SUB   WALL      CPU  ',
     $      '    CHK       QTQ    CHECK    TEST' )
 9978 FORMAT( ' ----- --- --- --- --- --- -------- --------',
     $      ' --------- --------- -----    ----' )
*
*     End of PCSEPRDRIVER
*
      END