pspocon.f

Go to the documentation of this file.

      SUBROUTINE pspocon( UPLO, N, A, IA, JA, DESCA, ANORM, RCOND, WORK,
     $                    LWORK, IWORK, LIWORK, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, INFO, JA, LIWORK, LWORK, N
      REAL               ANORM, RCOND
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), IWORK( * )
      REAL               A( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PSPOCON estimates the reciprocal of the condition number (in the
*  1-norm) of a real symmetric positive definite distributed matrix
*  using the Cholesky factorization A = U**T*U or A = L*L**T computed by
*  PSPOTRF.
*
*  An estimate is obtained for norm(inv(A(IA:IA+N-1,JA:JA+N-1))), and
*  the reciprocal of the condition number is computed as
*             RCOND = 1 / ( norm( A(IA:IA+N-1,JA:JA+N-1)      ) *
*                           norm( inv(A(IA:IA+N-1,JA:JA+N-1)) ) ).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the factor stored in
*          A(IA:IA+N-1,JA:JA+N-1) is upper or lower triangular.
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (global input) INTEGER
*          The order of the distributed matrix A(IA:IA+N-1,JA:JA+N-1).
*          N >= 0.
*
*  A       (local input) REAL pointer into the local memory to
*          an array of dimension ( LLD_A, LOCc(JA+N-1) ). On entry, this
*          array contains the local pieces of the factors L or U from
*          the Cholesky factorization A(IA:IA+N-1,JA:JA+N-1) = U'*U or
*          L*L', as computed by PSPOTRF.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  ANORM   (global input) REAL
*          The 1-norm (or infinity-norm) of the symmetric distributed
*          matrix A(IA:IA+N-1,JA:JA+N-1).
*
*  RCOND   (global output) REAL
*          The reciprocal of the condition number of the distributed
*          matrix A(IA:IA+N-1,JA:JA+N-1), computed as
*             RCOND = 1 / ( norm( A(IA:IA+N-1,JA:JA+N-1)      ) *
*                           norm( inv(A(IA:IA+N-1,JA:JA+N-1)) ) ).
*
*  WORK    (local workspace/local output) REAL array,
*                                                   dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          LWORK >= 2*LOCr(N+MOD(IA-1,MB_A)) + 2*LOCc(N+MOD(JA-1,NB_A))+
*          MAX( 2, MAX(NB_A*CEIL(NPROW-1,NPCOL),LOCc(N+MOD(JA-1,NB_A)) +
*          NB_A*CEIL(NPCOL-1,NPROW)) ).
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*  IWORK   (local workspace/local output) INTEGER array,
*                                                 dimension (LIWORK)
*          On exit, IWORK(1) returns the minimal and optimal LIWORK.
*
*  LIWORK  (local or global input) INTEGER
*          The dimension of the array IWORK.
*          LIWORK is local input and must be at least
*          LIWORK >= LOCr(N+MOD(IA-1,MB_A)).
*
*          If LIWORK = -1, then LIWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, UPPER
      CHARACTER          CBTOP, COLCTOP, NORMIN, ROWCTOP
      INTEGER            IACOL, IAROW, ICOFF, ICTXT, IIA, IPNL, IPNU,
     $                   ipv, ipw, ipx, iroff, iv, ix, ixx, jja, jv,
     $                   jx, kase, liwmin, lwmin, mycol, myrow, np,
     $                   npcol, nprow, npmod, nq, nqmod
      REAL               AINVNM, SCALE, SL, SU, SMLNUM
      REAL               WMAX
*     ..
*     .. Local Arrays ..
      INTEGER            DESCV( DLEN_ ), DESCX( DLEN_ ), IDUM1( 3 ),
     $                   idum2( 3 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, descset, infog2l,
     $                   pchk1mat, psamax, pslatrs, pslacon,
     $                   psrscl, pb_topget, pb_topset, pxerbla, sgebr2d,
     $                   sgebs2d
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, INDXG2P, NUMROC
      REAL               PSLAMCH
      EXTERNAL           iceil, indxg2p, lsame, numroc, pslamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, ichar, max, mod, real
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(600+ctxt_)
      ELSE
         CALL chk1mat( n, 2, n, 2, ia, ja, desca, 6, info )
         IF( info.EQ.0 ) THEN
            upper = lsame( uplo, 'U' )
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $                       npcol )
            npmod = numroc( n + mod( ia-1, desca( mb_ ) ), desca( mb_ ),
     $                      myrow, iarow, nprow )
            nqmod = numroc( n + mod( ja-1, desca( nb_ ) ), desca( nb_ ),
     $                      mycol, iacol, npcol )
            lwmin = 2*npmod + 2*nqmod +
     $              max( 2, max( desca( nb_ )*
     $                   max( 1, iceil( nprow-1, npcol ) ), nqmod +
     $                   desca( nb_ )*
     $                   max( 1, iceil( npcol-1, nprow ) ) ) )
            work( 1 ) = real( lwmin )
            liwmin = npmod
            iwork( 1 ) = liwmin
            lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
*
            IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
               info = -1
            ELSE IF( anorm.LT.zero ) THEN
               info = -7
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -10
            ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
               iwork( 1 ) = liwmin
               info = -12
            END IF
         END IF
*
         IF( upper ) THEN
            idum1( 1 ) = ichar( 'U' )
         ELSE
            idum1( 1 ) = ichar( 'L' )
         END IF
         idum2( 1 ) = 1
         IF( lwork.EQ.-1 ) THEN
            idum1( 2 ) = -1
         ELSE
            idum1( 2 ) = 1
         END IF
         idum2( 2 ) = 10
         IF( liwork.EQ.-1 ) THEN
            idum1( 3 ) = -1
         ELSE
            idum1( 3 ) = 1
         END IF
         idum2( 3 ) = 12
         CALL pchk1mat( n, 2, n, 2, ia, ja, desca, 6, 3, idum1, idum2,
     $                  info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PSPOCON', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      rcond = zero
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      ELSE IF( anorm.EQ.zero ) THEN
         RETURN
      ELSE IF( n.EQ.1 ) THEN
         rcond = one
         RETURN
      END IF
*
      CALL pb_topget( ictxt, 'Combine', 'Columnwise', colctop )
      CALL pb_topget( ictxt, 'Combine', 'Rowwise',    rowctop )
      CALL pb_topset( ictxt, 'Combine', 'Columnwise', '1-tree' )
      CALL pb_topset( ictxt, 'Combine', 'Rowwise',    '1-tree' )
*
      smlnum = pslamch( ictxt, 'Safe minimum' )
      iroff = mod( ia-1, desca( mb_ ) )
      icoff = mod( ja-1, desca( nb_ ) )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      np = numroc( n+iroff, desca( mb_ ), myrow, iarow, nprow )
      nq = numroc( n+icoff, desca( nb_ ), mycol, iacol, npcol )
      iv = iroff + 1
      ix = iv
      jv = icoff + 1
      jx = jv
*
      ipx  = 1
      ipv  = ipx + np
      ipnl = ipv + np
      ipnu = ipnl + nq
      ipw  = ipnu + nq
*
      CALL descset( descv, n+iroff, 1, desca( mb_ ), 1, iarow, mycol,
     $              ictxt, max( 1, np ) )
      CALL descset( descx, n+iroff, 1, desca( mb_ ), 1, iarow, mycol,
     $              ictxt, max( 1, np ) )
*
*     Estimate the 1-norm (or I-norm) of inv(A).
*
      ainvnm = zero
      kase   = 0
      normin = 'N'
*
   10 CONTINUE
      CALL pslacon( n, work( ipv ), iv, jv, descv, work( ipx ), ix, jx,
     $              descx, iwork, ainvnm, kase )
      IF( kase.NE.0 ) THEN
         IF( upper ) THEN
*
*           Multiply by inv(U').
*
            descx( csrc_ ) = iacol
            CALL pslatrs( 'Upper', 'Transpose', 'Non-unit', normin,
     $                    n, a, ia, ja, desca, work( ipx ), ix, jx,
     $                    descx, sl, work( ipnl ), work( ipw ) )
            descx( csrc_ ) = mycol
            normin = 'Y'
*
*           Multiply by inv(U).
*
            descx( csrc_ ) = iacol
            CALL pslatrs( 'Upper', 'No transpose', 'Non-unit', normin,
     $                    n, a, ia, ja, desca, work( ipx ), ix, jx,
     $                    descx, su, work( ipnu ), work( ipw ) )
            descx( csrc_ ) = mycol
         ELSE
*
*           Multiply by inv(L).
*
            descx( csrc_ ) = iacol
            CALL pslatrs( 'Lower', 'No transpose', 'Non-unit', normin,
     $                    n, a, ia, ja, desca, work( ipx ), ix, jx,
     $                    descx, sl, work( ipnl ), work( ipw ) )
            descx( csrc_ ) = mycol
            normin = 'Y'
*
*           Multiply by inv(L').
*
            descx( csrc_ ) = iacol
            CALL pslatrs( 'Lower', 'Transpose', 'Non-unit', normin,
     $                    n, a, ia, ja, desca, work( ipx ), ix, jx,
     $                    descx, su, work( ipnu ), work( ipw ) )
            descx( csrc_ ) = mycol
         END IF
*
*        Multiply by 1/SCALE if doing so will not cause overflow.
*
         scale = sl*su
         IF( scale.NE.one ) THEN
            CALL psamax( n, wmax, ixx, work( ipx ), ix, jx, descx, 1 )
            IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
               CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', cbtop )
               IF( myrow.EQ.iarow ) THEN
                  CALL sgebs2d( ictxt, 'Column', cbtop, 1, 1, wmax, 1 )
               ELSE
                  CALL sgebr2d( ictxt, 'Column', cbtop, 1, 1, wmax, 1,
     $                          iarow, mycol )
               END IF
            END IF
            IF( scale.LT.abs( wmax )*smlnum .OR. scale.EQ.zero )
     $         GO TO 20
            CALL psrscl( n, scale, work( ipx ), ix, jx, descx, 1 )
         END IF
         GO TO 10
      END IF
*
*     Compute the estimate of the reciprocal condition number.
*
      IF( ainvnm.NE.zero )
     $   rcond = ( one / ainvnm ) / anorm
*
   20 CONTINUE
*
      CALL pb_topset( ictxt, 'Combine', 'Columnwise', colctop )
      CALL pb_topset( ictxt, 'Combine', 'Rowwise',    rowctop )
*
      RETURN
*
*     End of PSPOCON
*
      END