clagsy.f

Go to the documentation of this file.

      SUBROUTINE clagsy( N, K, D, A, LDA, ISEED, WORK, INFO )
*
*  -- LAPACK auxiliary test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, N
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      REAL               D( * )
      COMPLEX            A( LDA, * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  CLAGSY generates a complex symmetric matrix A, by pre- and post-
*  multiplying a real diagonal matrix D with a random unitary matrix:
*  A = U*D*U**T. The semi-bandwidth may then be reduced to k by
*  additional unitary transformations.
*
*  Arguments
*  =========
*
*  N       (input) INTEGER
*          The order of the matrix A.  N >= 0.
*
*  K       (input) INTEGER
*          The number of nonzero subdiagonals within the band of A.
*          0 <= K <= N-1.
*
*  D       (input) REAL array, dimension (N)
*          The diagonal elements of the diagonal matrix D.
*
*  A       (output) COMPLEX array, dimension (LDA,N)
*          The generated n by n symmetric matrix A (the full matrix is
*          stored).
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= N.
*
*  ISEED   (input/output) INTEGER array, dimension (4)
*          On entry, the seed of the random number generator; the array
*          elements must be between 0 and 4095, and ISEED(4) must be
*          odd.
*          On exit, the seed is updated.
*
*  WORK    (workspace) COMPLEX array, dimension (2*N)
*
*  INFO    (output) INTEGER
*          = 0: successful exit
*          < 0: if INFO = -i, the i-th argument had an illegal value
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ZERO, ONE, HALF
      parameter( zero = ( 0.0e+0, 0.0e+0 ),
     $                   one = ( 1.0e+0, 0.0e+0 ),
     $                   half = ( 0.5e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, II, J, JJ
      REAL               WN
      COMPLEX            ALPHA, TAU, WA, WB
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, cgemv, cgerc, clacgv, clarnv, cscal,
     $                   csymv, xerbla
*     ..
*     .. External Functions ..
      REAL               SCNRM2
      COMPLEX            CDOTC
      EXTERNAL           scnrm2, cdotc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, real
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( k.LT.0 .OR. k.GT.n-1 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      END IF
      IF( info.LT.0 ) THEN
         CALL xerbla( 'CLAGSY', -info )
         RETURN
      END IF
*
*     initialize lower triangle of A to diagonal matrix
*
      DO 20 j = 1, n
         DO 10 i = j + 1, n
            a( i, j ) = zero
   10    CONTINUE
   20 CONTINUE
      DO 30 i = 1, n
         a( i, i ) = d( i )
   30 CONTINUE
*
*     Generate lower triangle of symmetric matrix
*
      DO 60 i = n - 1, 1, -1
*
*        generate random reflection
*
         CALL clarnv( 3, iseed, n-i+1, work )
         wn = scnrm2( n-i+1, work, 1 )
         wa = ( wn / abs( work( 1 ) ) )*work( 1 )
         IF( wn.EQ.zero ) THEN
            tau = zero
         ELSE
            wb = work( 1 ) + wa
            CALL cscal( n-i, one / wb, work( 2 ), 1 )
            work( 1 ) = one
            tau = real( wb / wa )
         END IF
*
*        apply random reflection to A(i:n,i:n) from the left
*        and the right
*
*        compute  y := tau * A * conjg(u)
*
         CALL clacgv( n-i+1, work, 1 )
         CALL csymv( 'Lower', n-i+1, tau, a( i, i ), lda, work, 1, zero,
     $               work( n+1 ), 1 )
         CALL clacgv( n-i+1, work, 1 )
*
*        compute  v := y - 1/2 * tau * ( u, y ) * u
*
         alpha = -half*tau*cdotc( n-i+1, work, 1, work( n+1 ), 1 )
         CALL caxpy( n-i+1, alpha, work, 1, work( n+1 ), 1 )
*
*        apply the transformation as a rank-2 update to A(i:n,i:n)
*
*        CALL CSYR2( 'Lower', N-I+1, -ONE, WORK, 1, WORK( N+1 ), 1,
*        $               A( I, I ), LDA )
*
         DO 50 jj = i, n
            DO 40 ii = jj, n
               a( ii, jj ) = a( ii, jj ) -
     $                       work( ii-i+1 )*work( n+jj-i+1 ) -
     $                       work( n+ii-i+1 )*work( jj-i+1 )
   40       CONTINUE
   50    CONTINUE
   60 CONTINUE
*
*     Reduce number of subdiagonals to K
*
      DO 100 i = 1, n - 1 - k
*
*        generate reflection to annihilate A(k+i+1:n,i)
*
         wn = scnrm2( n-k-i+1, a( k+i, i ), 1 )
         wa = ( wn / abs( a( k+i, i ) ) )*a( k+i, i )
         IF( wn.EQ.zero ) THEN
            tau = zero
         ELSE
            wb = a( k+i, i ) + wa
            CALL cscal( n-k-i, one / wb, a( k+i+1, i ), 1 )
            a( k+i, i ) = one
            tau = real( wb / wa )
         END IF
*
*        apply reflection to A(k+i:n,i+1:k+i-1) from the left
*
         CALL cgemv( 'Conjugate transpose', n-k-i+1, k-1, one,
     $               a( k+i, i+1 ), lda, a( k+i, i ), 1, zero, work, 1 )
         CALL cgerc( n-k-i+1, k-1, -tau, a( k+i, i ), 1, work, 1,
     $               a( k+i, i+1 ), lda )
*
*        apply reflection to A(k+i:n,k+i:n) from the left and the right
*
*        compute  y := tau * A * conjg(u)
*
         CALL clacgv( n-k-i+1, a( k+i, i ), 1 )
         CALL csymv( 'Lower', n-k-i+1, tau, a( k+i, k+i ), lda,
     $               a( k+i, i ), 1, zero, work, 1 )
         CALL clacgv( n-k-i+1, a( k+i, i ), 1 )
*
*        compute  v := y - 1/2 * tau * ( u, y ) * u
*
         alpha = -half*tau*cdotc( n-k-i+1, a( k+i, i ), 1, work, 1 )
         CALL caxpy( n-k-i+1, alpha, a( k+i, i ), 1, work, 1 )
*
*        apply symmetric rank-2 update to A(k+i:n,k+i:n)
*
*        CALL CSYR2( 'Lower', N-K-I+1, -ONE, A( K+I, I ), 1, WORK, 1,
*        $               A( K+I, K+I ), LDA )
*
         DO 80 jj = k + i, n
            DO 70 ii = jj, n
               a( ii, jj ) = a( ii, jj ) - a( ii, i )*work( jj-k-i+1 ) -
     $                       work( ii-k-i+1 )*a( jj, i )
   70       CONTINUE
   80    CONTINUE
*
         a( k+i, i ) = -wa
         DO 90 j = k + i + 1, n
            a( j, i ) = zero
   90    CONTINUE
  100 CONTINUE
*
*     Store full symmetric matrix
*
      DO 120 j = 1, n
         DO 110 i = j + 1, n
            a( j, i ) = a( i, j )
  110    CONTINUE
  120 CONTINUE
      RETURN
*
*     End of CLAGSY
*
      END