pdlafchk()

subroutine pdlafchk	(	character	aform,
		character	diag,
		integer	m,
		integer	n,
		double precision, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		integer	iaseed,
		double precision	anorm,
		double precision	fresid,
		double precision, dimension( * )	work
	)

Definition at line 1 of file pdlafchk.f.

*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          AFORM, DIAG
      INTEGER            IA, IASEED, JA, M, N
      DOUBLE PRECISION   ANORM, FRESID
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      DOUBLE PRECISION   A( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PDLAFCHK computes the residual
*       || sub( A ) - sub( Ao ) || / (|| sub( Ao ) ||*eps*MAX(M,N)),
*  where Ao will be regenerated by the parallel random matrix generator,
*  sub( A ) = A( IA:IA+M-1, JA:JA+N-1 ) and ||.|| stands for the infini-
*  ty norm.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  AFORM   (global input) CHARACTER
*          sub( A ) is overwritten with:
*             - a symmetric matrix, if AFORM = 'S';
*             - a Hermitian matrix, if AFORM = 'H';
*             - the transpose of what would normally be generated,
*               if AFORM = 'T';
*             - the conjugate transpose of what would normally be
*               generated, if AFORM = 'C';
*             - otherwise a random matrix.
*
*  DIAG    (global input) CHARACTER
*          if DIAG = 'D' : sub( A ) is diagonally dominant.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) DOUBLE PRECISION pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the M-by-N
*          distributed matrix sub( A ) to be checked. On exit, this
*          array contains the local pieces of the difference
*          sub( A ) - sub( Ao ).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  IASEED  (global input) INTEGER
*          The seed number to generate the original matrix Ao.
*
*  ANORM   (global input) DOUBLE PRECISION
*          The Infinity norm of sub( A ).
*
*  FRESID  (global output) DOUBLE PRECISION
*          The maximum (worst) factorizational error.
*
*  WORK    (local workspace) DOUBLE PRECISION array, dimension (LWORK).
*          LWORK >= MpA0 * NB_A, where
*
*          IROFFA = MOD( IA-1, MB_A ),
*          IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
*          MpA0 = NUMROC( M+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*
*          WORK is used to store a block of columns of sub( A ).
*          INDXG2P and NUMROC are ScaLAPACK tool functions; MYROW,
*          MYCOL, NPROW and NPCOL can be determined by calling the
*          subroutine BLACS_GRIDINFO.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            IACOL, IAROW, ICOFF, ICTXT, IIA, IOFFA, IROFF,
     $                   JB, JJ, JJA, JN, LDA, LDW, MP, MYCOL, MYROW,
     $                   NPCOL, NPROW, NQ
      DOUBLE PRECISION   EPS
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, dmatadd, infog2l, pdmatgen
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, NUMROC
      DOUBLE PRECISION   PDLAMCH, PDLANGE
      EXTERNAL           iceil, numroc, pdlamch, pdlange
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      eps = pdlamch( ictxt, 'eps' )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
*
*     Compute sub( A ) := sub( A ) - sub( Ao )
*
      iroff = mod( ia-1, desca( mb_ ) )
      icoff = mod( ja-1, desca( nb_ ) )
      mp = numroc( m+iroff, desca( mb_ ), myrow, iarow, nprow )
      nq = numroc( n+icoff, desca( nb_ ), mycol, iacol, npcol )
      IF( myrow.EQ.iarow )
     $   mp = mp-iroff
      IF( mycol.EQ.iacol )
     $   nq = nq-icoff
      jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
      ldw = max( 1, mp )
      lda = desca( lld_ )
      ioffa = iia + ( jja - 1 )*lda
*
*     Handle first block of columns separately
*
      IF( mycol.EQ.iacol ) THEN
         jb = jn-ja+1
         CALL pdmatgen( ictxt, aform, diag, desca( m_ ), desca( n_ ),
     $                  desca( mb_ ), desca( nb_ ), work, ldw,
     $                  desca( rsrc_ ), desca( csrc_ ), iaseed, iia-1,
     $                  mp, jja-1, jb, myrow, mycol, nprow, npcol )
         CALL dmatadd( mp, jb, -one, work, ldw, one, a( ioffa ), lda )
         jja = jja + jb
         nq  = nq - jb
         ioffa = ioffa + jb * lda
      END IF
*
*     Handle the remaning blocks of columns
*
      DO 10 jj = jja, jja+nq-1, desca( nb_ )
         jb = min( desca( nb_ ), jja+nq-jj )
         ioffa = iia + ( jj - 1 ) * lda
         CALL pdmatgen( ictxt, aform, diag, desca( m_ ), desca( n_ ),
     $                  desca( mb_ ), desca( nb_ ), work, ldw,
     $                  desca( rsrc_ ), desca( csrc_ ), iaseed, iia-1,
     $                  mp, jj-1, jb, myrow, mycol, nprow, npcol )
         CALL dmatadd( mp, jb, -one, work, ldw, one, a( ioffa ), lda )
   10 CONTINUE
*
*     Calculate factor residual
*
      fresid = pdlange( 'I', m, n, a, ia, ja, desca, work ) /
     $                  ( max( m, n ) * eps * anorm )
*
      RETURN
*
*     End PDLAFCHK
*

Here is the call graph for this function:

Here is the caller graph for this function: