psgeqlrv.f

Go to the documentation of this file.

      SUBROUTINE psgeqlrv( M, N, A, IA, JA, DESCA, TAU, WORK )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 28, 2001
*
*     .. Scalar Arguments ..
      INTEGER            IA, JA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               A( * ),  TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PSGEQLRV computes sub( A ) = A(IA:IA+M-1,JA:JA+N-1) from L, Q
*  computed by PSGEQLF.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, sub( A ) contains the the factors L and Q computed
*          by PSGEQLF. On exit, the original matrix is restored.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) REAL, array, dimension LOCc(N_A).
*          This array contains the scalar factors TAU of the elementary
*          reflectors computed by PSGEQLF. TAU is tied to the dis-
*          tributed matrix A.
*
*  WORK    (local workspace) REAL array, dimension (LWORK)
*          LWORK = NB_A * ( 2*Mp0 + Nq0 + NB_A ), where
*          Mp0   = NUMROC( M+IROFF, MB_A, MYROW, IAROW, NPROW ) * NB_A,
*          Nq0   = NUMROC( N+ICOFF, NB_A, MYCOL, IACOL, NPCOL ) * MB_A,
*          IROFF = MOD( IA-1, MB_A ), ICOFF = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, DESCA( MB_ ), MYROW, DESCA( RSRC_ ),
*                           NPROW ),
*          IACOL = INDXG2P( JA, DESCA( NB_ ), MYCOL, DESCA( CSRC_ ),
*                           NPCOL ),
*          and NUMROC, INDXG2P are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            IACOL, IAROW, ICTXT, IIA, IPT, IPV, IPW, IROFF,
     $                   IV, J, JB, JJA, JN, K, MP, MYCOL, MYROW, NPCOL,
     $                   NPROW
*     ..
*     .. Local Arrays ..
      INTEGER            DESCV( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, pslacpy,
     $                   pslarfb, pslarft, pslaset, pb_topget,
     $                   pb_topset
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, NUMROC
      EXTERNAL           iceil, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      k = min( m, n )
      jn = min( iceil( ja+n-k, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
*
      iroff = mod( ia-1, desca( mb_ ) )
      CALL infog2l( ia, ja+n-k, desca, nprow, npcol, myrow, mycol,
     $              iia, jja, iarow, iacol )
      mp = numroc( m+iroff, desca( mb_ ), myrow, iarow, nprow )
      ipv = 1
      ipt = ipv + mp * desca( nb_ )
      ipw = ipt + desca( nb_ ) * desca( nb_ )
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'I-ring' )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
*
      CALL descset( descv, m+iroff, desca( nb_ ), desca( mb_ ),
     $              desca( nb_ ), iarow, iacol, ictxt, max( 1, mp ) )
*
*     Handle first block separately
*
      iv = 1 + m - k + iroff
      jb = jn - ja - n + k + 1
*
*     Compute upper triangular matrix T
*
      CALL pslarft( 'Backward', 'Columnwise', m-n+jn-ja+1, jb, a, ia,
     $              ja+n-k, desca, tau, work( ipt ), work( ipw ) )
*
*     Copy Householder vectors into workspace
*
      CALL pslacpy( 'All', m-n+jn-ja+1, jb, a, ia, ja+n-k, desca,
     $              work( ipv ), iroff+1, 1, descv )
      CALL pslaset( 'Lower', jb, jb, zero, one, work( ipv ), iv,
     $              1, descv )
*
*     Zeoes the strict upper triangular part of A to get block
*     row of L
*
      CALL pslaset( 'All', m-k, jb, zero, zero, a, ia, ja+n-k,
     $              desca )
      CALL pslaset( 'Upper', jb, jb-1, zero, zero, a, ia+m-k,
     $              ja+n-k+1, desca )
*
*     Apply block Householder transformation
*
      CALL pslarfb( 'Left', 'No transpose', 'Backward', 'Columnwise',
     $              m-n+jn-ja+1, jn-ja+1, jb, work( ipv ), iroff+1, 1,
     $              descv, work( ipt ), a, ia, ja, desca, work( ipw ) )
*
      descv( csrc_ ) = mod( descv( csrc_ ) + 1, npcol )
*
*     Loop over the remaining column blocks
*
      DO 10 j = jn+1, ja+n-1, desca( nb_ )
         jb = min( ja+n-j, desca( nb_ ) )
         iv = 1 + m - n + j - ja + iroff
*
*        Compute upper triangular matrix T
*
         CALL pslarft( 'Backward', 'Columnwise', m-n+j+jb-ja, jb, a, ia,
     $                 j, desca, tau, work( ipt ), work( ipw ) )
*
*        Copy Householder vectors into workspace
*
         CALL pslacpy( 'All', m-n+j+jb-ja, jb, a, ia, j, desca,
     $                 work( ipv ), iroff+1, 1, descv )
         CALL pslaset( 'Lower', jb, jb, zero, one, work( ipv ), iv,
     $                 1, descv )
*
*        Zeoes the strict upper triangular part of sub( A ) to get
*        block row of L
*
         CALL pslaset( 'All', m-n+j-ja, jb, zero, zero, a, ia, j,
     $                 desca )
         CALL pslaset( 'Upper', jb, jb-1, zero, zero, a, ia+m-n+j-ja,
     $                 j+1, desca )
*
*        Apply block Householder transformation
*
         CALL pslarfb( 'Left', 'No transpose', 'Backward', 'Columnwise',
     $                 m-n+j+jb-ja, j+jb-ja, jb, work( ipv ), iroff+1,
     $                 1, descv, work( ipt ), a, ia, ja, desca,
     $                 work( ipw ) )
*
         descv( csrc_ ) = mod( descv( csrc_ ) + 1, npcol )
*
   10 CONTINUE
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      RETURN
*
*     End of PSGEQLRV
*
      END