pzgerqrv.f

Go to the documentation of this file.

      SUBROUTINE pzgerqrv( M, N, A, IA, JA, DESCA, TAU, WORK )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 28, 2001
*
*     .. Scalar Arguments ..
      INTEGER            IA, JA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      COMPLEX*16         A( * ),  TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PZGERQRV computes sub( A ) = A(IA:IA+M-1,JA:JA+N-1) from R, Q
*  computed by PZGERQF.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX*16 pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, sub( A ) contains the the factors R and Q computed
*          by PZGERQF. On exit, the original matrix is restored.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) COMPLEX*16, array, dimension LOCr(M_A).
*          This array contains the scalar factors TAU of the elementary
*          reflectors computed by PZGERQF. TAU is tied to the dis-
*          tributed matrix A.
*
*  WORK    (local workspace) COMPLEX*16 array, dimension (LWORK)
*          LWORK = MB_A * ( Mp0 + 2*Nq0 + MB_A ), where
*          Mp0   = NUMROC( M+IROFF, MB_A, MYROW, IAROW, NPROW ) * NB_A,
*          Nq0   = NUMROC( N+ICOFF, NB_A, MYCOL, IACOL, NPCOL ) * MB_A,
*          IROFF = MOD( IA-1, MB_A ), ICOFF = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, DESCA( MB_ ), MYROW, DESCA( RSRC_ ),
*                           NPROW ),
*          IACOL = INDXG2P( JA, DESCA( NB_ ), MYCOL, DESCA( CSRC_ ),
*                           NPCOL ),
*          and NUMROC, INDXG2P are ScaLAPACK tool functions.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX*16         ONE, ZERO
      parameter( one  = ( 1.0d+0, 0.0d+0 ),
     $                     zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            I, IACOL, IAROW, IB, ICOFF, ICTXT, IIA, IN,
     $                   IPT, IPV, IPW, JJA, JV, K, MYCOL, MYROW, NPCOL,
     $                   NPROW, NQ
*     ..
*     .. Local Arrays ..
      INTEGER            DESCV( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, pb_topget,
     $                   pb_topset, pzlacpy, pzlarfb, pzlarft,
     $                   pzlaset
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, NUMROC
      EXTERNAL           iceil, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      k = min( m, n )
      in = min( iceil( ia+m-k, desca( mb_ ) ) * desca( mb_ ), ia+m-1 )
*
      icoff = mod( ja-1, desca( nb_ ) )
      CALL infog2l( ia+m-k, ja, desca, nprow, npcol, myrow, mycol,
     $              iia, jja, iarow, iacol )
      nq = numroc( n+icoff, desca( nb_ ), mycol, iacol, npcol )
      ipv = 1
      ipt = ipv + nq * desca( mb_ )
      ipw = ipt + desca( mb_ ) * desca( mb_ )
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'I-ring' )
*
      CALL descset( descv, desca( mb_), n + icoff, desca( mb_ ),
     $              desca( nb_ ), iarow, iacol, ictxt, desca( mb_ ) )
*
*     Handle first block separately
*
      ib = in - ia - m + k + 1
      jv = 1 + n - k + icoff
*
*     Compute upper triangular matrix T
*
      CALL pzlarft( 'Backward', 'Rowwise', n-m+in-ia+1, ib, a, ia+m-k,
     $              ja, desca, tau, work( ipt ), work( ipw ) )
*
*     Copy Householder vectors into workspace
*
      CALL pzlacpy( 'All', ib, n-m+in-ia+1, a, ia+m-k, ja, desca,
     $              work( ipv ), 1, icoff+1, descv )
      CALL pzlaset( 'Upper', ib, ib, zero, one, work( ipv ), 1, jv,
     $              descv )
*
*     Zeoes the strict lower triangular part of sub( A ) to get block
*     column of R
*
      CALL pzlaset( 'All', ib, n-k, zero, zero, a, ia+m-k, ja,
     $              desca )
      CALL pzlaset( 'Lower', ib-1, ib, zero, zero, a, ia+m-k+1,
     $              ja+n-k, desca )
*
*     Apply block Householder transformation
*
      CALL pzlarfb( 'Right', 'Conjugate transpose', 'Backward',
     $              'Rowwise', in-ia+1, n-m+in-ia+1, ib, work( ipv ), 1,
     $              icoff+1, descv, work( ipt ), a, ia, ja, desca,
     $              work( ipw ) )
*
      descv( rsrc_ ) = mod( descv( rsrc_ ) + 1, nprow )
*
*     Loop over the remaining row blocks
*
      DO 10 i = in+1, ia+m-1, desca( mb_ )
         ib = min( ia+m-i, desca( mb_ ) )
         jv = 1 + n - m + i - ia + icoff
*
*        Compute upper triangular matrix T
*
         CALL pzlarft( 'Backward', 'Rowwise', n-m+i+ib-ia, ib, a, i, ja,
     $                 desca, tau, work( ipt ), work( ipw ) )
*
*        Copy Householder vectors into workspace
*
         CALL pzlacpy( 'All', ib, n-m+i+ib-ia, a, i, ja, desca,
     $                 work( ipv ), 1, icoff+1, descv )
         CALL pzlaset( 'Upper', ib, ib, zero, one, work( ipv ), 1, jv,
     $                 descv )
*
*        Zeoes the strict Lower triangular part of sub( A ) to get
*        block column of R
*
         CALL pzlaset( 'All', ib, n-m+i-ia, zero, zero, a, i, ja,
     $                 desca )
         CALL pzlaset( 'Lower', ib-1, ib, zero, zero, a, i+1,
     $                 ja+n-m+i-ia, desca )
*
*        Apply block Householder transformation
*
         CALL pzlarfb( 'Right', 'Conjugate transpose', 'Backward',
     $                 'Rowwise', i+ib-ia, n-m+i+ib-ia, ib, work( ipv ),
     $                 1, icoff+1, descv, work( ipt ), a, ia, ja, desca,
     $                 work( ipw ) )
*
         descv( rsrc_ ) = mod( descv( rsrc_ ) + 1, nprow )
*
   10 CONTINUE
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      RETURN
*
*     End of PZGERQRV
*
      END